matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_after.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rafter_3.ma".
  16 include "ground_2/relocation/rtmap_istot.ma".
  17
  18 (* RELOCATION MAP ***********************************************************)
  19
  20 coinductive after: relation3 rtmap rtmap rtmap ≝
  21 | after_refl: ∀f1,f2,f,g1,g2,g.
  22               after f1 f2 f → ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → after g1 g2 g
  23 | after_push: ∀f1,f2,f,g1,g2,g.
  24               after f1 f2 f → ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → after g1 g2 g
  25 | after_next: ∀f1,f2,f,g1,g.
  26               after f1 f2 f → ↑f1 = g1 → ↑f = g → after g1 f2 g
  27 .
  28
  29 interpretation "relational composition (rtmap)"
  30    'RAfter f1 f2 f = (after f1 f2 f).
  31
  32 definition H_after_inj: predicate rtmap ≝
  33                         λf1. 𝐓❪f1❫ →
  34                         ∀f,f21,f22. f1 ⊚ f21 ≘ f → f1 ⊚ f22 ≘ f → f21 ≡ f22.
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 lemma after_inv_ppx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ⫯f2 = g2 →
  39                      ∃∃f. f1 ⊚ f2 ≘ f & ⫯f = g.
  40 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  41 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  42   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  43   /2 width=3 by ex2_intro/
  44 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  45   elim (discr_push_next … Hx2)
  46 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  47   elim (discr_push_next … Hx1)
  48 ]
  49 qed-.
  50
  51 lemma after_inv_pnx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ↑f2 = g2 →
  52                      ∃∃f. f1 ⊚ f2 ≘ f & ↑f = g.
  53 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  54 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  55   elim (discr_next_push … Hx2)
  56 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  57   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  58   /2 width=3 by ex2_intro/
  59 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  60   elim (discr_push_next … Hx1)
  61 ]
  62 qed-.
  63
  64 lemma after_inv_nxx: ∀g1,f2,g. g1 ⊚ f2 ≘ g → ∀f1. ↑f1 = g1 →
  65                      ∃∃f. f1 ⊚ f2 ≘ f & ↑f = g.
  66 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  67 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  68   elim (discr_next_push … Hx1)
  69 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  70   elim (discr_next_push … Hx1)
  71 | #g #Hf #H1 #H #x1 #Hx1 destruct
  72   >(injective_next … Hx1) -x1
  73   /2 width=3 by ex2_intro/
  74 ]
  75 qed-.
  76
  77 (* Advanced inversion lemmas ************************************************)
  78
  79 lemma after_inv_ppp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  80                      ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⊚ f2 ≘ f.
  81 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  82 #x #Hf #Hx destruct <(injective_push … Hx) -f //
  83 qed-.
  84
  85 lemma after_inv_ppn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  86                      ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
  87 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  88 #x #Hf #Hx destruct elim (discr_push_next … Hx)
  89 qed-.
  90
  91 lemma after_inv_pnn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  92                     ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⊚ f2 ≘ f.
  93 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
  94 #x #Hf #Hx destruct <(injective_next … Hx) -f //
  95 qed-.
  96
  97 lemma after_inv_pnp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  98                      ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  99 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
 100 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 101 qed-.
 102
 103 lemma after_inv_nxn: ∀g1,f2,g. g1 ⊚ f2 ≘ g →
 104                      ∀f1,f. ↑f1 = g1 → ↑f = g → f1 ⊚ f2 ≘ f.
 105 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 106 #x #Hf #Hx destruct <(injective_next … Hx) -f //
 107 qed-.
 108
 109 lemma after_inv_nxp: ∀g1,f2,g. g1 ⊚ f2 ≘ g →
 110                      ∀f1,f. ↑f1 = g1 → ⫯f = g → ⊥.
 111 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 112 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 113 qed-.
 114
 115 lemma after_inv_pxp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 116                      ∀f1,f. ⫯f1 = g1 → ⫯f = g →
 117                      ∃∃f2. f1 ⊚ f2 ≘ f & ⫯f2 = g2.
 118 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 119 [ elim (after_inv_pnp … Hg … H1 … H) -g1 -g -f1 -f //
 120 | lapply (after_inv_ppp … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 121 ]
 122 qed-.
 123
 124 lemma after_inv_pxn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 125                      ∀f1,f. ⫯f1 = g1 → ↑f = g →
 126                      ∃∃f2. f1 ⊚ f2 ≘ f & ↑f2 = g2.
 127 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 128 [ lapply (after_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 129 | elim (after_inv_ppn … Hg … H1 … H) -g1 -g -f1 -f //
 130 ]
 131 qed-.
 132
 133 lemma after_inv_xxp: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f. ⫯f = g →
 134                      ∃∃f1,f2. f1 ⊚ f2 ≘ f & ⫯f1 = g1 & ⫯f2 = g2.
 135 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 136 [ elim (after_inv_nxp … Hg … H) -g2 -g -f //
 137 | elim (after_inv_pxp … Hg … H) -g /2 width=5 by ex3_2_intro/
 138 ]
 139 qed-.
 140
 141 lemma after_inv_xxn: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f. ↑f = g →
 142                      (∃∃f1,f2. f1 ⊚ f2 ≘ f & ⫯f1 = g1 & ↑f2 = g2) ∨
 143                      ∃∃f1. f1 ⊚ g2 ≘ f & ↑f1 = g1.
 144 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 145 [ /4 width=5 by after_inv_nxn, or_intror, ex2_intro/
 146 | elim (after_inv_pxn … Hg … H) -g
 147   /3 width=5 by or_introl, ex3_2_intro/
 148 ]
 149 qed-.
 150
 151 lemma after_inv_pxx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1. ⫯f1 = g1 →
 152                      (∃∃f2,f. f1 ⊚ f2 ≘ f & ⫯f2 = g2 & ⫯f = g) ∨
 153                      (∃∃f2,f. f1 ⊚ f2 ≘ f & ↑f2 = g2 & ↑f = g).
 154 #g1 * * [2: #m2 ] #g2 #g #Hg #f1 #H
 155 [  elim (after_inv_pnx … Hg … H) -g1
 156   /3 width=5 by or_intror, ex3_2_intro/
 157 | elim (after_inv_ppx … Hg … H) -g1
 158   /3 width=5 by or_introl, ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 (* Basic properties *********************************************************)
 163
 164 corec lemma after_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ⊚ f1 ≘ f).
 165 #f1 #f #f2 * -f2 -f1 -f
 166 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 167 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_refl/
 168 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_push/
 169 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by after_next/
 170 ]
 171 qed-.
 172
 173 lemma after_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ⊚ f1 ≘ f).
 174 #f1 #f @eq_repl_sym /2 width=3 by after_eq_repl_back2/
 175 qed-.
 176
 177 corec lemma after_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ⊚ f1 ≘ f).
 178 #f2 #f #f1 * -f2 -f1 -f
 179 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 180 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by after_refl/
 181 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by after_push/
 182 | @(after_next … H2 H) /2 width=5 by/
 183 ]
 184 qed-.
 185
 186 lemma after_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ⊚ f1 ≘ f).
 187 #f2 #f @eq_repl_sym /2 width=3 by after_eq_repl_back1/
 188 qed-.
 189
 190 corec lemma after_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ⊚ f1 ≘ f).
 191 #f2 #f1 #f * -f2 -f1 -f
 192 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 193 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by after_refl/
 194 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by after_push/
 195 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=5 by after_next/
 196 ]
 197 qed-.
 198
 199 lemma after_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ⊚ f1 ≘ f).
 200 #f2 #f1 @eq_repl_sym /2 width=3 by after_eq_repl_back0/
 201 qed-.
 202
 203 (* Main properties **********************************************************)
 204
 205 corec theorem after_trans1: ∀f0,f3,f4. f0 ⊚ f3 ≘ f4 →
 206                             ∀f1,f2. f1 ⊚ f2 ≘ f0 →
 207                             ∀f. f2 ⊚ f3 ≘ f → f1 ⊚ f ≘ f4.
 208 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 209 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 210   cases (after_inv_xxp … Hg0 … H0) -g0
 211   #f1 #f2 #Hf0 #H1 #H2
 212   cases (after_inv_ppx … Hg … H2 H3) -g2 -g3
 213   #f #Hf #H /3 width=7 by after_refl/
 214 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 215   cases (after_inv_xxp … Hg0 … H0) -g0
 216   #f1 #f2 #Hf0 #H1 #H2
 217   cases (after_inv_pnx … Hg … H2 H3) -g2 -g3
 218   #f #Hf #H /3 width=7 by after_push/
 219 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 220   cases (after_inv_xxn … Hg0 … H0) -g0 *
 221   [ #f1 #f2 #Hf0 #H1 #H2
 222     cases (after_inv_nxx … Hg … H2) -g2
 223     #f #Hf #H /3 width=7 by after_push/
 224   | #f1 #Hf0 #H1 /3 width=6 by after_next/
 225   ]
 226 ]
 227 qed-.
 228
 229 corec theorem after_trans2: ∀f1,f0,f4. f1 ⊚ f0 ≘ f4 →
 230                             ∀f2, f3. f2 ⊚ f3 ≘ f0 →
 231                             ∀f. f1 ⊚ f2 ≘ f → f ⊚ f3 ≘ f4.
 232 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 233 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 234   cases (after_inv_xxp … Hg0 … H0) -g0
 235   #f2 #f3 #Hf0 #H2 #H3
 236   cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 237   #f #Hf #H /3 width=7 by after_refl/
 238 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 239   cases (after_inv_xxn … Hg0 … H0) -g0 *
 240   [ #f2 #f3 #Hf0 #H2 #H3
 241     cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 242     #f #Hf #H /3 width=7 by after_push/
 243   | #f2 #Hf0 #H2
 244     cases (after_inv_pnx … Hg … H1 H2) -g1 -g2
 245     #f #Hf #H /3 width=6 by after_next/
 246   ]
 247 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 248   cases (after_inv_nxx … Hg … H1) -g1
 249   #f #Hg #H /3 width=6 by after_next/
 250 ]
 251 qed-.
 252
 253 (* Main inversion lemmas ****************************************************)
 254
 255 corec theorem after_mono: ∀f1,f2,x,y. f1 ⊚ f2 ≘ x → f1 ⊚ f2 ≘ y → x ≡ y.
 256 #f1 #f2 #x #y * -f1 -f2 -x
 257 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 258 [ cases (after_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 259 | cases (after_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 260 | cases (after_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_next/
 261 ]
 262 qed-.
 263
 264 lemma after_mono_eq: ∀f1,f2,f. f1 ⊚ f2 ≘ f → ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 265                      f1 ≡ g1 → f2 ≡ g2 → f ≡ g.
 266 /4 width=4 by after_mono, after_eq_repl_back1, after_eq_repl_back2/ qed-.
 267
 268 (* Properties on tls ********************************************************)
 269
 270 lemma after_tls: ∀n,f1,f2,f. @❪0, f1❫ ≘ n →
 271                  f1 ⊚ f2 ≘ f → ⫱*[n]f1 ⊚ f2 ≘ ⫱*[n]f.
 272 #n elim n -n //
 273 #n #IH #f1 #f2 #f #Hf1 #Hf
 274 cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ] #g1 #Hg1 #H1
 275 cases (after_inv_nxx … Hf … H1) -Hf #g #Hg #H0 destruct
 276 <tls_xn <tls_xn /2 width=1 by/
 277 qed.
 278
 279 (* Properties on isid *******************************************************)
 280
 281 corec lemma after_isid_sn: ∀f1. 𝐈❪f1❫ → ∀f2. f1 ⊚ f2 ≘ f2.
 282 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 283 /3 width=7 by after_push, after_refl/
 284 qed.
 285
 286 corec lemma after_isid_dx: ∀f2. 𝐈❪f2❫ → ∀f1. f1 ⊚ f2 ≘ f1.
 287 #f2 * -f2 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) * #g1 #H1
 288 [ /3 width=7 by after_refl/
 289 | @(after_next … H1 H1) /3 width=3 by isid_push/
 290 ]
 291 qed.
 292
 293 (* Inversion lemmas on isid *************************************************)
 294
 295 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❪f1❫ → f2 ≡ f.
 296 /3 width=6 by after_isid_sn, after_mono/ qed-.
 297
 298 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❪f2❫ → f1 ≡ f.
 299 /3 width=6 by after_isid_dx, after_mono/ qed-.
 300
 301 corec lemma after_fwd_isid1: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❪f❫ → 𝐈❪f1❫.
 302 #f1 #f2 #f * -f1 -f2 -f
 303 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 304 [ /4 width=6 by isid_inv_push, isid_push/ ]
 305 cases (isid_inv_next … H … H0)
 306 qed-.
 307
 308 corec lemma after_fwd_isid2: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❪f❫ → 𝐈❪f2❫.
 309 #f1 #f2 #f * -f1 -f2 -f
 310 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 311 [ /4 width=6 by isid_inv_push, isid_push/ ]
 312 cases (isid_inv_next … H … H0)
 313 qed-.
 314
 315 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈❪f❫ → 𝐈❪f1❫ ∧ 𝐈❪f2❫.
 316 /3 width=4 by after_fwd_isid2, after_fwd_isid1, conj/ qed-.
 317
 318 (* Properties on isuni ******************************************************)
 319
 320 lemma after_isid_isuni: ∀f1,f2. 𝐈❪f2❫ → 𝐔❪f1❫ → f1 ⊚ ↑f2 ≘ ↑f1.
 321 #f1 #f2 #Hf2 #H elim H -H
 322 /5 width=7 by after_isid_dx, after_eq_repl_back2, after_next, after_push, eq_push_inv_isid/
 323 qed.
 324
 325 lemma after_uni_next2: ∀f2. 𝐔❪f2❫ → ∀f1,f. ↑f2 ⊚ f1 ≘ f → f2 ⊚ ↑f1 ≘ f.
 326 #f2 #H elim H -f2
 327 [ #f2 #Hf2 #f1 #f #Hf
 328   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 329   /4 width=7 by after_isid_inv_sn, after_isid_sn, after_eq_repl_back0, eq_next/
 330 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 331   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 332   /3 width=5 by after_next/
 333 ]
 334 qed.
 335
 336 (* Properties on uni ********************************************************)
 337
 338 lemma after_uni: ∀n1,n2. 𝐔❨n1❩ ⊚ 𝐔❨n2❩ ≘ 𝐔❨n1+n2❩.
 339 @nat_elim2 [3: #n #m <plus_n_Sm ] (**) (* full auto fails *)
 340 /4 width=5 by after_uni_next2, after_isid_dx, after_isid_sn, after_next/
 341 qed.
 342
 343 (* Forward lemmas on at *****************************************************)
 344
 345 lemma after_at_fwd: ∀i,i1,f. @❪i1, f❫ ≘ i → ∀f2,f1. f2 ⊚ f1 ≘ f →
 346                     ∃∃i2. @❪i1, f1❫ ≘ i2 & @❪i2, f2❫ ≘ i.
 347 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 348 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 349   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 350 | elim (at_inv_xxp … Hf) -Hf //
 351   #g #H1 #H
 352 ]
 353 [2: elim (after_inv_xxn … Hf21 … H) -f *
 354     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 355 |*: elim (after_inv_xxp … Hf21 … H) -f
 356     #g2 #g1 #Hg21 #H2 #H1
 357 ]
 358 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 359 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 360 qed-.
 361
 362 lemma after_fwd_at: ∀i,i2,i1,f1,f2. @❪i1, f1❫ ≘ i2 → @❪i2, f2❫ ≘ i →
 363                     ∀f. f2 ⊚ f1 ≘ f → @❪i1, f❫ ≘ i.
 364 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 365 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 366   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 367   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 368     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 369     [ elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 370     | elim (after_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 371     ]
 372   | elim (after_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 373   ]
 374 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 375   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 376   elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 377 ]
 378 qed-.
 379
 380 lemma after_fwd_at2: ∀f,i1,i. @❪i1, f❫ ≘ i → ∀f1,i2. @❪i1, f1❫ ≘ i2 →
 381                      ∀f2. f2 ⊚ f1 ≘ f → @❪i2, f2❫ ≘ i.
 382 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (after_at_fwd … Hf … H) -f
 383 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 384 qed-.
 385
 386 lemma after_fwd_at1: ∀i,i2,i1,f,f2. @❪i1, f❫ ≘ i → @❪i2, f2❫ ≘ i →
 387                      ∀f1. f2 ⊚ f1 ≘ f → @❪i1, f1❫ ≘ i2.
 388 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 389 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 390   #g [ #j1 ] #Hg [ #H01 ] #H00
 391   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 392   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 393   [ elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 394   | elim (after_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 395   | elim (after_inv_nxp … Hf1 … H20 H00)
 396   | /4 width=9 by after_inv_nxn, at_next/
 397   ]
 398 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 399   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 400   elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 401 ]
 402 qed-.
 403
 404 (* Properties with at *******************************************************)
 405
 406 lemma after_uni_dx: ∀i2,i1,f2. @❪i1, f2❫ ≘ i2 →
 407                     ∀f. f2 ⊚ 𝐔❨i1❩ ≘ f → 𝐔❨i2❩ ⊚ ⫱*[i2] f2 ≘ f.
 408 #i2 elim i2 -i2
 409 [ #i1 #f2 #Hf2 #f #Hf
 410   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 411   lapply (after_isid_inv_dx … Hf ?) -Hf
 412   /3 width=3 by after_isid_sn, after_eq_repl_back0/
 413 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 414   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 415   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 416     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 417     <tls_xn /3 width=5 by after_next/
 418   | #g2 #Hg2 #H2 destruct
 419     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 420     <tls_xn /3 width=5 by after_next/
 421   ]
 422 ]
 423 qed.
 424
 425 lemma after_uni_sn: ∀i2,i1,f2. @❪i1, f2❫ ≘ i2 →
 426                     ∀f. 𝐔❨i2❩ ⊚ ⫱*[i2] f2 ≘ f → f2 ⊚ 𝐔❨i1❩ ≘ f.
 427 #i2 elim i2 -i2
 428 [ #i1 #f2 #Hf2 #f #Hf
 429   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 430   lapply (after_isid_inv_sn … Hf ?) -Hf
 431   /3 width=3 by after_isid_dx, after_eq_repl_back0/
 432 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 433   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 434   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 435   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by after_push/
 436   | #g2 #Hg2 #H2 destruct /3 width=5 by after_next/
 437   ]
 438 ]
 439 qed-.
 440
 441 lemma after_uni_succ_dx: ∀i2,i1,f2. @❪i1, f2❫ ≘ i2 →
 442                          ∀f. f2 ⊚ 𝐔❨↑i1❩ ≘ f → 𝐔❨↑i2❩ ⊚ ⫱*[↑i2] f2 ≘ f.
 443 #i2 elim i2 -i2
 444 [ #i1 #f2 #Hf2 #f #Hf
 445   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 446   elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 447   lapply (after_isid_inv_dx … Hg ?) -Hg
 448   /4 width=5 by after_isid_sn, after_eq_repl_back0, after_next/
 449 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 450   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 451   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 452     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 453     <tls_xn /3 width=5 by after_next/
 454   | #g2 #Hg2 #H2 destruct
 455     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 456     <tls_xn /3 width=5 by after_next/
 457   ]
 458 ]
 459 qed.
 460
 461 lemma after_uni_succ_sn: ∀i2,i1,f2. @❪i1, f2❫ ≘ i2 →
 462                          ∀f. 𝐔❨↑i2❩ ⊚ ⫱*[↑i2] f2 ≘ f → f2 ⊚ 𝐔❨↑i1❩ ≘ f.
 463 #i2 elim i2 -i2
 464 [ #i1 #f2 #Hf2 #f #Hf
 465   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 466   elim (after_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 467   lapply (after_isid_inv_sn … Hg ?) -Hg
 468   /4 width=7 by after_isid_dx, after_eq_repl_back0, after_push/
 469 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 470   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 471   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 472   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by after_push/
 473   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by after_next/
 474   ]
 475 ]
 476 qed-.
 477
 478 lemma after_uni_one_dx: ∀f2,f. ⫯f2 ⊚ 𝐔❨↑O❩ ≘ f → 𝐔❨↑O❩ ⊚ f2 ≘ f.
 479 #f2 #f #H @(after_uni_succ_dx … (⫯f2)) /2 width=3 by at_refl/
 480 qed.
 481
 482 lemma after_uni_one_sn: ∀f1,f. 𝐔❨↑O❩ ⊚ f1 ≘ f → ⫯f1 ⊚ 𝐔❨↑O❩ ≘ f.
 483 /3 width=3 by after_uni_succ_sn, at_refl/ qed-.
 484
 485 (* Forward lemmas on istot **************************************************)
 486
 487 lemma after_istot_fwd: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f2❫ → 𝐓❪f1❫ → 𝐓❪f❫.
 488 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 489 #i2 #Hf1 elim (Hf2 i2) -Hf2
 490 /3 width=7 by after_fwd_at, ex_intro/
 491 qed-.
 492
 493 lemma after_fwd_istot_dx: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → 𝐓❪f1❫.
 494 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 495 #i2 #Hf elim (after_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 496 qed-.
 497
 498 lemma after_fwd_istot_sn: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → 𝐓❪f2❫.
 499 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 500 #i #Hf elim (after_at_fwd … Hf … H) -f
 501 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 502 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 503 qed-.
 504
 505 lemma after_inv_istot: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → 𝐓❪f2❫ ∧ 𝐓❪f1❫.
 506 /3 width=4 by after_fwd_istot_sn, after_fwd_istot_dx, conj/ qed-.
 507
 508 lemma after_at1_fwd: ∀f1,i1,i2. @❪i1, f1❫ ≘ i2 → ∀f2. 𝐓❪f2❫ → ∀f. f2 ⊚ f1 ≘ f →
 509                      ∃∃i. @❪i2, f2❫ ≘ i & @❪i1, f❫ ≘ i.
 510 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 511 /3 width=8 by after_fwd_at, ex2_intro/
 512 qed-.
 513
 514 lemma after_fwd_isid_sn: ∀f2,f1,f. 𝐓❪f❫ → f2 ⊚ f1 ≘ f → f1 ≡ f → 𝐈❪f2❫.
 515 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 516 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 517 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 518 #i0 #Hf1 lapply (at_increasing … Hf1)
 519 #Hi20 lapply (after_fwd_at2 … i0 … Hf1 … Hf) -Hf
 520 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 521 qed-.
 522
 523 lemma after_fwd_isid_dx: ∀f2,f1,f.  𝐓❪f❫ → f2 ⊚ f1 ≘ f → f2 ≡ f → 𝐈❪f1❫.
 524 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 525 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 526 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Hf) -f1
 527 /3 width=8 by at_inj, at_eq_repl_back/
 528 qed-.
 529
 530 corec fact after_inj_O_aux: ∀f1. @❪0, f1❫ ≘ 0 → H_after_inj f1.
 531 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 532 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 533 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 534 cases (H2g1 0) #n #Hn
 535 cases (after_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 536 [ cases (after_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 537   @(eq_push … H21 H22) -f21 -f22
 538 | cases (after_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 539   @(eq_next … H21 H22) -f21 -f22
 540 ]
 541 @(after_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -after_inj_O_aux
 542 /2 width=1 by after_tls, istot_tls, at_pxx_tls/
 543 qed-.
 544
 545 fact after_inj_aux: (∀f1. @❪0, f1❫ ≘ 0 → H_after_inj f1) →
 546                     ∀i2,f1. @❪0, f1❫ ≘ i2 → H_after_inj f1.
 547 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 548 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 549 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 550 elim (after_inv_nxx … H1f … H1) -H1f #g #H1g #H
 551 lapply (after_inv_nxn … H2f … H1 H) -f #H2g
 552 /3 width=6 by istot_inv_next/
 553 qed-.
 554
 555 theorem after_inj: ∀f1. H_after_inj f1.
 556 #f1 #H cases (H 0) /3 width=7 by after_inj_aux, after_inj_O_aux/
 557 qed-.