matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "arithmetics/nat.ma".
  16 include "ground_2/lib/star.ma".
  17
  18 (* ARITHMETICAL PROPERTIES **************************************************)
  19
  20 (* Equations ****************************************************************)
  21
  22 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  23 // qed.
  24
  25 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  26 /2 by plus_minus/ qed.
  27
  28 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  29 /2 by plus_minus/ qed.
  30
  31 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  32 // qed.
  33
  34 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  35 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  36 qed.
  37
  38 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  39 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1/
  40 qed.
  41
  42 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  43 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  44
  45 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  46                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  47 #a1 #a2 #b #c1 #H1 #H2 >plus_minus // /2 width=1/
  48 qed.
  49
  50 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  51 /2 width=1 by plus_minus/ qed-.
  52
  53 (* Properties ***************************************************************)
  54
  55 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
  56 // qed-.
  57
  58 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
  59 // qed-.
  60
  61 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
  62 /3 width=1 by monotonic_le_minus_l/ qed.
  63
  64 (* Note: this might interfere with nat.ma *)
  65 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
  66 #m #n #Hmn #Hm whd >(S_pred … Hm)
  67 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
  68 qed.
  69
  70 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
  71 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
  72
  73 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
  74 #z #x #y #n #Hzx #Hxny
  75 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
  76 >plus_minus [2: /2 width=1 by lt_to_le/ ]
  77 /2 width=1 by monotonic_le_minus_l2/
  78 qed.
  79
  80 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
  81 #z #x #y #n #Hzx #Hyxn
  82 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
  83 >plus_minus [2: /2 width=1 by lt_to_le/ ]
  84 /2 width=1 by monotonic_le_minus_l2/
  85 qed.
  86
  87 (* Inversion & forward lemmas ***********************************************)
  88
  89 axiom eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  90
  91 axiom lt_dec: ∀n1,n2. Decidable (n1 < n2).
  92
  93 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  94 #m #n elim (lt_or_ge m n) /2 width=1/
  95 #H elim H -m /2 width=1/
  96 #m #Hm * #H /2 width=1/ /3 width=1/
  97 qed-.
  98
  99 lemma lt_refl_false: ∀n. n < n → ⊥.
 100 #n #H elim (lt_to_not_eq … H) -H /2 width=1/
 101 qed-.
 102
 103 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 104 #n #H elim (lt_to_not_le … H) -H /2 width=1/
 105 qed-.
 106
 107 lemma false_lt_to_le: ∀x,y. (x < y → ⊥) → y ≤ x.
 108 #x #y #H elim (decidable_lt x y) /2 width=1/
 109 #Hxy elim (H Hxy)
 110 qed-.
 111
 112 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 113 * // normalize #m #H elim (lt_refl_false m) //
 114 qed-.
 115
 116 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 117 #y #z #x elim x -x
 118 [ #H lapply (le_n_O_to_eq … H) -H
 119   <plus_n_Sm #H destruct
 120 | /3 width=1 by le_S_S_to_le/
 121 ]
 122 qed-.
 123
 124 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 125 /2 width=4 by le_plus_xySz_x_false/ qed-.
 126
 127 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 128 /2 width=4 by plus_xySz_x_false/ qed-.
 129
 130 (* Iterators ****************************************************************)
 131
 132 (* Note: see also: lib/arithemetcs/bigops.ma *)
 133 let rec iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 134   match n with
 135    [ O   ⇒ nil
 136    | S k ⇒ op (iter k B op nil)
 137    ].
 138
 139 interpretation "iterated function" 'exp op n = (iter n ? op).
 140
 141 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 142 #B #f #b #l >commutative_plus //
 143 qed.
 144
 145 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 146 #B #f #b #l elim l -l normalize //
 147 qed.
 148
 149 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 150 #B #f #b #l1 elim l1 -l1 normalize //
 151 qed.
 152
 153 (* Trichotomy operator ******************************************************)
 154
 155 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 156 let rec tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 157   match n1 with
 158   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 159   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 160   ].
 161
 162 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 163 #A #a1 #a2 #a3 #n2 elim n2 -n2
 164 [ #n1 #H elim (lt_zero_false … H)
 165 | #n2 #IH #n1 elim n1 -n1 // /3 width=1/
 166 ]
 167 qed.
 168
 169 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 170 #A #a1 #a2 #a3 #n elim n -n normalize //
 171 qed.
 172
 173 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 174 #A #a1 #a2 #a3 #n1 elim n1 -n1
 175 [ #n2 #H elim (lt_zero_false … H)
 176 | #n1 #IH #n2 elim n2 -n2 // /3 width=1/
 177 ]
 178 qed.