matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/successor_1.ma".
  16 include "ground_2/notation/functions/predecessor_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'Successor m = (S m).
  23
  24 interpretation "nat predecessor" 'Predecessor m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ⫯(x+y) = (⫯x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ⫯(n1∨n2) = (⫯n1 ∨ ⫯n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equations ****************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ⫯n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  61 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  62 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  63 qed-.
  64
  65 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  66 /2 width=1 by plus_minus_minus_be/ qed-.
  67
  68 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  69 // qed.
  70
  71 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  72 /2 by plus_minus/ qed.
  73
  74 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  75 /2 by plus_minus/ qed.
  76
  77 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  78 // qed.
  79
  80 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  81 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  82 qed.
  83
  84 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  85 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  86 qed.
  87
  88 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  89 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  90
  91 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  92                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  93 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  94 qed.
  95
  96 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  97 /2 width=1 by plus_minus/ qed-.
  98
  99 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 100 #n normalize >le_to_leb_true //
 101 qed.
 102
 103 lemma associative_max: associative … max.
 104 #x #y #z normalize
 105 @(leb_elim x y) normalize #Hxy
 106 @(leb_elim y z) normalize #Hyz //
 107 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 108 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 109   >not_le_to_leb_false //
 110 ]
 111 qed.
 112
 113 (* Properties ***************************************************************)
 114
 115 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 116 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 117 [1,4: @or_intror #H destruct
 118 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 119 | /2 width=1 by or_introl/
 120 ]
 121 qed-.
 122
 123 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 124 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 125 #H elim H -m /2 width=1 by or3_intro1/
 126 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 127 qed-.
 128
 129 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
 130 // qed-.
 131
 132 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
 133 // qed-.
 134
 135 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 136 /3 width=1 by monotonic_le_minus_l/ qed.
 137
 138 (* Note: this might interfere with nat.ma *)
 139 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
 140 #m #n #Hmn #Hm whd >(S_pred … Hm)
 141 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 142 qed.
 143
 144 lemma lt_S_S: ∀x,y. x < y → ⫯x < ⫯y.
 145 /2 width=1 by le_S_S/ qed.
 146
 147 lemma lt_S: ∀n,m. n < m → n < ⫯m.
 148 /2 width=1 by le_S/ qed.
 149
 150 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (⫯n1 ∨ n2) ≤ ⫯n.
 151 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 152
 153 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ⫯n2) ≤ ⫯n.
 154 /2 width=1 by max_S1_le_S/ qed-.
 155
 156 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
 157 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
 158
 159 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
 160 #z #x #y #n #Hzx #Hxny
 161 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 162 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 163 /2 width=1 by monotonic_le_minus_l2/
 164 qed.
 165
 166 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 167 #z #x #y #n #Hzx #Hyxn
 168 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 169 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 170 /2 width=1 by monotonic_le_minus_l2/
 171 qed.
 172
 173 (* Inversion & forward lemmas ***********************************************)
 174
 175 lemma nat_split: ∀x. x = 0 ∨ ∃y. ⫯y = x.
 176 * /3 width=2 by ex_intro, or_introl, or_intror/
 177 qed-.
 178
 179 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 180 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 181 qed-.
 182
 183 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 184 /2 width=1 by plus_le_0/ qed-.
 185
 186 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 187 // qed-.
 188
 189 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 190 /2 width=2 by le_plus_minus_comm/ qed-.
 191
 192 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 193 /2 width=1 by monotonic_pred/ qed-.
 194
 195 lemma lt_refl_false: ∀n. n < n → ⊥.
 196 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 197 qed-.
 198
 199 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 200 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 201 qed-.
 202
 203 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 204 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 205
 206 lemma succ_inv_refl_sn: ∀x. ⫯x = x → ⊥.
 207 #x #H @(lt_le_false x (⫯x)) //
 208 qed-.
 209
 210 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ⫯m = n.
 211 * /2 width=2 by ex_intro/
 212 #H cases (lt_le_false … H) -H //
 213 qed-.
 214
 215 lemma lt_inv_S1: ∀m,n. ⫯m < n → ∃∃p. m < p & ⫯p = n.
 216 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 217 #H cases (lt_le_false … H) -H //
 218 qed-.
 219
 220 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ⫯z = y.
 221 * /3 width=3 by le_S_S_to_le, ex2_intro/
 222 #x #H elim (lt_le_false … H) -H //
 223 qed-.
 224
 225 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 226 * // normalize #m #H elim (lt_refl_false m) //
 227 qed-.
 228
 229 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 230 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 231 qed-.
 232
 233 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 234 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 235 #H elim (le_plus_xSy_O_false … H)
 236 qed-.
 237
 238 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 239 /2 width=4 by le_plus_xySz_x_false/ qed-.
 240
 241 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 242 /2 width=4 by plus_xySz_x_false/ qed-.
 243
 244 (* Note this should go in nat.ma *)
 245 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 246 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 247 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 248 #y #_ >minus_plus_plus_l
 249 #H lapply (discr_plus_xy_minus_xz … H) -H
 250 #H destruct
 251 qed-.
 252
 253 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 254 * /2 width=1 by conj/ #x #y normalize #H destruct
 255 qed-.
 256
 257 lemma lt_S_S_to_lt: ∀x,y. ⫯x < ⫯y → x < y.
 258 /2 width=1 by le_S_S_to_le/ qed-.
 259
 260 lemma lt_elim: ∀R:relation nat.
 261                (∀n2. R O (⫯n2)) →
 262                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 263                ∀n2,n1. n1 < n2 → R n1 n2.
 264 #R #IH1 #IH2 #n2 elim n2 -n2
 265 [ #n1 #H elim (lt_le_false … H) -H //
 266 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 267 ]
 268 qed-.
 269
 270 lemma le_elim: ∀R:relation nat.
 271                (∀n2. R O (n2)) →
 272                (∀n1,n2. R n1 n2 → R (⫯n1) (⫯n2)) →
 273                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 274 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 275 /4 width=1 by monotonic_pred/ -IH1 -IH2
 276 #n1 #H elim (lt_le_false … H) -H //
 277 qed-.
 278
 279 (* Iterators ****************************************************************)
 280
 281 (* Note: see also: lib/arithemetics/bigops.ma *)
 282 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 283   match n with
 284    [ O   ⇒ nil
 285    | S k ⇒ op (iter k B op nil)
 286    ].
 287
 288 interpretation "iterated function" 'exp op n = (iter n ? op).
 289
 290 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 291 // qed.
 292
 293 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 294 // qed.
 295
 296 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 297 #B #f #b #l >commutative_plus //
 298 qed.
 299
 300 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 301 #B #f #b #l elim l -l normalize //
 302 qed.
 303
 304 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 305 #B #f #b #l1 elim l1 -l1 normalize //
 306 qed.
 307
 308 (* Trichotomy operator ******************************************************)
 309
 310 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 311 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 312   match n1 with
 313   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 314   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 315   ].
 316
 317 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 318 #A #a1 #a2 #a3 #n2 elim n2 -n2
 319 [ #n1 #H elim (lt_zero_false … H)
 320 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 321 ]
 322 qed.
 323
 324 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 325 #A #a1 #a2 #a3 #n elim n -n normalize //
 326 qed.
 327
 328 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 329 #A #a1 #a2 #a3 #n1 elim n1 -n1
 330 [ #n2 #H elim (lt_zero_false … H)
 331 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 332 ]
 333 qed.