matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'UpArrow m = (S m).
  23
  24 interpretation "nat predecessor" 'DownArrow m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ↑n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  61 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  62 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  63 qed-.
  64
  65 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  66 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  67 qed-.
  68
  69 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  70 /2 width=1 by plus_minus_minus_be/ qed-.
  71
  72 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  73 // qed.
  74
  75 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  76 /2 by plus_minus/ qed-.
  77
  78 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  79 /2 by plus_minus/ qed-.
  80
  81 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  82 // qed.
  83
  84 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  85 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  86 qed-.
  87
  88 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  89 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  90 qed-.
  91
  92 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  93 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  94
  95 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  96                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  97 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  98 qed-.
  99
 100 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
 101 /2 width=1 by plus_minus/ qed-.
 102
 103 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
 104                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
 105 /2 width=1 by arith_b1/ qed-.
 106
 107 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 108 #n normalize >le_to_leb_true //
 109 qed.
 110
 111 lemma associative_max: associative … max.
 112 #x #y #z normalize
 113 @(leb_elim x y) normalize #Hxy
 114 @(leb_elim y z) normalize #Hyz //
 115 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 116 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 117   >not_le_to_leb_false //
 118 ]
 119 qed.
 120
 121 (* Properties ***************************************************************)
 122
 123 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 124 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 125 [1,4: @or_intror #H destruct
 126 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 127 | /2 width=1 by or_introl/
 128 ]
 129 qed-.
 130
 131 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 132 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 133 #H elim H -m /2 width=1 by or3_intro1/
 134 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 135 qed-.
 136
 137 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 138 // qed-.
 139
 140 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 141 // qed-.
 142
 143 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 144 /3 width=1 by monotonic_le_minus_l/ qed.
 145
 146 (* Note: this might interfere with nat.ma *)
 147 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 148 #m #n #Hmn #Hm whd >(S_pred … Hm)
 149 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 150 qed.
 151
 152 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 153 /2 width=1 by le_S_S/ qed.
 154
 155 lemma lt_S: ∀n,m. n < m → n < ↑m.
 156 /2 width=1 by le_S/ qed.
 157
 158 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 159 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 160
 161 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 162 /2 width=1 by max_S1_le_S/ qed-.
 163
 164 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 165 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 166
 167 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 168 #z #x #y #n #Hzx #Hxny
 169 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 170 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 171 /2 width=1 by monotonic_le_minus_l2/
 172 qed.
 173
 174 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 175 #z #x #y #n #Hzx #Hyxn
 176 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 177 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 178 /2 width=1 by monotonic_le_minus_l2/
 179 qed.
 180
 181 (* Inversion & forward lemmas ***********************************************)
 182
 183 lemma lt_refl_false: ∀n. n < n → ⊥.
 184 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 185 qed-.
 186
 187 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 188 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 189 qed-.
 190
 191 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 192 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 193
 194 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 195 #x #H @(lt_le_false x (↑x)) //
 196 qed-.
 197
 198 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 199 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 200 qed-.
 201
 202 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 203 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 204 #H elim (le_plus_xSy_O_false … H)
 205 qed-.
 206
 207 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 208 /2 width=4 by le_plus_xySz_x_false/ qed-.
 209
 210 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 211 /2 width=4 by plus_xySz_x_false/ qed-.
 212
 213 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 214 * // normalize #m #H elim (lt_refl_false m) //
 215 qed-.
 216
 217 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 218 // qed-.
 219
 220 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 221 /2 width=2 by le_plus_minus_comm/ qed-.
 222
 223 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 224 /2 width=1 by monotonic_pred/ qed-.
 225
 226 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 227 #m1 #m2 #n1 #n2 #H #Hm
 228 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 229 /2 width=2 by le_plus_to_le/
 230 qed-.
 231
 232 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 233 /2 width=1 by le_S_S_to_le/ qed-.
 234
 235 (* Note this should go in nat.ma *)
 236 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 237 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 238 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 239 #y #_ >minus_plus_plus_l
 240 #H lapply (discr_plus_xy_minus_xz … H) -H
 241 #H destruct
 242 qed-.
 243
 244 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 245 * /2 width=2 by ex_intro/
 246 #H cases (lt_le_false … H) -H //
 247 qed-.
 248
 249 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 250 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 251 #H cases (lt_le_false … H) -H //
 252 qed-.
 253
 254 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 255 * /3 width=3 by le_S_S_to_le, ex2_intro/
 256 #x #H elim (lt_le_false … H) -H //
 257 qed-.
 258
 259 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 260 /2 width=1 by plus_le_0/ qed-.
 261
 262 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 263                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 264                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 265 * /3 width=1 by or_introl, conj/
 266 #x1 #x2 #x3 <plus_S1 #H destruct
 267 /3 width=3 by ex2_intro, or_intror/
 268 qed-.
 269
 270 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 271                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 272                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 273 * /3 width=1 by or_introl, conj/
 274 #x2 #x1 #x3 <plus_n_Sm #H destruct
 275 /3 width=3 by ex2_intro, or_intror/
 276 qed-.
 277
 278 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 279 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 280 qed-.
 281
 282 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 283 * /2 width=1 by conj/ #x #y normalize #H destruct
 284 qed-.
 285
 286 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 287 * /3 width=2 by ex_intro, or_introl, or_intror/
 288 qed-.
 289
 290 lemma lt_elim: ∀R:relation nat.
 291                (∀n2. R O (↑n2)) →
 292                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 293                ∀n2,n1. n1 < n2 → R n1 n2.
 294 #R #IH1 #IH2 #n2 elim n2 -n2
 295 [ #n1 #H elim (lt_le_false … H) -H //
 296 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 297 ]
 298 qed-.
 299
 300 lemma le_elim: ∀R:relation nat.
 301                (∀n2. R O (n2)) →
 302                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 303                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 304 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 305 /4 width=1 by monotonic_pred/ -IH1 -IH2
 306 #n1 #H elim (lt_le_false … H) -H //
 307 qed-.
 308
 309 (* Iterators ****************************************************************)
 310
 311 (* Note: see also: lib/arithemetics/bigops.ma *)
 312 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 313   match n with
 314    [ O   ⇒ nil
 315    | S k ⇒ op (iter k B op nil)
 316    ].
 317
 318 interpretation "iterated function" 'exp op n = (iter n ? op).
 319
 320 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 321 // qed.
 322
 323 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 324 // qed.
 325
 326 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 327 #B #f #b #l >commutative_plus //
 328 qed.
 329
 330 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 331 #B #f #b #l elim l -l normalize //
 332 qed.
 333
 334 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 335 #B #f #b #l1 elim l1 -l1 normalize //
 336 qed.
 337
 338 (* Trichotomy operator ******************************************************)
 339
 340 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 341 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 342   match n1 with
 343   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 344   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 345   ].
 346
 347 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 348 #A #a1 #a2 #a3 #n2 elim n2 -n2
 349 [ #n1 #H elim (lt_zero_false … H)
 350 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 351 ]
 352 qed.
 353
 354 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 355 #A #a1 #a2 #a3 #n elim n -n normalize //
 356 qed.
 357
 358 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 359 #A #a1 #a2 #a3 #n1 elim n1 -n1
 360 [ #n2 #H elim (lt_zero_false … H)
 361 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 362 ]
 363 qed.