matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "arithmetics/nat.ma".
  16 include "ground_2/lib/star.ma".
  17
  18 (* ARITHMETICAL PROPERTIES **************************************************)
  19
  20 (* Iota equations ***********************************************************)
  21
  22 lemma pred_O: pred 0 = 0.
  23 normalize // qed.
  24
  25 lemma pred_S: ∀m. pred (S m) = m.
  26 // qed.
  27
  28 (* Equations ****************************************************************)
  29
  30 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  31 // qed-.
  32
  33 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  34 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  35 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  36 qed-.
  37
  38 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  39 /2 width=1 by plus_minus_minus_be/ qed-.
  40
  41 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  42 // qed.
  43
  44 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  45 /2 by plus_minus/ qed.
  46
  47 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  48 /2 by plus_minus/ qed.
  49
  50 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  51 // qed.
  52
  53 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  54 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  55 qed.
  56
  57 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  58 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  59 qed.
  60
  61 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  62 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  63
  64 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  65                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  66 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  67 qed.
  68
  69 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  70 /2 width=1 by plus_minus/ qed-.
  71
  72 (* Properties ***************************************************************)
  73
  74 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  75 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
  76 [1,4: @or_intror #H destruct
  77 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
  78 | /2 width=1 by or_introl/
  79 ]
  80 qed-.
  81
  82 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  83 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
  84 #H elim H -m /2 width=1 by or3_intro1/
  85 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
  86 qed-.
  87
  88 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
  89 // qed-.
  90
  91 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
  92 // qed-.
  93
  94 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
  95 /3 width=1 by monotonic_le_minus_l/ qed.
  96
  97 (* Note: this might interfere with nat.ma *)
  98 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
  99 #m #n #Hmn #Hm whd >(S_pred … Hm)
 100 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 101 qed.
 102
 103 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 104 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 105
 106 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 107 #z #x #y #n #Hzx #Hxny
 108 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 109 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 110 /2 width=1 by monotonic_le_minus_l2/
 111 qed.
 112
 113 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 114 #z #x #y #n #Hzx #Hyxn
 115 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 116 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 117 /2 width=1 by monotonic_le_minus_l2/
 118 qed.
 119
 120 (* Inversion & forward lemmas ***********************************************)
 121
 122 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 123 // qed-.
 124
 125 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 126 /2 width=1 by monotonic_pred/ qed-.
 127
 128 lemma lt_refl_false: ∀n. n < n → ⊥.
 129 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 130 qed-.
 131
 132 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 133 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 134 qed-.
 135
 136 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 137 * // normalize #m #H elim (lt_refl_false m) //
 138 qed-.
 139
 140 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 141 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 142 qed-.
 143
 144 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 145 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 146 #H elim (le_plus_xSy_O_false … H)
 147 qed-.
 148
 149 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 150 /2 width=4 by le_plus_xySz_x_false/ qed-.
 151
 152 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 153 /2 width=4 by plus_xySz_x_false/ qed-.
 154
 155 (* Note this should go in nat.ma *)
 156 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 157 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 158 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 159 #y #_ >minus_plus_plus_l
 160 #H lapply (discr_plus_xy_minus_xz … H) -H
 161 #H destruct
 162 qed-.
 163
 164 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 165 * /2 width=1 by conj/ #x #y normalize #H destruct
 166 qed-.
 167
 168 (* Iterators ****************************************************************)
 169
 170 (* Note: see also: lib/arithemetics/bigops.ma *)
 171 let rec iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 172   match n with
 173    [ O   ⇒ nil
 174    | S k ⇒ op (iter k B op nil)
 175    ].
 176
 177 interpretation "iterated function" 'exp op n = (iter n ? op).
 178
 179 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 180 // qed.
 181
 182 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 183 // qed.
 184
 185 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 186 #B #f #b #l >commutative_plus //
 187 qed.
 188
 189 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 190 #B #f #b #l elim l -l normalize //
 191 qed.
 192
 193 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 194 #B #f #b #l1 elim l1 -l1 normalize //
 195 qed.
 196
 197 (* Trichotomy operator ******************************************************)
 198
 199 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 200 let rec tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 201   match n1 with
 202   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 203   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 204   ].
 205
 206 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 207 #A #a1 #a2 #a3 #n2 elim n2 -n2
 208 [ #n1 #H elim (lt_zero_false … H)
 209 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 210 ]
 211 qed.
 212
 213 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 214 #A #a1 #a2 #a3 #n elim n -n normalize //
 215 qed.
 216
 217 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 218 #A #a1 #a2 #a3 #n1 elim n1 -n1
 219 [ #n2 #H elim (lt_zero_false … H)
 220 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 221 ]
 222 qed.