matita/matita/contribs/lambdadelta/ground_2/lib/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/relations.ma".
  16 include "ground_2/xoa/xoa_props.ma".
  17
  18 (* GENERIC RELATIONS ********************************************************)
  19
  20 (* PROPERTIES OF RELATIONS **************************************************)
  21
  22 definition relation5 : Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0]
  23 ≝ λA,B,C,D,E.A→B→C→D→E→Prop.
  24
  25 definition relation6 : Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0]
  26 ≝ λA,B,C,D,E,F.A→B→C→D→E→F→Prop.
  27
  28 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  29
  30 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  31                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  32
  33 definition left_cancellable: ∀A. ∀R: relation A. Prop ≝ λA,R.
  34                              ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 → R a1 a2.
  35
  36 definition right_cancellable: ∀A. ∀R: relation A. Prop ≝ λA,R.
  37                               ∀a1,a0. R a1 a0 → ∀a2. R a2 a0 → R a1 a2.
  38
  39 definition pw_confluent2: ∀A. relation A → relation A → predicate A ≝ λA,R1,R2,a0.
  40                           ∀a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  41                           ∃∃a. R2 a1 a & R1 a2 a.
  42
  43 definition confluent2: ∀A. relation (relation A) ≝ λA,R1,R2.
  44                        ∀a0. pw_confluent2 A R1 R2 a0.
  45
  46 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  47                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  48                         ∃∃a. R2 a1 a & R1 a a2.
  49
  50 definition bi_confluent:  ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
  51                           ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  52                           ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  53
  54 definition lsub_trans: ∀A,B. relation2 (A→relation B) (relation A) ≝ λA,B,R1,R2.
  55                        ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → R1 L1 T1 T2.
  56
  57 definition s_r_confluent1: ∀A,B. relation2 (A→relation B) (B→relation A) ≝ λA,B,R1,R2.
  58                            ∀L1,T1,T2. R1 L1 T1 T2 → ∀L2. R2 T1 L1 L2 → R2 T2 L1 L2.
  59
  60 definition is_mono: ∀B:Type[0]. predicate (predicate B) ≝
  61                     λB,R. ∀b1. R b1 → ∀b2. R b2 → b1 = b2.
  62
  63 definition is_inj2: ∀A,B:Type[0]. predicate (relation2 A B) ≝
  64                     λA,B,R. ∀a1,b. R a1 b → ∀a2. R a2 b → a1 = a2.
  65
  66 (* Normal form and strong normalization *************************************)
  67
  68 definition NF: ∀A. relation A → relation A → predicate A ≝
  69    λA,R,S,a1. ∀a2. R a1 a2 → S a1 a2.
  70
  71 definition NF_dec: ∀A. relation A → relation A → Prop ≝
  72                    λA,R,S. ∀a1. NF A R S a1 ∨
  73                    ∃∃a2. R … a1 a2 & (S a1 a2 → ⊥).
  74
  75 inductive SN (A) (R,S:relation A): predicate A ≝
  76 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a1 a2 → ⊥) → SN A R S a2) → SN A R S a1
  77 .
  78
  79 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
  80 #A #R #S #a1 #Ha1
  81 @SN_intro #a2 #HRa12 #HSa12
  82 elim HSa12 -HSa12 /2 width=1 by/
  83 qed.
  84
  85 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
  86    λA,R,S,a2. ∀a1. R a1 a2 → S a1 a2.
  87
  88 inductive SN_sn (A) (R,S:relation A): predicate A ≝
  89 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a1 a2 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
  90 .
  91
  92 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
  93 #A #R #S #a2 #Ha2
  94 @SN_sn_intro #a1 #HRa12 #HSa12
  95 elim HSa12 -HSa12 /2 width=1 by/
  96 qed.
  97
  98 (* Relations on unboxed triples *********************************************)
  99
 100 definition tri_RC: ∀A,B,C. tri_relation A B C → tri_relation A B C ≝
 101                    λA,B,C,R,a1,b1,c1,a2,b2,c2. R … a1 b1 c1 a2 b2 c2 ∨
 102                    ∧∧ a1 = a2 & b1 = b2 & c1 = c2.
 103
 104 lemma tri_RC_reflexive: ∀A,B,C,R. tri_reflexive A B C (tri_RC … R).
 105 /3 width=1 by and3_intro, or_intror/ qed.