matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/successor_1.ma".
  16 include "ground_2/notation/functions/predecessor_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/star.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'Successor m = (S m).
  23
  24 interpretation "nat predecessor" 'Predecessor m = (pred m).
  25
  26 (* Iota equations ***********************************************************)
  27
  28 lemma pred_O: pred 0 = 0.
  29 normalize // qed.
  30
  31 lemma pred_S: ∀m. pred (S m) = m.
  32 // qed.
  33
  34 (* Equations ****************************************************************)
  35
  36 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  37 // qed-.
  38
  39 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  40 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  41 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  42 qed-.
  43
  44 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  45 /2 width=1 by plus_minus_minus_be/ qed-.
  46
  47 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  48 // qed.
  49
  50 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  51 /2 by plus_minus/ qed.
  52
  53 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  54 /2 by plus_minus/ qed.
  55
  56 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  57 // qed.
  58
  59 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  60 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  61 qed.
  62
  63 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  64 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  65 qed.
  66
  67 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  68 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  69
  70 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  71                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  72 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  73 qed.
  74
  75 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  76 /2 width=1 by plus_minus/ qed-.
  77
  78 (* Properties ***************************************************************)
  79
  80 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  81 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
  82 [1,4: @or_intror #H destruct
  83 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
  84 | /2 width=1 by or_introl/
  85 ]
  86 qed-.
  87
  88 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  89 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
  90 #H elim H -m /2 width=1 by or3_intro1/
  91 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
  92 qed-.
  93
  94 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
  95 // qed-.
  96
  97 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
  98 // qed-.
  99
 100 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 101 /3 width=1 by monotonic_le_minus_l/ qed.
 102
 103 (* Note: this might interfere with nat.ma *)
 104 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
 105 #m #n #Hmn #Hm whd >(S_pred … Hm)
 106 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 107 qed.
 108
 109 lemma lt_S_S: ∀x,y. x < y → ⫯x < ⫯y.
 110 /2 width=1 by le_S_S/ qed.
 111
 112 lemma lt_S: ∀n,m. n < m → n < ⫯m.
 113 /2 width=1 by le_S/ qed.
 114
 115 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 116 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 117
 118 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 119 #z #x #y #n #Hzx #Hxny
 120 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 121 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 122 /2 width=1 by monotonic_le_minus_l2/
 123 qed.
 124
 125 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 126 #z #x #y #n #Hzx #Hyxn
 127 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 128 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 129 /2 width=1 by monotonic_le_minus_l2/
 130 qed.
 131
 132 (* Inversion & forward lemmas ***********************************************)
 133
 134 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 135 // qed-.
 136
 137 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 138 /2 width=1 by monotonic_pred/ qed-.
 139
 140 lemma lt_refl_false: ∀n. n < n → ⊥.
 141 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 142 qed-.
 143
 144 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 145 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 146 qed-.
 147
 148 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 149 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 150
 151 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ⫯m = n.
 152 * /2 width=2 by ex_intro/
 153 #H cases (lt_le_false … H) -H //
 154 qed-.
 155
 156 lemma lt_inv_S1: ∀m,n. ⫯m < n → ∃∃p. m < p & ⫯p = n.
 157 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 158 #H cases (lt_le_false … H) -H //
 159 qed-.
 160
 161 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ⫯z = y.
 162 * /3 width=3 by le_S_S_to_le, ex2_intro/
 163 #x #H elim (lt_le_false … H) -H //
 164 qed-.
 165
 166 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 167 * // normalize #m #H elim (lt_refl_false m) //
 168 qed-.
 169
 170 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 171 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 172 qed-.
 173
 174 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 175 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 176 #H elim (le_plus_xSy_O_false … H)
 177 qed-.
 178
 179 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 180 /2 width=4 by le_plus_xySz_x_false/ qed-.
 181
 182 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 183 /2 width=4 by plus_xySz_x_false/ qed-.
 184
 185 (* Note this should go in nat.ma *)
 186 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 187 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 188 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 189 #y #_ >minus_plus_plus_l
 190 #H lapply (discr_plus_xy_minus_xz … H) -H
 191 #H destruct
 192 qed-.
 193
 194 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 195 * /2 width=1 by conj/ #x #y normalize #H destruct
 196 qed-.
 197
 198 lemma lt_S_S_to_lt: ∀x,y. ⫯x < ⫯y → x < y.
 199 /2 width=1 by le_S_S_to_le/ qed-.
 200
 201 lemma lt_elim: ∀R:relation nat.
 202                (∀n2. R O (⫯n2)) →
 203                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 204                ∀n2,n1. n1 < n2 → R n1 n2.
 205 #R #IH1 #IH2 #n2 elim n2 -n2
 206 [ #n1 #H elim (lt_le_false … H) -H //
 207 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 208 ]
 209 qed-.
 210
 211 lemma le_elim: ∀R:relation nat.
 212                (∀n2. R O (n2)) →
 213                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 214                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 215 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 216 /4 width=1 by monotonic_pred/ -IH1 -IH2
 217 #n1 #H elim (lt_le_false … H) -H //
 218 qed-.
 219
 220 (* Iterators ****************************************************************)
 221
 222 (* Note: see also: lib/arithemetics/bigops.ma *)
 223 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 224   match n with
 225    [ O   ⇒ nil
 226    | S k ⇒ op (iter k B op nil)
 227    ].
 228
 229 interpretation "iterated function" 'exp op n = (iter n ? op).
 230
 231 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 232 // qed.
 233
 234 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 235 // qed.
 236
 237 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 238 #B #f #b #l >commutative_plus //
 239 qed.
 240
 241 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 242 #B #f #b #l elim l -l normalize //
 243 qed.
 244
 245 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 246 #B #f #b #l1 elim l1 -l1 normalize //
 247 qed.
 248
 249 (* Trichotomy operator ******************************************************)
 250
 251 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 252 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 253   match n1 with
 254   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 255   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 256   ].
 257
 258 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 259 #A #a1 #a2 #a3 #n2 elim n2 -n2
 260 [ #n1 #H elim (lt_zero_false … H)
 261 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 262 ]
 263 qed.
 264
 265 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 266 #A #a1 #a2 #a3 #n elim n -n normalize //
 267 qed.
 268
 269 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 270 #A #a1 #a2 #a3 #n1 elim n1 -n1
 271 [ #n2 #H elim (lt_zero_false … H)
 272 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 273 ]
 274 qed.