matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_after.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rafter_3.ma".
  16 include "ground_2/relocation/rtmap_istot.ma".
  17 include "ground_2/relocation/rtmap_isuni.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive after: relation3 rtmap rtmap rtmap ≝
  22 | after_refl: ∀f1,f2,f,g1,g2,g.
  23               after f1 f2 f → ↑f1 = g1 → ↑f2 = g2 → ↑f = g → after g1 g2 g
  24 | after_push: ∀f1,f2,f,g1,g2,g.
  25               after f1 f2 f → ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → after g1 g2 g
  26 | after_next: ∀f1,f2,f,g1,g.
  27               after f1 f2 f → ⫯f1 = g1 → ⫯f = g → after g1 f2 g
  28 .
  29
  30 interpretation "relational composition (rtmap)"
  31    'RAfter f1 f2 f = (after f1 f2 f).
  32
  33 definition H_after_inj: predicate rtmap ≝
  34                         λf1. 𝐓⦃f1⦄ →
  35                         ∀f,f21,f22. f1 ⊚ f21 ≡ f → f1 ⊚ f22 ≡ f → f21 ≗ f22.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 lemma after_inv_ppx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  40                      ∃∃f. f1 ⊚ f2 ≡ f & ↑f = g.
  41 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  42 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  43   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  44   /2 width=3 by ex2_intro/
  45 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  46   elim (discr_push_next … Hx2)
  47 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  48   elim (discr_push_next … Hx1)
  49 ]
  50 qed-.
  51
  52 lemma after_inv_pnx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  53                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  54 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  55 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  56   elim (discr_next_push … Hx2)
  57 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  58   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  59   /2 width=3 by ex2_intro/
  60 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  61   elim (discr_push_next … Hx1)
  62 ]
  63 qed-.
  64
  65 lemma after_inv_nxx: ∀g1,f2,g. g1 ⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  66                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  67 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  68 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  69   elim (discr_next_push … Hx1)
  70 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  71   elim (discr_next_push … Hx1)
  72 | #g #Hf #H1 #H #x1 #Hx1 destruct
  73   >(injective_next … Hx1) -x1
  74   /2 width=3 by ex2_intro/
  75 ]
  76 qed-.
  77
  78 (* Advanced inversion lemmas ************************************************)
  79
  80 lemma after_inv_ppp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  81                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⊚ f2 ≡ f.
  82 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  83 #x #Hf #Hx destruct <(injective_push … Hx) -f //
  84 qed-.
  85
  86 lemma after_inv_ppn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  87                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  88 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  89 #x #Hf #Hx destruct elim (discr_push_next … Hx)
  90 qed-.
  91
  92 lemma after_inv_pnn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  93                     ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⊚ f2 ≡ f.
  94 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
  95 #x #Hf #Hx destruct <(injective_next … Hx) -f //
  96 qed-.
  97
  98 lemma after_inv_pnp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  99                      ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
 100 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
 101 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 102 qed-.
 103
 104 lemma after_inv_nxn: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 105                      ∀f1,f. ⫯f1 = g1 → ⫯f = g → f1 ⊚ f2 ≡ f.
 106 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 107 #x #Hf #Hx destruct <(injective_next … Hx) -f //
 108 qed-.
 109
 110 lemma after_inv_nxp: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 111                      ∀f1,f. ⫯f1 = g1 → ↑f = g → ⊥.
 112 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 113 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 114 qed-.
 115
 116 lemma after_inv_pxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 117                      ∀f1,f. ↑f1 = g1 → ↑f = g →
 118                      ∃∃f2. f1 ⊚ f2 ≡ f & ↑f2 = g2.
 119 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 120 [ elim (after_inv_pnp … Hg … H1 … H) -g1 -g -f1 -f //
 121 | lapply (after_inv_ppp … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 122 ]
 123 qed-.
 124
 125 lemma after_inv_pxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 126                      ∀f1,f. ↑f1 = g1 → ⫯f = g →
 127                      ∃∃f2. f1 ⊚ f2 ≡ f & ⫯f2 = g2.
 128 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 129 [ lapply (after_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 130 | elim (after_inv_ppn … Hg … H1 … H) -g1 -g -f1 -f //
 131 ]
 132 qed-.
 133
 134 lemma after_inv_xxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ↑f = g →
 135                      ∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2.
 136 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 137 [ elim (after_inv_nxp … Hg … H) -g2 -g -f //
 138 | elim (after_inv_pxp … Hg … H) -g /2 width=5 by ex3_2_intro/
 139 ]
 140 qed-.
 141
 142 lemma after_inv_xxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ⫯f = g →
 143                      (∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2) ∨
 144                      ∃∃f1. f1 ⊚ g2 ≡ f & ⫯f1 = g1.
 145 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 146 [ /4 width=5 by after_inv_nxn, or_intror, ex2_intro/
 147 | elim (after_inv_pxn … Hg … H) -g
 148   /3 width=5 by or_introl, ex3_2_intro/
 149 ]
 150 qed-.
 151
 152 lemma after_inv_pxx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 153                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 154                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 155 #g1 * * [2: #m2 ] #g2 #g #Hg #f1 #H
 156 [  elim (after_inv_pnx … Hg … H) -g1
 157   /3 width=5 by or_intror, ex3_2_intro/
 158 | elim (after_inv_ppx … Hg … H) -g1
 159   /3 width=5 by or_introl, ex3_2_intro/
 160 ]
 161 qed-.
 162
 163 (* Basic properties *********************************************************)
 164
 165 corec lemma after_eq_repl_back_2: ∀f1,f. eq_repl_back (λf2. f2 ⊚ f1 ≡ f).
 166 #f1 #f #f2 * -f2 -f1 -f
 167 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 168 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_refl/
 169 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_push/
 170 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by after_next/
 171 ]
 172 qed-.
 173
 174 lemma after_eq_repl_fwd_2: ∀f1,f. eq_repl_fwd (λf2. f2 ⊚ f1 ≡ f).
 175 #f1 #f @eq_repl_sym /2 width=3 by after_eq_repl_back_2/
 176 qed-.
 177
 178 corec lemma after_eq_repl_back_1: ∀f2,f. eq_repl_back (λf1. f2 ⊚ f1 ≡ f).
 179 #f2 #f #f1 * -f2 -f1 -f
 180 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 181 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by after_refl/
 182 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by after_push/
 183 | @(after_next … H2 H) /2 width=5 by/
 184 ]
 185 qed-.
 186
 187 lemma after_eq_repl_fwd_1: ∀f2,f. eq_repl_fwd (λf1. f2 ⊚ f1 ≡ f).
 188 #f2 #f @eq_repl_sym /2 width=3 by after_eq_repl_back_1/
 189 qed-.
 190
 191 corec lemma after_eq_repl_back_0: ∀f1,f2. eq_repl_back (λf. f2 ⊚ f1 ≡ f).
 192 #f2 #f1 #f * -f2 -f1 -f
 193 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 194 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by after_refl/
 195 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by after_push/
 196 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=5 by after_next/
 197 ]
 198 qed-.
 199
 200 lemma after_eq_repl_fwd_0: ∀f2,f1. eq_repl_fwd (λf. f2 ⊚ f1 ≡ f).
 201 #f2 #f1 @eq_repl_sym /2 width=3 by after_eq_repl_back_0/
 202 qed-.
 203
 204 (* Main properties **********************************************************)
 205
 206 corec theorem after_trans1: ∀f0,f3,f4. f0 ⊚ f3 ≡ f4 →
 207                             ∀f1,f2. f1 ⊚ f2 ≡ f0 →
 208                             ∀f. f2 ⊚ f3 ≡ f → f1 ⊚ f ≡ f4.
 209 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 210 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 211   cases (after_inv_xxp … Hg0 … H0) -g0
 212   #f1 #f2 #Hf0 #H1 #H2
 213   cases (after_inv_ppx … Hg … H2 H3) -g2 -g3
 214   #f #Hf #H /3 width=7 by after_refl/
 215 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 216   cases (after_inv_xxp … Hg0 … H0) -g0
 217   #f1 #f2 #Hf0 #H1 #H2
 218   cases (after_inv_pnx … Hg … H2 H3) -g2 -g3
 219   #f #Hf #H /3 width=7 by after_push/
 220 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 221   cases (after_inv_xxn … Hg0 … H0) -g0 *
 222   [ #f1 #f2 #Hf0 #H1 #H2
 223     cases (after_inv_nxx … Hg … H2) -g2
 224     #f #Hf #H /3 width=7 by after_push/
 225   | #f1 #Hf0 #H1 /3 width=6 by after_next/
 226   ]
 227 ]
 228 qed-.
 229
 230 corec theorem after_trans2: ∀f1,f0,f4. f1 ⊚ f0 ≡ f4 →
 231                             ∀f2, f3. f2 ⊚ f3 ≡ f0 →
 232                             ∀f. f1 ⊚ f2 ≡ f → f ⊚ f3 ≡ f4.
 233 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 234 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 235   cases (after_inv_xxp … Hg0 … H0) -g0
 236   #f2 #f3 #Hf0 #H2 #H3
 237   cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 238   #f #Hf #H /3 width=7 by after_refl/
 239 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 240   cases (after_inv_xxn … Hg0 … H0) -g0 *
 241   [ #f2 #f3 #Hf0 #H2 #H3
 242     cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 243     #f #Hf #H /3 width=7 by after_push/
 244   | #f2 #Hf0 #H2
 245     cases (after_inv_pnx … Hg … H1 H2) -g1 -g2
 246     #f #Hf #H /3 width=6 by after_next/
 247   ]
 248 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 249   cases (after_inv_nxx … Hg … H1) -g1
 250   #f #Hg #H /3 width=6 by after_next/
 251 ]
 252 qed-.
 253
 254 (* Main inversion lemmas on after *******************************************)
 255
 256 corec theorem after_mono: ∀f1,f2,x,y. f1 ⊚ f2 ≡ x → f1 ⊚ f2 ≡ y → x ≗ y.
 257 #f1 #f2 #x #y * -f1 -f2 -x
 258 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 259 [ cases (after_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 260 | cases (after_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 261 | cases (after_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_next/
 262 ]
 263 qed-.
 264
 265 lemma after_mono_eq: ∀f1,f2,f. f1 ⊚ f2 ≡ f → ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 266                      f1 ≗ g1 → f2 ≗ g2 → f ≗ g.
 267 /4 width=4 by after_mono, after_eq_repl_back_1, after_eq_repl_back_2/ qed-.
 268
 269 (* Properties on tls ********************************************************)
 270
 271 lemma after_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 272                  f1 ⊚ f2 ≡ f → ⫱*[n]f1 ⊚ f2 ≡ ⫱*[n]f.
 273 #n elim n -n //
 274 #n #IH #f1 #f2 #f #Hf1 #Hf cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ]
 275 #g1 #Hg1 #H1 cases (after_inv_nxx … Hf … H1) -Hf /2 width=1 by/
 276 qed.
 277
 278 (* Inversion lemmas on isid *************************************************)
 279
 280 corec lemma isid_after_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⊚ f2 ≡ f2.
 281 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 282 /3 width=7 by after_push, after_refl/
 283 qed-.
 284
 285 corec lemma isid_after_dx: ∀f2. 𝐈⦃f2⦄ → ∀f1. f1 ⊚ f2 ≡ f1.
 286 #f2 * -f2 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) * #g1 #H1
 287 [ /3 width=7 by after_refl/
 288 | @(after_next … H1 H1) /3 width=3 by isid_push/
 289 ]
 290 qed-.
 291
 292 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f1⦄ → f2 ≗ f.
 293 /3 width=6 by isid_after_sn, after_mono/
 294 qed-.
 295
 296 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f2⦄ → f1 ≗ f.
 297 /3 width=6 by isid_after_dx, after_mono/
 298 qed-.
 299
 300 corec lemma after_fwd_isid1: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄.
 301 #f1 #f2 #f * -f1 -f2 -f
 302 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 303 [ /4 width=6 by isid_inv_push, isid_push/ ]
 304 cases (isid_inv_next … H … H0)
 305 qed-.
 306
 307 corec lemma after_fwd_isid2: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
 308 #f1 #f2 #f * -f1 -f2 -f
 309 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 310 [ /4 width=6 by isid_inv_push, isid_push/ ]
 311 cases (isid_inv_next … H … H0)
 312 qed-.
 313
 314 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ∧ 𝐈⦃f2⦄.
 315 /3 width=4 by after_fwd_isid2, after_fwd_isid1, conj/ qed-.
 316
 317 (* Properties on isuni ******************************************************)
 318
 319 lemma after_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ⊚ ⫯f2 ≡ ⫯f1.
 320 #f1 #f2 #Hf2 #H elim H -H
 321 /5 width=7 by isid_after_dx, after_eq_repl_back_2, after_next, after_push, eq_push_inv_isid/
 322 qed.
 323
 324 (* Forward lemmas on at *****************************************************)
 325
 326 lemma after_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ⊚ f1 ≡ f →
 327                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 328 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 329 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 330   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 331 | elim (at_inv_xxp … Hf) -Hf //
 332   #g #H1 #H
 333 ]
 334 [2: elim (after_inv_xxn … Hf21 … H) -f *
 335     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 336 |*: elim (after_inv_xxp … Hf21 … H) -f
 337     #g2 #g1 #Hg21 #H2 #H1
 338 ]
 339 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 340 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 341 qed-.
 342
 343 lemma after_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 344                     ∀f. f2 ⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 345 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 346 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 347   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 348   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 349     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 350     [ elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 351     | elim (after_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 352     ]
 353   | elim (after_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 354   ]
 355 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 356   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 357   elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 358 ]
 359 qed-.
 360
 361 lemma after_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 362                      ∀f2. f2 ⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 363 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (after_at_fwd … Hf … H) -f
 364 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 365 qed-.
 366
 367 lemma after_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 368                      ∀f1. f2 ⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 369 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 370 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 371   #g [ #j1 ] #Hg [ #H01 ] #H00
 372   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 373   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 374   [ elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 375   | elim (after_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 376   | elim (after_inv_nxp … Hf1 … H20 H00)
 377   | /4 width=9 by after_inv_nxn, at_next/
 378   ]
 379 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 380   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 381   elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 382 ]
 383 qed-.
 384
 385 (* Forward lemmas on istot **************************************************)
 386
 387 lemma after_istot_fwd: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 388 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 389 #i2 #Hf1 elim (Hf2 i2) -Hf2
 390 /3 width=7 by after_fwd_at, ex_intro/
 391 qed-.
 392
 393 lemma after_fwd_istot_dx: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 394 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 395 #i2 #Hf elim (after_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 396 qed-.
 397
 398 lemma after_fwd_istot_sn: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 399 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 400 #i #Hf elim (after_at_fwd … Hf … H) -f
 401 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 402 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 403 qed-.
 404
 405 lemma after_inv_istot: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 406 /3 width=4 by after_fwd_istot_sn, after_fwd_istot_dx, conj/ qed-.
 407
 408 lemma after_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ⊚ f1 ≡ f →
 409                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 410 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 411 /3 width=8 by after_fwd_at, ex2_intro/
 412 qed-.
 413
 414 lemma after_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 415 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 416 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 417 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 418 #i0 #Hf1 lapply (at_increasing … Hf1)
 419 #Hi20 lapply (after_fwd_at2 … i0 … Hf1 … Hf) -Hf
 420 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 421 qed-.
 422
 423 lemma after_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 424 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 425 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 426 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Hf) -f1
 427 /3 width=8 by at_inj, at_eq_repl_back/
 428 qed-.
 429
 430 corec fact after_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1.
 431 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 432 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 433 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 434 cases (H2g1 0) #n #Hn
 435 cases (after_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 436 [ cases (after_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 437   @(eq_push … H21 H22) -f21 -f22
 438 | cases (after_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 439   @(eq_next … H21 H22) -f21 -f22
 440 ]
 441 @(after_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -after_inj_O_aux
 442 /2 width=1 by after_tls, istot_tls, at_pxx_tls/
 443 qed-.
 444
 445 fact after_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1) →
 446                     ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_after_inj f1.
 447 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 448 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 449 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 450 elim (after_inv_nxx … H1f … H1) -H1f #g #H1g #H
 451 lapply (after_inv_nxn … H2f … H1 H) -f #H2g
 452 /3 width=6 by istot_inv_next/
 453 qed-.
 454
 455 theorem after_inj: ∀f1. H_after_inj f1.
 456 #f1 #H cases (H 0) /3 width=7 by after_inj_aux, after_inj_O_aux/
 457 qed-.