matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/pull/pull_2.ma".
  19 include "ground_2/lib/relations.ma".
  20
  21 (* ARITHMETICAL PROPERTIES **************************************************)
  22
  23 interpretation "nat successor" 'UpArrow m = (S m).
  24
  25 interpretation "nat predecessor" 'DownArrow m = (pred m).
  26
  27 interpretation "nat min" 'and x y = (min x y).
  28
  29 interpretation "nat max" 'or x y = (max x y).
  30
  31 (* Iota equations ***********************************************************)
  32
  33 lemma pred_O: pred 0 = 0.
  34 normalize // qed.
  35
  36 lemma pred_S: ∀m. pred (S m) = m.
  37 // qed.
  38
  39 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  40 // qed.
  41
  42 lemma max_O1: ∀n. n = (0 ∨ n).
  43 // qed.
  44
  45 lemma max_O2: ∀n. n = (n ∨ 0).
  46 // qed.
  47
  48 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  49 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  50 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  51 qed.
  52
  53 (* Equalities ***************************************************************)
  54
  55 lemma plus_SO_sn (n): 1 + n = ↑n.
  56 // qed-.
  57
  58 lemma plus_SO_dx (n): n + 1 = ↑n.
  59 // qed.
  60
  61 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  62 // qed-.
  63
  64 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
  65 /2 width=1 by plus_minus_associative/ qed-.
  66
  67 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  68                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  69 #m1 #m2 #n1 #n2 #H1 #H2 #H
  70 @plus_to_minus >plus_minus_associative //
  71 qed-.
  72
  73 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  74 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  75 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  76 qed-.
  77
  78 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  79 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  80 qed-.
  81
  82 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  83 /2 width=1 by plus_minus_minus_be/ qed-.
  84
  85 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  86 /2 by plus_minus/ qed-.
  87
  88 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  89 /2 by plus_minus/ qed-.
  90
  91 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  92 // qed.
  93
  94 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
  95 #n normalize >le_to_leb_true //
  96 qed.
  97
  98 lemma associative_max: associative … max.
  99 #x #y #z normalize
 100 @(leb_elim x y) normalize #Hxy
 101 @(leb_elim y z) normalize #Hyz //
 102 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 103 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 104   >not_le_to_leb_false //
 105 ]
 106 qed.
 107
 108 (* Properties ***************************************************************)
 109
 110 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 111 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 112 [1,4: @or_intror #H destruct
 113 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 114 | /2 width=1 by or_introl/
 115 ]
 116 qed-.
 117
 118 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 119 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 120 #H elim H -m /2 width=1 by or3_intro1/
 121 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 122 qed-.
 123
 124 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 125 /3 width=1 by monotonic_le_minus_l/ qed.
 126
 127 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 128 /2 width=3 by transitive_le/ qed.
 129
 130 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
 131 /2 width=1 by le_plus_to_minus_r/
 132 qed-.
 133
 134 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
 135 /2 width=1 by le_plus_to_minus/ qed-.
 136
 137 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
 138 #m *
 139 [ #H lapply (le_n_O_to_eq … H) -H
 140   #H destruct
 141 | /3 width=3 by monotonic_pred, ex2_intro/
 142 ]
 143 qed-.
 144
 145 (* Note: this might interfere with nat.ma *)
 146 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 147 #m #n #Hmn #Hm whd >(S_pred … Hm)
 148 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 149 qed.
 150
 151 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 152 /2 width=1 by le_S_S/ qed.
 153
 154 lemma lt_S: ∀n,m. n < m → n < ↑m.
 155 /2 width=1 by le_S/ qed.
 156
 157 lemma monotonic_lt_minus_r:
 158 ∀p,q,n. q < n -> q < p → n-p < n-q.
 159 #p #q #n #Hn #H
 160 lapply (monotonic_le_minus_r … n H) -H #H
 161 @(le_to_lt_to_lt … H) -H
 162 /2 width=1 by lt_plus_to_minus/
 163 qed.
 164
 165 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 166 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 167
 168 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 169 /2 width=1 by max_S1_le_S/ qed-.
 170
 171 (* Inversion & forward lemmas ***********************************************)
 172
 173 lemma lt_refl_false: ∀n. n < n → ⊥.
 174 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 175 qed-.
 176
 177 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 178 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 179 qed-.
 180
 181 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 182 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 183
 184 lemma le_dec (n) (m): Decidable (n≤m).
 185 #n elim n -n [ /2 width=1 by or_introl/ ]
 186 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 187 #m elim (IH m) -IH
 188 [ /3 width=1 by or_introl, le_S_S/
 189 | /4 width=1 by or_intror, le_S_S_to_le/
 190 ]
 191 qed-.
 192
 193 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 194 #x #H @(lt_le_false x (↑x)) //
 195 qed-.
 196
 197 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 198 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 199 qed-.
 200
 201 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 202 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 203 #H elim (le_plus_xSy_O_false … H)
 204 qed-.
 205
 206 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 207 /2 width=4 by le_plus_xySz_x_false/ qed-.
 208
 209 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 210 /2 width=4 by plus_xySz_x_false/ qed-.
 211
 212 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 213 * // #x <pred_Sn #H
 214 elim (succ_inv_refl_sn x) //
 215 qed-.
 216
 217 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 218 // qed-.
 219
 220 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 221 /2 width=2 by le_plus_minus_comm/ qed-.
 222
 223 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 224 #m1 #m2 #n1 #n2 #H #Hm
 225 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 226 /2 width=2 by le_plus_to_le/
 227 qed-.
 228
 229 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 230 /2 width=1 by le_S_S_to_le/ qed-.
 231
 232 (* Note this should go in nat.ma *)
 233 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 234 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 235 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 236 #y #_ >minus_plus_plus_l
 237 #H lapply (discr_plus_xy_minus_xz … H) -H
 238 #H destruct
 239 qed-.
 240
 241 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 242 * /2 width=2 by ex_intro/
 243 #H cases (lt_le_false … H) -H //
 244 qed-.
 245
 246 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 247 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 248 #H cases (lt_le_false … H) -H //
 249 qed-.
 250
 251 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 252 * /3 width=3 by le_S_S_to_le, ex2_intro/
 253 #x #H elim (lt_le_false … H) -H //
 254 qed-.
 255
 256 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 257 /2 width=1 by plus_le_0/ qed-.
 258
 259 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 260                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 261                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 262 * /3 width=1 by or_introl, conj/
 263 #x1 #x2 #x3 <plus_S1 #H destruct
 264 /3 width=3 by ex2_intro, or_intror/
 265 qed-.
 266
 267 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 268                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 269                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 270 * /3 width=1 by or_introl, conj/
 271 #x2 #x1 #x3 <plus_n_Sm #H destruct
 272 /3 width=3 by ex2_intro, or_intror/
 273 qed-.
 274
 275 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 276 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 277 qed-.
 278
 279 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 280 * /2 width=1 by conj/ #x #y normalize #H destruct
 281 qed-.
 282
 283 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 284 * /3 width=2 by ex_intro, or_introl, or_intror/
 285 qed-.
 286
 287 lemma lt_elim: ∀R:relation nat.
 288                (∀n2. R O (↑n2)) →
 289                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 290                ∀n2,n1. n1 < n2 → R n1 n2.
 291 #R #IH1 #IH2 #n2 elim n2 -n2
 292 [ #n1 #H elim (lt_le_false … H) -H //
 293 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 294 ]
 295 qed-.
 296
 297 lemma le_elim: ∀R:relation nat.
 298                (∀n2. R O (n2)) →
 299                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 300                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 301 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 302 /4 width=1 by monotonic_pred/ -IH1 -IH2
 303 #n1 #H elim (lt_le_false … H) -H //
 304 qed-.
 305
 306 lemma nat_elim_le_sn (Q:relation …):
 307       (∀m1,m2. (∀m. m < m2-m1 → Q (m2-m) m2) → m1 ≤ m2 → Q m1 m2) →
 308       ∀n1,n2. n1 ≤ n2 → Q n1 n2.
 309 #Q #IH #n1 #n2 #Hn
 310 <(minus_minus_m_m … Hn) -Hn
 311 lapply (minus_le n2 n1)
 312 let d ≝ (n2-n1)
 313 @(nat_elim1 … d) -d -n1 #d
 314 @pull_2 #Hd
 315 <(minus_minus_m_m … Hd) in ⊢ (%→?); -Hd
 316 let n1 ≝ (n2-d) #IHd
 317 @IH -IH [| // ] #m #Hn
 318 /4 width=3 by lt_to_le, lt_to_le_to_lt/
 319 qed-.
 320
 321 (* Iterators ****************************************************************)
 322
 323 (* Note: see also: lib/arithemetics/bigops.ma *)
 324 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 325   match n with
 326    [ O   ⇒ nil
 327    | S k ⇒ op (iter k B op nil)
 328    ].
 329
 330 interpretation "iterated function" 'exp op n = (iter n ? op).
 331
 332 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 333 // qed.
 334
 335 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 336 // qed.
 337
 338 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 339 #B #f #b #l elim l -l normalize //
 340 qed.
 341
 342 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 343 #B #f #b #l1 elim l1 -l1 normalize //
 344 qed.
 345
 346 (* Trichotomy operator ******************************************************)
 347
 348 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 349 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 350   match n1 with
 351   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 352   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 353   ].
 354
 355 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 356 #A #a1 #a2 #a3 #n2 elim n2 -n2
 357 [ #n1 #H elim (lt_zero_false … H)
 358 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 359 ]
 360 qed.
 361
 362 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 363 #A #a1 #a2 #a3 #n elim n -n normalize //
 364 qed.
 365
 366 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 367 #A #a1 #a2 #a3 #n1 elim n1 -n1
 368 [ #n2 #H elim (lt_zero_false … H)
 369 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 370 ]
 371 qed.
 372
 373 (* Decidability of predicates ***********************************************)
 374
 375 lemma dec_lt (R:predicate nat):
 376       (∀n. Decidable … (R n)) →
 377       ∀n. Decidable … (∃∃m. m < n & R m).
 378 #R #HR #n elim n -n [| #n * ]
 379 [ @or_intror * /2 width=2 by lt_zero_false/
 380 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 381 | #H0 elim (HR n) -HR
 382   [ /3 width=3 by or_introl, ex2_intro/
 383   | #Hn @or_intror * #m #Hmn #Hm
 384     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 385     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 386   ]
 387 ]
 388 qed-.
 389
 390 lemma dec_min (R:predicate nat):
 391       (∀n. Decidable … (R n)) → ∀n. R n →
 392       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 393 #R #HR #n
 394 @(nat_elim1 n) -n #n #IH #Hn
 395 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 396 [ * #p #Hpn #Hp
 397   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 398   @(ex3_intro … Hm HNm) -HNm
 399   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 400 | /4 width=4 by ex3_intro, ex2_intro/
 401 ]
 402 qed-.