matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'UpArrow m = (S m).
  23
  24 interpretation "nat predecessor" 'DownArrow m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ↑n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  61 // qed.
  62
  63 lemma arith_l: ∀x. 1 = 1-x+(x-(x-1)).
  64 * // #x >minus_S_S >minus_S_S <minus_O_n <minus_n_O //
  65 qed.
  66
  67 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  68 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  69 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  70 qed-.
  71
  72 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  73 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  74 qed-.
  75
  76 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  77 /2 width=1 by plus_minus_minus_be/ qed-.
  78
  79 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  80 /2 by plus_minus/ qed-.
  81
  82 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  83 /2 by plus_minus/ qed-.
  84
  85 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  86 // qed.
  87
  88 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  89 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  90 qed-.
  91
  92 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  93 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  94 qed-.
  95
  96 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  97 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  98
  99 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
 100                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
 101 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
 102 qed-.
 103
 104 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
 105 /2 width=1 by plus_minus/ qed-.
 106
 107 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
 108                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
 109 /2 width=1 by arith_b1/ qed-.
 110
 111 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 112 #n normalize >le_to_leb_true //
 113 qed.
 114
 115 lemma associative_max: associative … max.
 116 #x #y #z normalize
 117 @(leb_elim x y) normalize #Hxy
 118 @(leb_elim y z) normalize #Hyz //
 119 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 120 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 121   >not_le_to_leb_false //
 122 ]
 123 qed.
 124
 125 (* Properties ***************************************************************)
 126
 127 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 128 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 129 [1,4: @or_intror #H destruct
 130 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 131 | /2 width=1 by or_introl/
 132 ]
 133 qed-.
 134
 135 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 136 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 137 #H elim H -m /2 width=1 by or3_intro1/
 138 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 139 qed-.
 140
 141 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 142 // qed-.
 143
 144 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 145 // qed-.
 146
 147 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 148 /3 width=1 by monotonic_le_minus_l/ qed.
 149
 150 (* Note: this might interfere with nat.ma *)
 151 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 152 #m #n #Hmn #Hm whd >(S_pred … Hm)
 153 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 154 qed.
 155
 156 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 157 /2 width=1 by le_S_S/ qed.
 158
 159 lemma lt_S: ∀n,m. n < m → n < ↑m.
 160 /2 width=1 by le_S/ qed.
 161
 162 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 163 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 164
 165 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 166 /2 width=1 by max_S1_le_S/ qed-.
 167
 168 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 169 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 170
 171 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 172 #z #x #y #n #Hzx #Hxny
 173 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 174 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 175 /2 width=1 by monotonic_le_minus_l2/
 176 qed.
 177
 178 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 179 #z #x #y #n #Hzx #Hyxn
 180 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 181 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 182 /2 width=1 by monotonic_le_minus_l2/
 183 qed.
 184
 185 (* Inversion & forward lemmas ***********************************************)
 186
 187 lemma lt_refl_false: ∀n. n < n → ⊥.
 188 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 189 qed-.
 190
 191 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 192 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 193 qed-.
 194
 195 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 196 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 197
 198 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 199 #x #H @(lt_le_false x (↑x)) //
 200 qed-.
 201
 202 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 203 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 204 qed-.
 205
 206 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 207 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 208 #H elim (le_plus_xSy_O_false … H)
 209 qed-.
 210
 211 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 212 /2 width=4 by le_plus_xySz_x_false/ qed-.
 213
 214 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 215 /2 width=4 by plus_xySz_x_false/ qed-.
 216
 217 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 218 * // normalize #m #H elim (lt_refl_false m) //
 219 qed-.
 220
 221 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 222 // qed-.
 223
 224 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 225 /2 width=2 by le_plus_minus_comm/ qed-.
 226
 227 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 228 /2 width=1 by monotonic_pred/ qed-.
 229
 230 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 231 #m1 #m2 #n1 #n2 #H #Hm
 232 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 233 /2 width=2 by le_plus_to_le/
 234 qed-.
 235
 236 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 237 /2 width=1 by le_S_S_to_le/ qed-.
 238
 239 (* Note this should go in nat.ma *)
 240 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 241 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 242 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 243 #y #_ >minus_plus_plus_l
 244 #H lapply (discr_plus_xy_minus_xz … H) -H
 245 #H destruct
 246 qed-.
 247
 248 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 249 * /2 width=2 by ex_intro/
 250 #H cases (lt_le_false … H) -H //
 251 qed-.
 252
 253 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 254 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 255 #H cases (lt_le_false … H) -H //
 256 qed-.
 257
 258 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 259 * /3 width=3 by le_S_S_to_le, ex2_intro/
 260 #x #H elim (lt_le_false … H) -H //
 261 qed-.
 262
 263 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 264 /2 width=1 by plus_le_0/ qed-.
 265
 266 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 267                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 268                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 269 * /3 width=1 by or_introl, conj/
 270 #x1 #x2 #x3 <plus_S1 #H destruct
 271 /3 width=3 by ex2_intro, or_intror/
 272 qed-.
 273
 274 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 275                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 276                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 277 * /3 width=1 by or_introl, conj/
 278 #x2 #x1 #x3 <plus_n_Sm #H destruct
 279 /3 width=3 by ex2_intro, or_intror/
 280 qed-.
 281
 282 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 283 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 284 qed-.
 285
 286 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 287 * /2 width=1 by conj/ #x #y normalize #H destruct
 288 qed-.
 289
 290 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 291 * /3 width=2 by ex_intro, or_introl, or_intror/
 292 qed-.
 293
 294 lemma lt_elim: ∀R:relation nat.
 295                (∀n2. R O (↑n2)) →
 296                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 297                ∀n2,n1. n1 < n2 → R n1 n2.
 298 #R #IH1 #IH2 #n2 elim n2 -n2
 299 [ #n1 #H elim (lt_le_false … H) -H //
 300 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 301 ]
 302 qed-.
 303
 304 lemma le_elim: ∀R:relation nat.
 305                (∀n2. R O (n2)) →
 306                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 307                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 308 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 309 /4 width=1 by monotonic_pred/ -IH1 -IH2
 310 #n1 #H elim (lt_le_false … H) -H //
 311 qed-.
 312
 313 (* Iterators ****************************************************************)
 314
 315 (* Note: see also: lib/arithemetics/bigops.ma *)
 316 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 317   match n with
 318    [ O   ⇒ nil
 319    | S k ⇒ op (iter k B op nil)
 320    ].
 321
 322 interpretation "iterated function" 'exp op n = (iter n ? op).
 323
 324 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 325 // qed.
 326
 327 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 328 // qed.
 329
 330 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 331 #B #f #b #l >commutative_plus //
 332 qed.
 333
 334 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 335 #B #f #b #l elim l -l normalize //
 336 qed.
 337
 338 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 339 #B #f #b #l1 elim l1 -l1 normalize //
 340 qed.
 341
 342 (* Trichotomy operator ******************************************************)
 343
 344 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 345 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 346   match n1 with
 347   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 348   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 349   ].
 350
 351 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 352 #A #a1 #a2 #a3 #n2 elim n2 -n2
 353 [ #n1 #H elim (lt_zero_false … H)
 354 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 355 ]
 356 qed.
 357
 358 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 359 #A #a1 #a2 #a3 #n elim n -n normalize //
 360 qed.
 361
 362 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 363 #A #a1 #a2 #a3 #n1 elim n1 -n1
 364 [ #n2 #H elim (lt_zero_false … H)
 365 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 366 ]
 367 qed.