matita/matita/contribs/lambdadelta/ground_2/relocation/nstream_at.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.tcs.unibo.it                            *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/apply_2.ma".
  16 include "ground_2/notation/relations/rat_3.ma".
  17 include "ground_2/relocation/nstream.ma".
  18
  19 (* RELOCATION N-STREAM ******************************************************)
  20
  21 let rec apply (i: nat) on i: nstream → nat ≝ ?.
  22 * #b #t cases i -i
  23 [ @b
  24 | #i lapply (apply i t) -apply -i -t
  25   #i @(⫯(b+i))
  26 ]
  27 qed.
  28
  29 interpretation "functional application (nstream)"
  30    'Apply t i = (apply i t).
  31
  32 inductive at: nstream → relation nat ≝
  33 | at_zero: ∀t. at (0 @ t) 0 0
  34 | at_skip: ∀t,i1,i2. at t i1 i2 → at (0 @ t) (⫯i1) (⫯i2)
  35 | at_lift: ∀t,b,i1,i2. at (b @ t) i1 i2 → at (⫯b @ t) i1 (⫯i2)
  36 .
  37
  38 interpretation "relational application (nstream)"
  39    'RAt i1 t i2 = (at t i1 i2).
  40
  41 (* Basic properties on apply ************************************************)
  42
  43 lemma apply_S1: ∀t,a,i. (⫯a@t)@❴i❵ = ⫯((a@t)@❴i❵).
  44 #a #t * //
  45 qed.
  46
  47 (* Basic inversion lemmas on at *********************************************)
  48
  49 fact at_inv_xOx_aux: ∀t,i1,i2. @⦃i1, t⦄ ≡ i2 → ∀u. t = 0 @ u →
  50                     (i1 = 0 ∧ i2 = 0) ∨
  51                     ∃∃j1,j2. @⦃j1, u⦄ ≡ j2 & i1 = ⫯j1 & i2 = ⫯j2.
  52 #t #i1 #i2 * -t -i1 -i2
  53 [ /3 width=1 by or_introl, conj/
  54 | #t #i1 #i2 #Hi #u #H destruct /3 width=5 by ex3_2_intro, or_intror/
  55 | #t #b #i1 #i2 #_ #u #H destruct
  56 ]
  57 qed-.
  58
  59 lemma at_inv_xOx: ∀t,i1,i2. @⦃i1, 0 @ t⦄ ≡ i2 →
  60                  (i1 = 0 ∧ i2 = 0) ∨
  61                  ∃∃j1,j2. @⦃j1, t⦄ ≡ j2 & i1 = ⫯j1 & i2 = ⫯j2.
  62 /2 width=3 by at_inv_xOx_aux/ qed-.
  63
  64 lemma at_inv_OOx: ∀t,i. @⦃0, 0 @ t⦄ ≡ i → i = 0.
  65 #t #i #H elim (at_inv_xOx … H) -H * //
  66 #j1 #j2 #_ #H destruct
  67 qed-.
  68
  69 lemma at_inv_xOO: ∀t,i. @⦃i, 0 @ t⦄ ≡ 0 → i = 0.
  70 #t #i #H elim (at_inv_xOx … H) -H * //
  71 #j1 #j2 #_ #_ #H destruct
  72 qed-.
  73
  74 lemma at_inv_SOx: ∀t,i1,i2. @⦃⫯i1, 0 @ t⦄ ≡ i2 →
  75                   ∃∃j2. @⦃i1, t⦄ ≡ j2 & i2 = ⫯j2.
  76 #t #i1 #i2 #H elim (at_inv_xOx … H) -H *
  77 [ #H destruct
  78 | #j1 #j2 #Hj #H1 #H2 destruct /2 width=3 by ex2_intro/
  79 ]
  80 qed-.
  81
  82 lemma at_inv_xOS: ∀t,i1,i2. @⦃i1, 0 @ t⦄ ≡ ⫯i2 →
  83                   ∃∃j1. @⦃j1, t⦄ ≡ i2 & i1 = ⫯j1.
  84 #t #i1 #i2 #H elim (at_inv_xOx … H) -H *
  85 [ #_ #H destruct
  86 | #j1 #j2 #Hj #H1 #H2 destruct /2 width=3 by ex2_intro/
  87 ]
  88 qed-.
  89
  90 lemma at_inv_SOS: ∀t,i1,i2. @⦃⫯i1, 0 @ t⦄ ≡ ⫯i2 → @⦃i1, t⦄ ≡ i2.
  91 #t #i1 #i2 #H elim (at_inv_xOx … H) -H *
  92 [ #H destruct
  93 | #j1 #j2 #Hj #H1 #H2 destruct //
  94 ]
  95 qed-.
  96
  97 lemma at_inv_OOS: ∀t,i. @⦃0, 0 @ t⦄ ≡ ⫯i → ⊥.
  98 #t #i #H elim (at_inv_xOx … H) -H *
  99 [ #_ #H destruct
 100 | #j1 #j2 #_ #H destruct
 101 ]
 102 qed-.
 103
 104 lemma at_inv_SOO: ∀t,i. @⦃⫯i, 0 @ t⦄ ≡ 0 → ⊥.
 105 #t #i #H elim (at_inv_xOx … H) -H *
 106 [ #H destruct
 107 | #j1 #j2 #_ #_ #H destruct
 108 ]
 109 qed-.
 110
 111 fact at_inv_xSx_aux: ∀t,i1,i2. @⦃i1, t⦄ ≡ i2 → ∀u,a. t = ⫯a @ u →
 112                      ∃∃j2. @⦃i1, a@u⦄ ≡ j2 & i2 = ⫯j2.
 113 #t #i1 #i2 * -t -i1 -i2
 114 [ #t #u #a #H destruct
 115 | #t #i1 #i2 #_ #u #a #H destruct
 116 | #t #b #i1 #i2 #Hi #u #a #H destruct /2 width=3 by ex2_intro/
 117 ]
 118 qed-.
 119
 120 lemma at_inv_xSx: ∀t,b,i1,i2. @⦃i1, ⫯b @ t⦄ ≡ i2 →
 121                   ∃∃j2. @⦃i1, b @ t⦄ ≡ j2 & i2 = ⫯j2.
 122 /2 width=3 by at_inv_xSx_aux/ qed-.
 123
 124 lemma at_inv_xSS: ∀t,b,i1,i2. @⦃i1, ⫯b @ t⦄ ≡ ⫯i2 → @⦃i1, b@t⦄ ≡ i2.
 125 #t #b #i1 #i2 #H elim (at_inv_xSx … H) -H
 126 #j2 #Hj #H destruct //
 127 qed-.
 128
 129 lemma at_inv_xSO: ∀t,b,i. @⦃i, ⫯b @ t⦄ ≡ 0 → ⊥.
 130 #t #b #i #H elim (at_inv_xSx … H) -H
 131 #j2 #_ #H destruct
 132 qed-.
 133
 134 (* alternative definition ***************************************************)
 135
 136 lemma at_O1: ∀b,t. @⦃0, b @ t⦄ ≡ b.
 137 #b elim b -b /2 width=1 by at_lift/
 138 qed.
 139
 140 lemma at_S1: ∀b,t,i1,i2. @⦃i1, t⦄ ≡ i2 → @⦃⫯i1, b@t⦄ ≡ ⫯(b+i2).
 141 #b elim b -b /3 width=1 by at_skip, at_lift/
 142 qed.
 143
 144 lemma at_inv_O1: ∀t,b,i2. @⦃0, b@t⦄ ≡ i2 → i2 = b.
 145 #t #b elim b -b /2 width=2 by at_inv_OOx/
 146 #b #IH #i2 #H elim (at_inv_xSx … H) -H
 147 #j2 #Hj #H destruct /3 width=1 by eq_f/
 148 qed-.
 149
 150 lemma at_inv_S1: ∀t,b,j1,i2. @⦃⫯j1, b@t⦄ ≡ i2 → ∃∃j2. @⦃j1, t⦄ ≡ j2 & i2 =⫯(b+j2).
 151 #t #b elim b -b /2 width=1 by at_inv_SOx/
 152 #b #IH #j1 #i2 #H elim (at_inv_xSx … H) -H
 153 #j2 #Hj #H destruct elim (IH … Hj) -IH -Hj
 154 #i2 #Hi #H destruct /2 width=3 by ex2_intro/
 155 qed-.
 156
 157 lemma at_total: ∀i,t. @⦃i, t⦄ ≡ t@❴i❵.
 158 #i elim i -i
 159 [ * // | #i #IH * /3 width=1 by at_S1/ ]
 160 qed.
 161
 162 (* Advanced forward lemmas on at ********************************************)
 163
 164 lemma at_increasing: ∀t,i1,i2. @⦃i1, t⦄ ≡ i2 → i1 ≤ i2.
 165 #t #i1 #i2 #H elim H -t -i1 -i2 /2 width=1 by le_S_S, le_S/
 166 qed-.
 167
 168 lemma at_increasing_plus: ∀t,b,i1,i2. @⦃i1, b@t⦄ ≡ i2 → i1 + b ≤ i2.
 169 #t #b *
 170 [ #i2 #H >(at_inv_O1 … H) -i2 //
 171 | #i1 #i2 #H elim (at_inv_S1 … H) -H
 172   #j1 #Ht #H destruct
 173   /4 width=2 by at_increasing, monotonic_le_plus_r, le_S_S/
 174 ]
 175 qed-.
 176
 177 lemma at_increasing_strict: ∀t,b,i1,i2. @⦃i1, ⫯b @ t⦄ ≡ i2 →
 178                             i1 < i2 ∧ @⦃i1, b@t⦄ ≡ ⫰i2.
 179 #t #b #i1 #i2 #H elim (at_inv_xSx … H) -H
 180 #j2 #Hj #H destruct /4 width=2 by conj, at_increasing, le_S_S/
 181 qed-.
 182
 183 (* Main properties on at ****************************************************)
 184
 185 let corec at_ext: ∀t1,t2. (∀i,i1,i2. @⦃i, t1⦄ ≡ i1 → @⦃i, t2⦄ ≡ i2 → i1 = i2) → t1 ≐ t2 ≝ ?.
 186 * #b1 #t1 * #b2 #t2 #Hi lapply (Hi 0 b1 b2 ? ?) //
 187 #H lapply (at_ext t1 t2 ?) /2 width=1 by eq_sec/ -at_ext
 188 #j #j1 #j2 #H1 #H2 @(injective_plus_r … b2) /4 width=5 by at_S1, injective_S/ (**) (* full auto fails *)
 189 qed-.
 190
 191 theorem at_monotonic: ∀i1,i2. i1 < i2 → ∀t,j1,j2. @⦃i1, t⦄ ≡ j1 → @⦃i2, t⦄ ≡ j2 → j1 < j2.
 192 #i1 #i2 #H @(lt_elim … H) -i1 -i2
 193 [ #i2 *#b #t #j1 #j2 #H1 #H2 >(at_inv_O1 … H1) elim (at_inv_S1 … H2) -H2 -j1 //
 194 | #i1 #i2 #IH * #b #t #j1 #j2 #H1 #H2 elim (at_inv_S1 … H2) elim (at_inv_S1 … H1) -H1 -H2
 195   #x1 #Hx1 #H1 #x2 #Hx2 #H2 destruct /4 width=3 by lt_S_S, monotonic_lt_plus_r/
 196 ]
 197 qed-.
 198
 199 theorem at_inv_monotonic: ∀t,i1,j1. @⦃i1, t⦄ ≡ j1 → ∀i2,j2. @⦃i2, t⦄ ≡ j2 → j2 < j1 → i2 < i1.
 200 #t #i1 #j1 #H elim H -t -i1 -j1
 201 [ #t #i2 #j2 #_ #H elim (lt_le_false … H) //
 202 | #t #i1 #j1 #_ #IH #i2 #j2 #H #Hj elim (at_inv_xOx … H) -H *
 203   [ #H1 #H2 destruct //
 204   | #x2 #y2 #Hxy #H1 #H2 destruct /4 width=3 by lt_S_S_to_lt, lt_S_S/
 205   ]
 206 | #t #b1 #i1 #j1 #_ #IH #i2 #j2 #H #Hj elim (at_inv_xSx … H) -H
 207   #y2 #Hy #H destruct /3 width=3 by lt_S_S_to_lt/
 208 ]
 209 qed-.
 210
 211 theorem at_mono: ∀t,i,i1. @⦃i, t⦄ ≡ i1 → ∀i2. @⦃i, t⦄ ≡ i2 → i2 = i1.
 212 #t #i #i1 #H1 #i2 #H2 elim (lt_or_eq_or_gt i2 i1) //
 213 #Hi elim (lt_le_false i i) /2 width=6 by at_inv_monotonic/
 214 qed-.
 215
 216 theorem at_inj: ∀t,i1,i. @⦃i1, t⦄ ≡ i → ∀i2. @⦃i2, t⦄ ≡ i → i1 = i2.
 217 #t #i1 #i #H1 #i2 #H2 elim (lt_or_eq_or_gt i2 i1) //
 218 #Hi elim (lt_le_false i i) /2 width=6 by at_monotonic/
 219 qed-.
 220
 221 (* Advanced properties on at ************************************************)
 222
 223 (* Note: see also: trace_at/at_dec *)
 224 lemma at_dec: ∀t,i1,i2. Decidable (@⦃i1, t⦄ ≡ i2).
 225 #t #i1 #i2 lapply (at_total i1 t)
 226 #Ht elim (eq_nat_dec i2 (t@❴i1❵))
 227 [ #H destruct /2 width=1 by or_introl/
 228 | /4 width=4 by at_mono, or_intror/
 229 ]
 230 qed-.
 231
 232 lemma is_at_dec_le: ∀t,i2,i. (∀i1. i1 + i ≤ i2 → @⦃i1, t⦄ ≡ i2 → ⊥) → Decidable (∃i1. @⦃i1, t⦄ ≡ i2).
 233 #t #i2 #i elim i -i
 234 [ #Ht @or_intror * /3 width=3 by at_increasing/
 235 | #i #IH #Ht elim (at_dec t (i2-i) i2) /3 width=2 by ex_intro, or_introl/
 236   #Hi2 @IH -IH #i1 #H #Hi elim (le_to_or_lt_eq … H) -H /2 width=3 by/
 237   #H destruct -Ht /2 width=1 by/
 238 ]
 239 qed-.
 240
 241 (* Note: see also: trace_at/is_at_dec *)
 242 lemma is_at_dec: ∀t,i2. Decidable (∃i1. @⦃i1, t⦄ ≡ i2).
 243 #t #i2 @(is_at_dec_le ? ? (⫯i2)) /2 width=4 by lt_le_false/
 244 qed-.