matita/matita/contribs/lambdadelta/ground_2/lib/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/relations.ma".
  16 include "ground_2/lib/logic.ma".
  17
  18 (* GENERIC RELATIONS ********************************************************)
  19
  20 lemma insert_eq: ∀A,a. ∀Q1,Q2:predicate A. (∀a0. Q1 a0 → a = a0 → Q2 a0) → Q1 a → Q2 a.
  21 /2 width=1 by/ qed-.
  22
  23 definition replace_2 (A) (B): relation3 (relation2 A B) (relation A) (relation B) ≝
  24                               λR,Sa,Sb. ∀a1,b1. R a1 b1 → ∀a2. Sa a1 a2 → ∀b2. Sb b1 b2 → R a2 b2.
  25
  26 (* Inclusion ****************************************************************)
  27
  28 definition subR2 (S1) (S2): relation (relation2 S1 S2) ≝
  29            λR1,R2. (∀a1,a2. R1 a1 a2 → R2 a1 a2).
  30
  31 interpretation "2-relation inclusion"
  32    'subseteq R1 R2 = (subR2 ?? R1 R2).
  33
  34 definition subR3 (S1) (S2) (S3): relation (relation3 S1 S2 S3) ≝
  35            λR1,R2. (∀a1,a2,a3. R1 a1 a2 a3 → R2 a1 a2 a3).
  36
  37 interpretation "3-relation inclusion"
  38    'subseteq R1 R2 = (subR3 ??? R1 R2).
  39
  40 (* Properties of relations **************************************************)
  41
  42 definition relation5: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0]
  43 ≝ λA,B,C,D,E.A→B→C→D→E→Prop.
  44
  45 definition relation6: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0]
  46 ≝ λA,B,C,D,E,F.A→B→C→D→E→F→Prop.
  47
  48 (**) (* we dont use "∀a. reflexive … (R a)" since auto seems to dislike repeatd δ-expansion *)
  49 definition c_reflexive (A) (B): predicate (relation3 A B B) ≝
  50                                 λR. ∀a,b. R a b b.
  51
  52 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  53
  54 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  55                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  56
  57 definition left_cancellable: ∀A. ∀R: relation A. Prop ≝ λA,R.
  58                              ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 → R a1 a2.
  59
  60 definition right_cancellable: ∀A. ∀R: relation A. Prop ≝ λA,R.
  61                               ∀a1,a0. R a1 a0 → ∀a2. R a2 a0 → R a1 a2.
  62
  63 definition pw_confluent2: ∀A. relation A → relation A → predicate A ≝ λA,R1,R2,a0.
  64                           ∀a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  65                           ∃∃a. R2 a1 a & R1 a2 a.
  66
  67 definition confluent2: ∀A. relation (relation A) ≝ λA,R1,R2.
  68                        ∀a0. pw_confluent2 A R1 R2 a0.
  69
  70 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  71                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  72                         ∃∃a. R2 a1 a & R1 a a2.
  73
  74 definition bi_confluent: ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
  75                          ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  76                          ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  77
  78 definition lsub_trans: ∀A,B. relation2 (A→relation B) (relation A) ≝ λA,B,R1,R2.
  79                        ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → R1 L1 T1 T2.
  80
  81 definition s_r_confluent1: ∀A,B. relation2 (A→relation B) (B→relation A) ≝ λA,B,R1,R2.
  82                            ∀L1,T1,T2. R1 L1 T1 T2 → ∀L2. R2 T1 L1 L2 → R2 T2 L1 L2.
  83
  84 definition is_mono: ∀B:Type[0]. predicate (predicate B) ≝
  85                     λB,R. ∀b1. R b1 → ∀b2. R b2 → b1 = b2.
  86
  87 definition is_inj2: ∀A,B:Type[0]. predicate (relation2 A B) ≝
  88                     λA,B,R. ∀a1,b. R a1 b → ∀a2. R a2 b → a1 = a2.
  89
  90 (* Normal form and strong normalization *************************************)
  91
  92 definition NF: ∀A. relation A → relation A → predicate A ≝
  93    λA,R,S,a1. ∀a2. R a1 a2 → S a1 a2.
  94
  95 definition NF_dec: ∀A. relation A → relation A → Prop ≝
  96                    λA,R,S. ∀a1. NF A R S a1 ∨
  97                    ∃∃a2. R … a1 a2 & (S a1 a2 → ⊥).
  98
  99 inductive SN (A) (R,S:relation A): predicate A ≝
 100 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a1 a2 → ⊥) → SN A R S a2) → SN A R S a1
 101 .
 102
 103 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 104 #A #R #S #a1 #Ha1
 105 @SN_intro #a2 #HRa12 #HSa12
 106 elim HSa12 -HSa12 /2 width=1 by/
 107 qed.
 108
 109 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 110    λA,R,S,a2. ∀a1. R a1 a2 → S a1 a2.
 111
 112 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 113 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a1 a2 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 114 .
 115
 116 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 117 #A #R #S #a2 #Ha2
 118 @SN_sn_intro #a1 #HRa12 #HSa12
 119 elim HSa12 -HSa12 /2 width=1 by/
 120 qed.
 121
 122 (* Relations on unboxed triples *********************************************)
 123
 124 definition tri_RC: ∀A,B,C. tri_relation A B C → tri_relation A B C ≝
 125                    λA,B,C,R,a1,b1,c1,a2,b2,c2. R … a1 b1 c1 a2 b2 c2 ∨
 126                    ∧∧ a1 = a2 & b1 = b2 & c1 = c2.
 127
 128 lemma tri_RC_reflexive: ∀A,B,C,R. tri_reflexive A B C (tri_RC … R).
 129 /3 width=1 by and3_intro, or_intror/ qed.