matita/matita/contribs/lambdadelta/ground_2/lib/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/relations.ma".
  16 include "ground_2/lib/logic.ma".
  17
  18 (* GENERIC RELATIONS ********************************************************)
  19
  20 definition replace_2 (A) (B): relation3 (relation2 A B) (relation A) (relation B) ≝
  21            λR,Sa,Sb. ∀a1,b1. R a1 b1 → ∀a2. Sa a1 a2 → ∀b2. Sb b1 b2 → R a2 b2.
  22
  23 (* Inclusion ****************************************************************)
  24
  25 definition subR2 (S1) (S2): relation (relation2 S1 S2) ≝
  26            λR1,R2. (∀a1,a2. R1 a1 a2 → R2 a1 a2).
  27
  28 interpretation "2-relation inclusion"
  29    'subseteq R1 R2 = (subR2 ?? R1 R2).
  30
  31 definition subR3 (S1) (S2) (S3): relation (relation3 S1 S2 S3) ≝
  32            λR1,R2. (∀a1,a2,a3. R1 a1 a2 a3 → R2 a1 a2 a3).
  33
  34 interpretation "3-relation inclusion"
  35    'subseteq R1 R2 = (subR3 ??? R1 R2).
  36
  37 (* Properties of relations **************************************************)
  38
  39 definition relation5: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  40            λA,B,C,D,E.A→B→C→D→E→Prop.
  41
  42 definition relation6: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  43            λA,B,C,D,E,F.A→B→C→D→E→F→Prop.
  44
  45 (**) (* we don't use "∀a. reflexive … (R a)" since auto seems to dislike repeatd δ-expansion *)
  46 definition c_reflexive (A) (B): predicate (relation3 A B B) ≝
  47            λR. ∀a,b. R a b b.
  48
  49 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  50
  51 definition Transitive (A) (R:relation A): Prop ≝
  52            ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  53
  54 definition left_cancellable (A) (R:relation A): Prop ≝
  55            ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 → R a1 a2.
  56
  57 definition right_cancellable (A) (R:relation A): Prop ≝
  58            ∀a1,a0. R a1 a0 → ∀a2. R a2 a0 → R a1 a2.
  59
  60 definition pw_confluent2 (A) (R1,R2:relation A): predicate A ≝
  61            λa0.
  62            ∀a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  63            ∃∃a. R2 a1 a & R1 a2 a.
  64
  65 definition confluent2 (A): relation (relation A) ≝
  66            λR1,R2.
  67            ∀a0. pw_confluent2 A R1 R2 a0.
  68
  69 definition transitive2 (A) (R1,R2:relation A): Prop ≝
  70            ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  71            ∃∃a. R2 a1 a & R1 a a2.
  72
  73 definition bi_confluent (A) (B) (R: bi_relation A B): Prop ≝
  74            ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  75            ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  76
  77 definition lsub_trans (A) (B): relation2 (A→relation B) (relation A) ≝
  78            λR1,R2.
  79            ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → R1 L1 T1 T2.
  80
  81 definition s_r_confluent1 (A) (B): relation2 (A→relation B) (B→relation A) ≝
  82            λR1,R2.
  83            ∀L1,T1,T2. R1 L1 T1 T2 → ∀L2. R2 T1 L1 L2 → R2 T2 L1 L2.
  84
  85 definition is_mono (B:Type[0]): predicate (predicate B) ≝
  86            λR. ∀b1. R b1 → ∀b2. R b2 → b1 = b2.
  87
  88 definition is_inj2 (A,B:Type[0]): predicate (relation2 A B) ≝
  89            λR. ∀a1,b. R a1 b → ∀a2. R a2 b → a1 = a2.
  90
  91 (* Main properties of equality **********************************************)
  92
  93 theorem canc_sn_eq (A): left_cancellable A (eq …).
  94 // qed-.
  95
  96 theorem canc_dx_eq (A): right_cancellable A (eq …).
  97 // qed-.
  98
  99 (* Normal form and strong normalization *************************************)
 100
 101 definition NF (A): relation A → relation A → predicate A ≝
 102            λR,S,a1. ∀a2. R a1 a2 → S a1 a2.
 103
 104 definition NF_dec (A): relation A → relation A → Prop ≝
 105            λR,S. ∀a1. NF A R S a1 ∨
 106            ∃∃a2. R … a1 a2 & (S a1 a2 → ⊥).
 107
 108 inductive SN (A) (R,S:relation A): predicate A ≝
 109 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a1 a2 → ⊥) → SN A R S a2) → SN A R S a1
 110 .
 111
 112 lemma NF_to_SN (A) (R) (S): ∀a. NF A R S a → SN A R S a.
 113 #A #R #S #a1 #Ha1
 114 @SN_intro #a2 #HRa12 #HSa12
 115 elim HSa12 -HSa12 /2 width=1 by/
 116 qed.
 117
 118 definition NF_sn (A): relation A → relation A → predicate A ≝
 119    λR,S,a2. ∀a1. R a1 a2 → S a1 a2.
 120
 121 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 122 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a1 a2 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 123 .
 124
 125 lemma NF_to_SN_sn (A) (R) (S): ∀a. NF_sn A R S a → SN_sn A R S a.
 126 #A #R #S #a2 #Ha2
 127 @SN_sn_intro #a1 #HRa12 #HSa12
 128 elim HSa12 -HSa12 /2 width=1 by/
 129 qed.
 130
 131 (* Relations on unboxed triples *********************************************)
 132
 133 definition tri_RC (A,B,C): tri_relation A B C → tri_relation A B C ≝
 134            λR,a1,b1,c1,a2,b2,c2.
 135            ∨∨ R … a1 b1 c1 a2 b2 c2
 136             | ∧∧ a1 = a2 & b1 = b2 & c1 = c2.
 137
 138 lemma tri_RC_reflexive (A) (B) (C): ∀R. tri_reflexive A B C (tri_RC … R).
 139 /3 width=1 by and3_intro, or_intror/ qed.