matita/matita/contribs/lambdadelta/ground_2/relocation/nstream_id.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/identity_0.ma".
  16 include "ground_2/notation/relations/isidentity_1.ma".
  17 include "ground_2/relocation/nstream_after.ma".
  18
  19 (* RELOCATION N-STREAM ******************************************************)
  20
  21 let corec id: rtmap ≝ ↑id.
  22
  23 interpretation "identity (nstream)"
  24    'Identity = (id).
  25
  26 definition isid: predicate rtmap ≝ λf. f ≐ 𝐈𝐝.
  27
  28 interpretation "test for identity (trace)"
  29    'IsIdentity f = (isid f).
  30
  31 (* Basic properties on id ***************************************************)
  32
  33 lemma id_unfold: 𝐈𝐝 = ↑𝐈𝐝.
  34 >(stream_expand … (𝐈𝐝)) in ⊢ (??%?); normalize //
  35 qed.
  36
  37 (* Basic properties on isid *************************************************)
  38
  39 lemma isid_eq_repl_back: eq_stream_repl_back … isid.
  40 /2 width=3 by eq_stream_canc_sn/ qed-.
  41
  42 lemma isid_eq_repl_fwd: eq_stream_repl_fwd … isid.
  43 /3 width=3 by isid_eq_repl_back, eq_stream_repl_sym/ qed-.
  44
  45 lemma isid_id: 𝐈⦃𝐈𝐝⦄.
  46 // qed.
  47
  48 lemma isid_push: ∀f. 𝐈⦃f⦄ → 𝐈⦃↑f⦄.
  49 #f #H normalize >id_unfold /2 width=1 by eq_seq/
  50 qed.
  51
  52 (* Basic inversion lemmas on isid *******************************************)
  53
  54 lemma isid_inv_seq: ∀f,n.  𝐈⦃n@f⦄ → 𝐈⦃f⦄ ∧ n = 0.
  55 #f #n normalize >id_unfold in ⊢ (???%→?);
  56 #H elim (eq_stream_inv_seq ????? H) -H /2 width=1 by conj/
  57 qed-.
  58
  59 lemma isid_inv_push: ∀f. 𝐈⦃↑f⦄ → 𝐈⦃f⦄.
  60 * #n #f #H elim (isid_inv_seq … H) -H //
  61 qed-.
  62
  63 lemma isid_inv_next: ∀f. 𝐈⦃⫯f⦄ → ⊥.
  64 * #n #f #H elim (isid_inv_seq … H) -H
  65 #_ #H destruct
  66 qed-.
  67
  68 lemma isid_inv_gen: ∀f. 𝐈⦃f⦄ → ∃∃g. 𝐈⦃g⦄ & f = ↑g.
  69 * #n #f #H elim (isid_inv_seq … H) -H
  70 #Hf #H destruct /2 width=3 by ex2_intro/
  71 qed-.
  72
  73 lemma isid_inv_eq_repl: ∀f1,f2. 𝐈⦃f1⦄ → 𝐈⦃f2⦄ → f1 ≐ f2.
  74 /2 width=3 by eq_stream_canc_dx/ qed-.
  75
  76 (* inversion lemmas on at ***************************************************)
  77
  78 let corec id_inv_at: ∀f. (∀i. @⦃i, f⦄ ≡ i) → f ≐ 𝐈𝐝 ≝ ?.
  79 * #n #f #Ht lapply (Ht 0)
  80 #H lapply (at_inv_O1 … H) -H
  81 #H0 >id_unfold @eq_seq
  82 [ cases H0 -n //
  83 | @id_inv_at -id_inv_at
  84   #i lapply (Ht (⫯i)) -Ht cases H0 -n
  85   #H elim (at_inv_SOx … H) -H //
  86 ]
  87 qed-.
  88
  89 lemma isid_inv_at: ∀i,f. 𝐈⦃f⦄ → @⦃i, f⦄ ≡ i.
  90 #i elim i -i
  91 [ * #n #f #H elim (isid_inv_seq … H) -H //
  92 | #i #IH * #n #f #H elim (isid_inv_seq … H) -H
  93   /3 width=1 by at_S1/
  94 ]
  95 qed-.
  96
  97 lemma isid_inv_at_mono: ∀f,i1,i2. 𝐈⦃f⦄ → @⦃i1, f⦄ ≡ i2 → i1 = i2.
  98 /3 width=6 by isid_inv_at, at_mono/ qed-.
  99
 100 (* Properties on at *********************************************************)
 101
 102 lemma id_at: ∀i. @⦃i, 𝐈𝐝⦄ ≡ i.
 103 /2 width=1 by isid_inv_at/ qed.
 104
 105 lemma isid_at: ∀f. (∀i. @⦃i, f⦄ ≡ i) → 𝐈⦃f⦄.
 106 /2 width=1 by id_inv_at/ qed.
 107
 108 lemma isid_at_total: ∀f. (∀i1,i2. @⦃i1, f⦄ ≡ i2 → i1 = i2) → 𝐈⦃f⦄.
 109 #f #Ht @isid_at
 110 #i lapply (at_total i f)
 111 #H >(Ht … H) in ⊢ (???%); -Ht //
 112 qed.
 113
 114 (* Properties on after ******************************************************)
 115
 116 lemma after_isid_dx: ∀f2,f1,f. f2 ⊚ f1 ≡ f → f2 ≐ f → 𝐈⦃f1⦄.
 117 #f2 #f1 #f #Ht #H2 @isid_at_total
 118 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Ht) -f1
 119 /3 width=6 by at_inj, eq_stream_sym/
 120 qed.
 121
 122 lemma after_isid_sn: ∀f2,f1,f. f2 ⊚ f1 ≡ f → f1 ≐ f → 𝐈⦃f2⦄.
 123 #f2 #f1 #f #Ht #H1 @isid_at_total
 124 #i2 #i #Hi2 lapply (at_total i2 f1)
 125 #H0 lapply (at_increasing … H0)
 126 #Ht1 lapply (after_fwd_at2 … (f1@❴i2❵) … H0 … Ht)
 127 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 128 qed.
 129
 130 (* Inversion lemmas on after ************************************************)
 131
 132 let corec isid_after_sn: ∀f1,f2. 𝐈⦃f1⦄ → f1 ⊚ f2 ≡ f2 ≝ ?.
 133 * #n1 #f1 * * [ | #n2 ] #f2 #H cases (isid_inv_seq … H) -H
 134 /3 width=7 by after_push, after_refl/
 135 qed-.
 136
 137 let corec isid_after_dx: ∀f2,f1. 𝐈⦃f2⦄ → f1 ⊚ f2 ≡ f1 ≝ ?.
 138 * #n2 #f2 * *
 139 [ #f1 #H cases (isid_inv_seq … H) -H
 140   /3 width=7 by after_refl/
 141 | #n1 #f1 #H @after_next [4,5: // |1,2: skip ] /2 width=1 by/
 142 ]
 143 qed-.
 144
 145 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f1⦄ → f2 ≐ f.
 146 /3 width=8 by isid_after_sn, after_mono/
 147 qed-.
 148
 149 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f2⦄ → f1 ≐ f.
 150 /3 width=8 by isid_after_dx, after_mono/
 151 qed-.
 152 (*
 153 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃t⦄ → 𝐈⦃t1⦄ ∧ 𝐈⦃t2⦄.
 154 qed-.
 155 *)