matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'UpArrow m = (S m).
  23
  24 interpretation "nat predecessor" 'DownArrow m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ↑n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  61 // qed.
  62
  63 lemma arith_l: ∀x. 1 = 1-x+(x-(x-1)).
  64 * // #x >minus_S_S >minus_S_S <minus_O_n <minus_n_O //
  65 qed.
  66
  67 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  68 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  69 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  70 qed-.
  71
  72 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  73 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  74 qed-.
  75
  76 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  77 /2 width=1 by plus_minus_minus_be/ qed-.
  78
  79 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  80 /2 by plus_minus/ qed-.
  81
  82 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  83 /2 by plus_minus/ qed-.
  84
  85 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  86 // qed.
  87
  88 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  89 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  90 qed-.
  91
  92 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  93 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  94 qed-.
  95
  96 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  97 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  98
  99 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
 100                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
 101 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
 102 qed-.
 103
 104 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
 105 /2 width=1 by plus_minus/ qed-.
 106
 107 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
 108                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
 109 /2 width=1 by arith_b1/ qed-.
 110
 111 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 112 #n normalize >le_to_leb_true //
 113 qed.
 114
 115 lemma associative_max: associative … max.
 116 #x #y #z normalize
 117 @(leb_elim x y) normalize #Hxy
 118 @(leb_elim y z) normalize #Hyz //
 119 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 120 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 121   >not_le_to_leb_false //
 122 ]
 123 qed.
 124
 125 (* Properties ***************************************************************)
 126
 127 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 128 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 129 [1,4: @or_intror #H destruct
 130 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 131 | /2 width=1 by or_introl/
 132 ]
 133 qed-.
 134
 135 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 136 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 137 #H elim H -m /2 width=1 by or3_intro1/
 138 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 139 qed-.
 140
 141 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 142 // qed-.
 143
 144 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 145 // qed-.
 146
 147 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 148 /3 width=1 by monotonic_le_minus_l/ qed.
 149
 150 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 151 /2 width=3 by transitive_le/ qed.
 152
 153 (* Note: this might interfere with nat.ma *)
 154 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 155 #m #n #Hmn #Hm whd >(S_pred … Hm)
 156 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 157 qed.
 158
 159 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 160 /2 width=1 by le_S_S/ qed.
 161
 162 lemma lt_S: ∀n,m. n < m → n < ↑m.
 163 /2 width=1 by le_S/ qed.
 164
 165 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 166 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 167
 168 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 169 /2 width=1 by max_S1_le_S/ qed-.
 170
 171 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 172 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 173
 174 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 175 #z #x #y #n #Hzx #Hxny
 176 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 177 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 178 /2 width=1 by monotonic_le_minus_l2/
 179 qed.
 180
 181 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 182 #z #x #y #n #Hzx #Hyxn
 183 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 184 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 185 /2 width=1 by monotonic_le_minus_l2/
 186 qed.
 187
 188 (* Inversion & forward lemmas ***********************************************)
 189
 190 lemma lt_refl_false: ∀n. n < n → ⊥.
 191 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 192 qed-.
 193
 194 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 195 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 196 qed-.
 197
 198 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 199 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 200
 201 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 202 #x #H @(lt_le_false x (↑x)) //
 203 qed-.
 204
 205 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 206 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 207 qed-.
 208
 209 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 210 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 211 #H elim (le_plus_xSy_O_false … H)
 212 qed-.
 213
 214 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 215 /2 width=4 by le_plus_xySz_x_false/ qed-.
 216
 217 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 218 /2 width=4 by plus_xySz_x_false/ qed-.
 219
 220 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 221 * // normalize #m #H elim (lt_refl_false m) //
 222 qed-.
 223
 224 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 225 // qed-.
 226
 227 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 228 /2 width=2 by le_plus_minus_comm/ qed-.
 229
 230 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 231 /2 width=1 by monotonic_pred/ qed-.
 232
 233 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 234 #m1 #m2 #n1 #n2 #H #Hm
 235 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 236 /2 width=2 by le_plus_to_le/
 237 qed-.
 238
 239 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 240 /2 width=1 by le_S_S_to_le/ qed-.
 241
 242 (* Note this should go in nat.ma *)
 243 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 244 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 245 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 246 #y #_ >minus_plus_plus_l
 247 #H lapply (discr_plus_xy_minus_xz … H) -H
 248 #H destruct
 249 qed-.
 250
 251 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 252 * /2 width=2 by ex_intro/
 253 #H cases (lt_le_false … H) -H //
 254 qed-.
 255
 256 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 257 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 258 #H cases (lt_le_false … H) -H //
 259 qed-.
 260
 261 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 262 * /3 width=3 by le_S_S_to_le, ex2_intro/
 263 #x #H elim (lt_le_false … H) -H //
 264 qed-.
 265
 266 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 267 /2 width=1 by plus_le_0/ qed-.
 268
 269 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 270                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 271                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 272 * /3 width=1 by or_introl, conj/
 273 #x1 #x2 #x3 <plus_S1 #H destruct
 274 /3 width=3 by ex2_intro, or_intror/
 275 qed-.
 276
 277 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 278                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 279                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 280 * /3 width=1 by or_introl, conj/
 281 #x2 #x1 #x3 <plus_n_Sm #H destruct
 282 /3 width=3 by ex2_intro, or_intror/
 283 qed-.
 284
 285 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 286 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 287 qed-.
 288
 289 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 290 * /2 width=1 by conj/ #x #y normalize #H destruct
 291 qed-.
 292
 293 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 294 * /3 width=2 by ex_intro, or_introl, or_intror/
 295 qed-.
 296
 297 lemma lt_elim: ∀R:relation nat.
 298                (∀n2. R O (↑n2)) →
 299                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 300                ∀n2,n1. n1 < n2 → R n1 n2.
 301 #R #IH1 #IH2 #n2 elim n2 -n2
 302 [ #n1 #H elim (lt_le_false … H) -H //
 303 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 304 ]
 305 qed-.
 306
 307 lemma le_elim: ∀R:relation nat.
 308                (∀n2. R O (n2)) →
 309                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 310                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 311 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 312 /4 width=1 by monotonic_pred/ -IH1 -IH2
 313 #n1 #H elim (lt_le_false … H) -H //
 314 qed-.
 315
 316 (* Iterators ****************************************************************)
 317
 318 (* Note: see also: lib/arithemetics/bigops.ma *)
 319 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 320   match n with
 321    [ O   ⇒ nil
 322    | S k ⇒ op (iter k B op nil)
 323    ].
 324
 325 interpretation "iterated function" 'exp op n = (iter n ? op).
 326
 327 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 328 // qed.
 329
 330 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 331 // qed.
 332
 333 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 334 #B #f #b #l >commutative_plus //
 335 qed.
 336
 337 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 338 #B #f #b #l elim l -l normalize //
 339 qed.
 340
 341 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 342 #B #f #b #l1 elim l1 -l1 normalize //
 343 qed.
 344
 345 (* Trichotomy operator ******************************************************)
 346
 347 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 348 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 349   match n1 with
 350   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 351   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 352   ].
 353
 354 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 355 #A #a1 #a2 #a3 #n2 elim n2 -n2
 356 [ #n1 #H elim (lt_zero_false … H)
 357 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 358 ]
 359 qed.
 360
 361 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 362 #A #a1 #a2 #a3 #n elim n -n normalize //
 363 qed.
 364
 365 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 366 #A #a1 #a2 #a3 #n1 elim n1 -n1
 367 [ #n2 #H elim (lt_zero_false … H)
 368 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 369 ]
 370 qed.