matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_after.ma

   1
   2 (**************************************************************************)
   3 (*       ___                                                              *)
   4 (*      ||M||                                                             *)
   5 (*      ||A||       A project by Andrea Asperti                           *)
   6 (*      ||T||                                                             *)
   7 (*      ||I||       Developers:                                           *)
   8 (*      ||T||         The HELM team.                                      *)
   9 (*      ||A||         http://helm.cs.unibo.it                             *)
  10 (*      \   /                                                             *)
  11 (*       \ /        This file is distributed under the terms of the       *)
  12 (*        v         GNU General Public License Version 2                  *)
  13 (*                                                                        *)
  14 (**************************************************************************)
  15
  16 include "ground_2/notation/relations/rafter_3.ma".
  17 include "ground_2/relocation/rtmap_istot.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive after: relation3 rtmap rtmap rtmap ≝
  22 | after_refl: ∀f1,f2,f,g1,g2,g.
  23               after f1 f2 f → ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → after g1 g2 g
  24 | after_push: ∀f1,f2,f,g1,g2,g.
  25               after f1 f2 f → ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → after g1 g2 g
  26 | after_next: ∀f1,f2,f,g1,g.
  27               after f1 f2 f → ↑f1 = g1 → ↑f = g → after g1 f2 g
  28 .
  29
  30 interpretation "relational composition (rtmap)"
  31    'RAfter f1 f2 f = (after f1 f2 f).
  32
  33 definition H_after_inj: predicate rtmap ≝
  34                         λf1. 𝐓⦃f1⦄ →
  35                         ∀f,f21,f22. f1 ⊚ f21 ≘ f → f1 ⊚ f22 ≘ f → f21 ≡ f22.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 lemma after_inv_ppx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ⫯f2 = g2 →
  40                      ∃∃f. f1 ⊚ f2 ≘ f & ⫯f = g.
  41 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  42 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  43   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  44   /2 width=3 by ex2_intro/
  45 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  46   elim (discr_push_next … Hx2)
  47 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  48   elim (discr_push_next … Hx1)
  49 ]
  50 qed-.
  51
  52 lemma after_inv_pnx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ↑f2 = g2 →
  53                      ∃∃f. f1 ⊚ f2 ≘ f & ↑f = g.
  54 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  55 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  56   elim (discr_next_push … Hx2)
  57 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  58   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  59   /2 width=3 by ex2_intro/
  60 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  61   elim (discr_push_next … Hx1)
  62 ]
  63 qed-.
  64
  65 lemma after_inv_nxx: ∀g1,f2,g. g1 ⊚ f2 ≘ g → ∀f1. ↑f1 = g1 →
  66                      ∃∃f. f1 ⊚ f2 ≘ f & ↑f = g.
  67 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  68 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  69   elim (discr_next_push … Hx1)
  70 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  71   elim (discr_next_push … Hx1)
  72 | #g #Hf #H1 #H #x1 #Hx1 destruct
  73   >(injective_next … Hx1) -x1
  74   /2 width=3 by ex2_intro/
  75 ]
  76 qed-.
  77
  78 (* Advanced inversion lemmas ************************************************)
  79
  80 lemma after_inv_ppp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  81                      ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⊚ f2 ≘ f.
  82 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  83 #x #Hf #Hx destruct <(injective_push … Hx) -f //
  84 qed-.
  85
  86 lemma after_inv_ppn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  87                      ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
  88 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  89 #x #Hf #Hx destruct elim (discr_push_next … Hx)
  90 qed-.
  91
  92 lemma after_inv_pnn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  93                     ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⊚ f2 ≘ f.
  94 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
  95 #x #Hf #Hx destruct <(injective_next … Hx) -f //
  96 qed-.
  97
  98 lemma after_inv_pnp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
  99                      ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
 100 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
 101 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 102 qed-.
 103
 104 lemma after_inv_nxn: ∀g1,f2,g. g1 ⊚ f2 ≘ g →
 105                      ∀f1,f. ↑f1 = g1 → ↑f = g → f1 ⊚ f2 ≘ f.
 106 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 107 #x #Hf #Hx destruct <(injective_next … Hx) -f //
 108 qed-.
 109
 110 lemma after_inv_nxp: ∀g1,f2,g. g1 ⊚ f2 ≘ g →
 111                      ∀f1,f. ↑f1 = g1 → ⫯f = g → ⊥.
 112 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 113 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 114 qed-.
 115
 116 lemma after_inv_pxp: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 117                      ∀f1,f. ⫯f1 = g1 → ⫯f = g →
 118                      ∃∃f2. f1 ⊚ f2 ≘ f & ⫯f2 = g2.
 119 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 120 [ elim (after_inv_pnp … Hg … H1 … H) -g1 -g -f1 -f //
 121 | lapply (after_inv_ppp … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 122 ]
 123 qed-.
 124
 125 lemma after_inv_pxn: ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 126                      ∀f1,f. ⫯f1 = g1 → ↑f = g →
 127                      ∃∃f2. f1 ⊚ f2 ≘ f & ↑f2 = g2.
 128 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 129 [ lapply (after_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 130 | elim (after_inv_ppn … Hg … H1 … H) -g1 -g -f1 -f //
 131 ]
 132 qed-.
 133
 134 lemma after_inv_xxp: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f. ⫯f = g →
 135                      ∃∃f1,f2. f1 ⊚ f2 ≘ f & ⫯f1 = g1 & ⫯f2 = g2.
 136 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 137 [ elim (after_inv_nxp … Hg … H) -g2 -g -f //
 138 | elim (after_inv_pxp … Hg … H) -g /2 width=5 by ex3_2_intro/
 139 ]
 140 qed-.
 141
 142 lemma after_inv_xxn: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f. ↑f = g →
 143                      (∃∃f1,f2. f1 ⊚ f2 ≘ f & ⫯f1 = g1 & ↑f2 = g2) ∨
 144                      ∃∃f1. f1 ⊚ g2 ≘ f & ↑f1 = g1.
 145 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 146 [ /4 width=5 by after_inv_nxn, or_intror, ex2_intro/
 147 | elim (after_inv_pxn … Hg … H) -g
 148   /3 width=5 by or_introl, ex3_2_intro/
 149 ]
 150 qed-.
 151
 152 lemma after_inv_pxx: ∀g1,g2,g. g1 ⊚ g2 ≘ g → ∀f1. ⫯f1 = g1 →
 153                      (∃∃f2,f. f1 ⊚ f2 ≘ f & ⫯f2 = g2 & ⫯f = g) ∨
 154                      (∃∃f2,f. f1 ⊚ f2 ≘ f & ↑f2 = g2 & ↑f = g).
 155 #g1 * * [2: #m2 ] #g2 #g #Hg #f1 #H
 156 [  elim (after_inv_pnx … Hg … H) -g1
 157   /3 width=5 by or_intror, ex3_2_intro/
 158 | elim (after_inv_ppx … Hg … H) -g1
 159   /3 width=5 by or_introl, ex3_2_intro/
 160 ]
 161 qed-.
 162
 163 (* Basic properties *********************************************************)
 164
 165 corec lemma after_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ⊚ f1 ≘ f).
 166 #f1 #f #f2 * -f2 -f1 -f
 167 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 168 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_refl/
 169 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_push/
 170 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by after_next/
 171 ]
 172 qed-.
 173
 174 lemma after_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ⊚ f1 ≘ f).
 175 #f1 #f @eq_repl_sym /2 width=3 by after_eq_repl_back2/
 176 qed-.
 177
 178 corec lemma after_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ⊚ f1 ≘ f).
 179 #f2 #f #f1 * -f2 -f1 -f
 180 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 181 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by after_refl/
 182 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by after_push/
 183 | @(after_next … H2 H) /2 width=5 by/
 184 ]
 185 qed-.
 186
 187 lemma after_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ⊚ f1 ≘ f).
 188 #f2 #f @eq_repl_sym /2 width=3 by after_eq_repl_back1/
 189 qed-.
 190
 191 corec lemma after_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ⊚ f1 ≘ f).
 192 #f2 #f1 #f * -f2 -f1 -f
 193 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 194 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by after_refl/
 195 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by after_push/
 196 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=5 by after_next/
 197 ]
 198 qed-.
 199
 200 lemma after_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ⊚ f1 ≘ f).
 201 #f2 #f1 @eq_repl_sym /2 width=3 by after_eq_repl_back0/
 202 qed-.
 203
 204 (* Main properties **********************************************************)
 205
 206 corec theorem after_trans1: ∀f0,f3,f4. f0 ⊚ f3 ≘ f4 →
 207                             ∀f1,f2. f1 ⊚ f2 ≘ f0 →
 208                             ∀f. f2 ⊚ f3 ≘ f → f1 ⊚ f ≘ f4.
 209 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 210 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 211   cases (after_inv_xxp … Hg0 … H0) -g0
 212   #f1 #f2 #Hf0 #H1 #H2
 213   cases (after_inv_ppx … Hg … H2 H3) -g2 -g3
 214   #f #Hf #H /3 width=7 by after_refl/
 215 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 216   cases (after_inv_xxp … Hg0 … H0) -g0
 217   #f1 #f2 #Hf0 #H1 #H2
 218   cases (after_inv_pnx … Hg … H2 H3) -g2 -g3
 219   #f #Hf #H /3 width=7 by after_push/
 220 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 221   cases (after_inv_xxn … Hg0 … H0) -g0 *
 222   [ #f1 #f2 #Hf0 #H1 #H2
 223     cases (after_inv_nxx … Hg … H2) -g2
 224     #f #Hf #H /3 width=7 by after_push/
 225   | #f1 #Hf0 #H1 /3 width=6 by after_next/
 226   ]
 227 ]
 228 qed-.
 229
 230 corec theorem after_trans2: ∀f1,f0,f4. f1 ⊚ f0 ≘ f4 →
 231                             ∀f2, f3. f2 ⊚ f3 ≘ f0 →
 232                             ∀f. f1 ⊚ f2 ≘ f → f ⊚ f3 ≘ f4.
 233 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 234 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 235   cases (after_inv_xxp … Hg0 … H0) -g0
 236   #f2 #f3 #Hf0 #H2 #H3
 237   cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 238   #f #Hf #H /3 width=7 by after_refl/
 239 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 240   cases (after_inv_xxn … Hg0 … H0) -g0 *
 241   [ #f2 #f3 #Hf0 #H2 #H3
 242     cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 243     #f #Hf #H /3 width=7 by after_push/
 244   | #f2 #Hf0 #H2
 245     cases (after_inv_pnx … Hg … H1 H2) -g1 -g2
 246     #f #Hf #H /3 width=6 by after_next/
 247   ]
 248 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 249   cases (after_inv_nxx … Hg … H1) -g1
 250   #f #Hg #H /3 width=6 by after_next/
 251 ]
 252 qed-.
 253
 254 (* Main inversion lemmas ****************************************************)
 255
 256 corec theorem after_mono: ∀f1,f2,x,y. f1 ⊚ f2 ≘ x → f1 ⊚ f2 ≘ y → x ≡ y.
 257 #f1 #f2 #x #y * -f1 -f2 -x
 258 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 259 [ cases (after_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 260 | cases (after_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 261 | cases (after_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_next/
 262 ]
 263 qed-.
 264
 265 lemma after_mono_eq: ∀f1,f2,f. f1 ⊚ f2 ≘ f → ∀g1,g2,g. g1 ⊚ g2 ≘ g →
 266                      f1 ≡ g1 → f2 ≡ g2 → f ≡ g.
 267 /4 width=4 by after_mono, after_eq_repl_back1, after_eq_repl_back2/ qed-.
 268
 269 (* Properties on tls ********************************************************)
 270
 271 lemma after_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≘ n →
 272                  f1 ⊚ f2 ≘ f → ⫱*[n]f1 ⊚ f2 ≘ ⫱*[n]f.
 273 #n elim n -n //
 274 #n #IH #f1 #f2 #f #Hf1 #Hf
 275 cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ] #g1 #Hg1 #H1
 276 cases (after_inv_nxx … Hf … H1) -Hf #g #Hg #H0 destruct
 277 <tls_xn <tls_xn /2 width=1 by/
 278 qed.
 279
 280 (* Properties on isid *******************************************************)
 281
 282 corec lemma after_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⊚ f2 ≘ f2.
 283 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 284 /3 width=7 by after_push, after_refl/
 285 qed.
 286
 287 corec lemma after_isid_dx: ∀f2. 𝐈⦃f2⦄ → ∀f1. f1 ⊚ f2 ≘ f1.
 288 #f2 * -f2 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) * #g1 #H1
 289 [ /3 width=7 by after_refl/
 290 | @(after_next … H1 H1) /3 width=3 by isid_push/
 291 ]
 292 qed.
 293
 294 (* Inversion lemmas on isid *************************************************)
 295
 296 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈⦃f1⦄ → f2 ≡ f.
 297 /3 width=6 by after_isid_sn, after_mono/ qed-.
 298
 299 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈⦃f2⦄ → f1 ≡ f.
 300 /3 width=6 by after_isid_dx, after_mono/ qed-.
 301
 302 corec lemma after_fwd_isid1: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄.
 303 #f1 #f2 #f * -f1 -f2 -f
 304 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 305 [ /4 width=6 by isid_inv_push, isid_push/ ]
 306 cases (isid_inv_next … H … H0)
 307 qed-.
 308
 309 corec lemma after_fwd_isid2: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
 310 #f1 #f2 #f * -f1 -f2 -f
 311 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 312 [ /4 width=6 by isid_inv_push, isid_push/ ]
 313 cases (isid_inv_next … H … H0)
 314 qed-.
 315
 316 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ∧ 𝐈⦃f2⦄.
 317 /3 width=4 by after_fwd_isid2, after_fwd_isid1, conj/ qed-.
 318
 319 (* Properties on isuni ******************************************************)
 320
 321 lemma after_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ⊚ ↑f2 ≘ ↑f1.
 322 #f1 #f2 #Hf2 #H elim H -H
 323 /5 width=7 by after_isid_dx, after_eq_repl_back2, after_next, after_push, eq_push_inv_isid/
 324 qed.
 325
 326 lemma after_uni_next2: ∀f2. 𝐔⦃f2⦄ → ∀f1,f. ↑f2 ⊚ f1 ≘ f → f2 ⊚ ↑f1 ≘ f.
 327 #f2 #H elim H -f2
 328 [ #f2 #Hf2 #f1 #f #Hf
 329   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 330   /4 width=7 by after_isid_inv_sn, after_isid_sn, after_eq_repl_back0, eq_next/
 331 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 332   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 333   /3 width=5 by after_next/
 334 ]
 335 qed.
 336
 337 (* Properties on uni ********************************************************)
 338
 339 lemma after_uni: ∀n1,n2. 𝐔❴n1❵ ⊚ 𝐔❴n2❵ ≘ 𝐔❴n1+n2❵.
 340 @nat_elim2 [3: #n #m <plus_n_Sm ] (**) (* full auto fails *)
 341 /4 width=5 by after_uni_next2, after_isid_dx, after_isid_sn, after_next/
 342 qed.
 343
 344 (* Forward lemmas on at *****************************************************)
 345
 346 lemma after_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≘ i → ∀f2,f1. f2 ⊚ f1 ≘ f →
 347                     ∃∃i2. @⦃i1, f1⦄ ≘ i2 & @⦃i2, f2⦄ ≘ i.
 348 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 349 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 350   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 351 | elim (at_inv_xxp … Hf) -Hf //
 352   #g #H1 #H
 353 ]
 354 [2: elim (after_inv_xxn … Hf21 … H) -f *
 355     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 356 |*: elim (after_inv_xxp … Hf21 … H) -f
 357     #g2 #g1 #Hg21 #H2 #H1
 358 ]
 359 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 360 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 361 qed-.
 362
 363 lemma after_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≘ i2 → @⦃i2, f2⦄ ≘ i →
 364                     ∀f. f2 ⊚ f1 ≘ f → @⦃i1, f⦄ ≘ i.
 365 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 366 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 367   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 368   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 369     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 370     [ elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 371     | elim (after_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 372     ]
 373   | elim (after_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 374   ]
 375 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 376   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 377   elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 378 ]
 379 qed-.
 380
 381 lemma after_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≘ i → ∀f1,i2. @⦃i1, f1⦄ ≘ i2 →
 382                      ∀f2. f2 ⊚ f1 ≘ f → @⦃i2, f2⦄ ≘ i.
 383 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (after_at_fwd … Hf … H) -f
 384 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 385 qed-.
 386
 387 lemma after_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≘ i → @⦃i2, f2⦄ ≘ i →
 388                      ∀f1. f2 ⊚ f1 ≘ f → @⦃i1, f1⦄ ≘ i2.
 389 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 390 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 391   #g [ #j1 ] #Hg [ #H01 ] #H00
 392   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 393   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 394   [ elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 395   | elim (after_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 396   | elim (after_inv_nxp … Hf1 … H20 H00)
 397   | /4 width=9 by after_inv_nxn, at_next/
 398   ]
 399 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 400   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 401   elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 402 ]
 403 qed-.
 404
 405 (* Properties with at *******************************************************)
 406
 407 lemma after_uni_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≘ i2 →
 408                     ∀f. f2 ⊚ 𝐔❴i1❵ ≘ f → 𝐔❴i2❵ ⊚ ⫱*[i2] f2 ≘ f.
 409 #i2 elim i2 -i2
 410 [ #i1 #f2 #Hf2 #f #Hf
 411   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 412   lapply (after_isid_inv_dx … Hf ?) -Hf
 413   /3 width=3 by after_isid_sn, after_eq_repl_back0/
 414 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 415   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 416   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 417     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 418     <tls_xn /3 width=5 by after_next/
 419   | #g2 #Hg2 #H2 destruct
 420     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 421     <tls_xn /3 width=5 by after_next/
 422   ]
 423 ]
 424 qed.
 425
 426 lemma after_uni_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≘ i2 →
 427                     ∀f. 𝐔❴i2❵ ⊚ ⫱*[i2] f2 ≘ f → f2 ⊚ 𝐔❴i1❵ ≘ f.
 428 #i2 elim i2 -i2
 429 [ #i1 #f2 #Hf2 #f #Hf
 430   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 431   lapply (after_isid_inv_sn … Hf ?) -Hf
 432   /3 width=3 by after_isid_dx, after_eq_repl_back0/
 433 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 434   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 435   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 436   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by after_push/
 437   | #g2 #Hg2 #H2 destruct /3 width=5 by after_next/
 438   ]
 439 ]
 440 qed-.
 441
 442 lemma after_uni_succ_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≘ i2 →
 443                          ∀f. f2 ⊚ 𝐔❴↑i1❵ ≘ f → 𝐔❴↑i2❵ ⊚ ⫱*[↑i2] f2 ≘ f.
 444 #i2 elim i2 -i2
 445 [ #i1 #f2 #Hf2 #f #Hf
 446   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 447   elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 448   lapply (after_isid_inv_dx … Hg ?) -Hg
 449   /4 width=5 by after_isid_sn, after_eq_repl_back0, after_next/
 450 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 451   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 452   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 453     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 454     <tls_xn /3 width=5 by after_next/
 455   | #g2 #Hg2 #H2 destruct
 456     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 457     <tls_xn /3 width=5 by after_next/
 458   ]
 459 ]
 460 qed.
 461
 462 lemma after_uni_succ_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≘ i2 →
 463                          ∀f. 𝐔❴↑i2❵ ⊚ ⫱*[↑i2] f2 ≘ f → f2 ⊚ 𝐔❴↑i1❵ ≘ f.
 464 #i2 elim i2 -i2
 465 [ #i1 #f2 #Hf2 #f #Hf
 466   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 467   elim (after_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 468   lapply (after_isid_inv_sn … Hg ?) -Hg
 469   /4 width=7 by after_isid_dx, after_eq_repl_back0, after_push/
 470 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 471   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 472   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 473   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by after_push/
 474   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by after_next/
 475   ]
 476 ]
 477 qed-.
 478
 479 lemma after_uni_one_dx: ∀f2,f. ⫯f2 ⊚ 𝐔❴↑O❵ ≘ f → 𝐔❴↑O❵ ⊚ f2 ≘ f.
 480 #f2 #f #H @(after_uni_succ_dx … (⫯f2)) /2 width=3 by at_refl/
 481 qed.
 482
 483 lemma after_uni_one_sn: ∀f1,f. 𝐔❴↑O❵ ⊚ f1 ≘ f → ⫯f1 ⊚ 𝐔❴↑O❵ ≘ f.
 484 /3 width=3 by after_uni_succ_sn, at_refl/ qed-.
 485
 486 (* Forward lemmas on istot **************************************************)
 487
 488 lemma after_istot_fwd: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 489 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 490 #i2 #Hf1 elim (Hf2 i2) -Hf2
 491 /3 width=7 by after_fwd_at, ex_intro/
 492 qed-.
 493
 494 lemma after_fwd_istot_dx: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 495 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 496 #i2 #Hf elim (after_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 497 qed-.
 498
 499 lemma after_fwd_istot_sn: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 500 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 501 #i #Hf elim (after_at_fwd … Hf … H) -f
 502 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 503 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 504 qed-.
 505
 506 lemma after_inv_istot: ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 507 /3 width=4 by after_fwd_istot_sn, after_fwd_istot_dx, conj/ qed-.
 508
 509 lemma after_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≘ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ⊚ f1 ≘ f →
 510                      ∃∃i. @⦃i2, f2⦄ ≘ i & @⦃i1, f⦄ ≘ i.
 511 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 512 /3 width=8 by after_fwd_at, ex2_intro/
 513 qed-.
 514
 515 lemma after_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ⊚ f1 ≘ f → f1 ≡ f → 𝐈⦃f2⦄.
 516 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 517 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 518 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 519 #i0 #Hf1 lapply (at_increasing … Hf1)
 520 #Hi20 lapply (after_fwd_at2 … i0 … Hf1 … Hf) -Hf
 521 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 522 qed-.
 523
 524 lemma after_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ⊚ f1 ≘ f → f2 ≡ f → 𝐈⦃f1⦄.
 525 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 526 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 527 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Hf) -f1
 528 /3 width=8 by at_inj, at_eq_repl_back/
 529 qed-.
 530
 531 corec fact after_inj_O_aux: ∀f1. @⦃0, f1⦄ ≘ 0 → H_after_inj f1.
 532 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 533 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 534 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 535 cases (H2g1 0) #n #Hn
 536 cases (after_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 537 [ cases (after_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 538   @(eq_push … H21 H22) -f21 -f22
 539 | cases (after_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 540   @(eq_next … H21 H22) -f21 -f22
 541 ]
 542 @(after_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -after_inj_O_aux
 543 /2 width=1 by after_tls, istot_tls, at_pxx_tls/
 544 qed-.
 545
 546 fact after_inj_aux: (∀f1. @⦃0, f1⦄ ≘ 0 → H_after_inj f1) →
 547                     ∀i2,f1. @⦃0, f1⦄ ≘ i2 → H_after_inj f1.
 548 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 549 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 550 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 551 elim (after_inv_nxx … H1f … H1) -H1f #g #H1g #H
 552 lapply (after_inv_nxn … H2f … H1 H) -f #H2g
 553 /3 width=6 by istot_inv_next/
 554 qed-.
 555
 556 theorem after_inj: ∀f1. H_after_inj f1.
 557 #f1 #H cases (H 0) /3 width=7 by after_inj_aux, after_inj_O_aux/
 558 qed-.