matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/successor_1.ma".
  16 include "ground_2/notation/functions/predecessor_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/star.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'Successor m = (S m).
  23
  24 interpretation "nat predecessor" 'Predecessor m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ⫯(x+y) = (⫯x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ⫯(n1∨n2) = (⫯n1 ∨ ⫯n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  55 // qed-.
  56
  57 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  58 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  59 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  60 qed-.
  61
  62 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  63 /2 width=1 by plus_minus_minus_be/ qed-.
  64
  65 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  66 // qed.
  67
  68 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  69 /2 by plus_minus/ qed.
  70
  71 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  72 /2 by plus_minus/ qed.
  73
  74 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  75 // qed.
  76
  77 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  78 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  79 qed.
  80
  81 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  82 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  83 qed.
  84
  85 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  86 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  87
  88 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  89                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  90 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  91 qed.
  92
  93 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  94 /2 width=1 by plus_minus/ qed-.
  95
  96 (* Properties ***************************************************************)
  97
  98 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  99 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 100 [1,4: @or_intror #H destruct
 101 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 102 | /2 width=1 by or_introl/
 103 ]
 104 qed-.
 105
 106 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 107 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 108 #H elim H -m /2 width=1 by or3_intro1/
 109 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 110 qed-.
 111
 112 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 113 // qed-.
 114
 115 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 116 // qed-.
 117
 118 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 119 /3 width=1 by monotonic_le_minus_l/ qed.
 120
 121 (* Note: this might interfere with nat.ma *)
 122 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
 123 #m #n #Hmn #Hm whd >(S_pred … Hm)
 124 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 125 qed.
 126
 127 lemma lt_S_S: ∀x,y. x < y → ⫯x < ⫯y.
 128 /2 width=1 by le_S_S/ qed.
 129
 130 lemma lt_S: ∀n,m. n < m → n < ⫯m.
 131 /2 width=1 by le_S/ qed.
 132
 133 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (⫯n1 ∨ n2) ≤ ⫯n.
 134 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 135
 136 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ⫯n2) ≤ ⫯n.
 137 /2 width=1 by max_S1_le_S/ qed-.
 138
 139 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 140 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 141
 142 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 143 #z #x #y #n #Hzx #Hxny
 144 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 145 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 146 /2 width=1 by monotonic_le_minus_l2/
 147 qed.
 148
 149 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 150 #z #x #y #n #Hzx #Hyxn
 151 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 152 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 153 /2 width=1 by monotonic_le_minus_l2/
 154 qed.
 155
 156 (* Inversion & forward lemmas ***********************************************)
 157
 158 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 159 // qed-.
 160
 161 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 162 /2 width=2 by le_plus_minus_comm/ qed-.
 163
 164 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 165 /2 width=1 by monotonic_pred/ qed-.
 166
 167 lemma lt_refl_false: ∀n. n < n → ⊥.
 168 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 169 qed-.
 170
 171 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 172 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 173 qed-.
 174
 175 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 176 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 177
 178 lemma succ_inv_refl_sn: ∀x. ⫯x = x → ⊥.
 179 #x #H @(lt_le_false x (⫯x)) //
 180 qed-.
 181
 182 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ⫯m = n.
 183 * /2 width=2 by ex_intro/
 184 #H cases (lt_le_false … H) -H //
 185 qed-.
 186
 187 lemma lt_inv_S1: ∀m,n. ⫯m < n → ∃∃p. m < p & ⫯p = n.
 188 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 189 #H cases (lt_le_false … H) -H //
 190 qed-.
 191
 192 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ⫯z = y.
 193 * /3 width=3 by le_S_S_to_le, ex2_intro/
 194 #x #H elim (lt_le_false … H) -H //
 195 qed-.
 196
 197 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 198 * // normalize #m #H elim (lt_refl_false m) //
 199 qed-.
 200
 201 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 202 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 203 qed-.
 204
 205 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 206 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 207 #H elim (le_plus_xSy_O_false … H)
 208 qed-.
 209
 210 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 211 /2 width=4 by le_plus_xySz_x_false/ qed-.
 212
 213 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 214 /2 width=4 by plus_xySz_x_false/ qed-.
 215
 216 (* Note this should go in nat.ma *)
 217 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 218 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 219 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 220 #y #_ >minus_plus_plus_l
 221 #H lapply (discr_plus_xy_minus_xz … H) -H
 222 #H destruct
 223 qed-.
 224
 225 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 226 * /2 width=1 by conj/ #x #y normalize #H destruct
 227 qed-.
 228
 229 lemma lt_S_S_to_lt: ∀x,y. ⫯x < ⫯y → x < y.
 230 /2 width=1 by le_S_S_to_le/ qed-.
 231
 232 lemma lt_elim: ∀R:relation nat.
 233                (∀n2. R O (⫯n2)) →
 234                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 235                ∀n2,n1. n1 < n2 → R n1 n2.
 236 #R #IH1 #IH2 #n2 elim n2 -n2
 237 [ #n1 #H elim (lt_le_false … H) -H //
 238 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 239 ]
 240 qed-.
 241
 242 lemma le_elim: ∀R:relation nat.
 243                (∀n2. R O (n2)) →
 244                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 245                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 246 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 247 /4 width=1 by monotonic_pred/ -IH1 -IH2
 248 #n1 #H elim (lt_le_false … H) -H //
 249 qed-.
 250
 251 (* Iterators ****************************************************************)
 252
 253 (* Note: see also: lib/arithemetics/bigops.ma *)
 254 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 255   match n with
 256    [ O   ⇒ nil
 257    | S k ⇒ op (iter k B op nil)
 258    ].
 259
 260 interpretation "iterated function" 'exp op n = (iter n ? op).
 261
 262 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 263 // qed.
 264
 265 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 266 // qed.
 267
 268 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 269 #B #f #b #l >commutative_plus //
 270 qed.
 271
 272 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 273 #B #f #b #l elim l -l normalize //
 274 qed.
 275
 276 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 277 #B #f #b #l1 elim l1 -l1 normalize //
 278 qed.
 279
 280 (* Trichotomy operator ******************************************************)
 281
 282 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 283 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 284   match n1 with
 285   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 286   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 287   ].
 288
 289 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 290 #A #a1 #a2 #a3 #n2 elim n2 -n2
 291 [ #n1 #H elim (lt_zero_false … H)
 292 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 293 ]
 294 qed.
 295
 296 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 297 #A #a1 #a2 #a3 #n elim n -n normalize //
 298 qed.
 299
 300 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 301 #A #a1 #a2 #a3 #n1 elim n1 -n1
 302 [ #n2 #H elim (lt_zero_false … H)
 303 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 304 ]
 305 qed.