matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_after.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rafter_3.ma".
  16 include "ground_2/relocation/rtmap_istot.ma".
  17
  18 (* RELOCATION MAP ***********************************************************)
  19
  20 coinductive after: relation3 rtmap rtmap rtmap ≝
  21 | after_refl: ∀f1,f2,f,g1,g2,g.
  22               after f1 f2 f → ↑f1 = g1 → ↑f2 = g2 → ↑f = g → after g1 g2 g
  23 | after_push: ∀f1,f2,f,g1,g2,g.
  24               after f1 f2 f → ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → after g1 g2 g
  25 | after_next: ∀f1,f2,f,g1,g.
  26               after f1 f2 f → ⫯f1 = g1 → ⫯f = g → after g1 f2 g
  27 .
  28
  29 interpretation "relational composition (rtmap)"
  30    'RAfter f1 f2 f = (after f1 f2 f).
  31
  32 definition H_after_inj: predicate rtmap ≝
  33                         λf1. 𝐓⦃f1⦄ →
  34                         ∀f,f21,f22. f1 ⊚ f21 ≡ f → f1 ⊚ f22 ≡ f → f21 ≗ f22.
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 lemma after_inv_ppx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  39                      ∃∃f. f1 ⊚ f2 ≡ f & ↑f = g.
  40 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  41 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  42   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  43   /2 width=3 by ex2_intro/
  44 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  45   elim (discr_push_next … Hx2)
  46 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  47   elim (discr_push_next … Hx1)
  48 ]
  49 qed-.
  50
  51 lemma after_inv_pnx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  52                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  53 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  54 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  55   elim (discr_next_push … Hx2)
  56 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  57   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  58   /2 width=3 by ex2_intro/
  59 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  60   elim (discr_push_next … Hx1)
  61 ]
  62 qed-.
  63
  64 lemma after_inv_nxx: ∀g1,f2,g. g1 ⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  65                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  66 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  67 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  68   elim (discr_next_push … Hx1)
  69 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  70   elim (discr_next_push … Hx1)
  71 | #g #Hf #H1 #H #x1 #Hx1 destruct
  72   >(injective_next … Hx1) -x1
  73   /2 width=3 by ex2_intro/
  74 ]
  75 qed-.
  76
  77 (* Advanced inversion lemmas ************************************************)
  78
  79 lemma after_inv_ppp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  80                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⊚ f2 ≡ f.
  81 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  82 #x #Hf #Hx destruct <(injective_push … Hx) -f //
  83 qed-.
  84
  85 lemma after_inv_ppn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  86                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  87 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  88 #x #Hf #Hx destruct elim (discr_push_next … Hx)
  89 qed-.
  90
  91 lemma after_inv_pnn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  92                     ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⊚ f2 ≡ f.
  93 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
  94 #x #Hf #Hx destruct <(injective_next … Hx) -f //
  95 qed-.
  96
  97 lemma after_inv_pnp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  98                      ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
  99 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
 100 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 101 qed-.
 102
 103 lemma after_inv_nxn: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 104                      ∀f1,f. ⫯f1 = g1 → ⫯f = g → f1 ⊚ f2 ≡ f.
 105 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 106 #x #Hf #Hx destruct <(injective_next … Hx) -f //
 107 qed-.
 108
 109 lemma after_inv_nxp: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 110                      ∀f1,f. ⫯f1 = g1 → ↑f = g → ⊥.
 111 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 112 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 113 qed-.
 114
 115 lemma after_inv_pxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 116                      ∀f1,f. ↑f1 = g1 → ↑f = g →
 117                      ∃∃f2. f1 ⊚ f2 ≡ f & ↑f2 = g2.
 118 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 119 [ elim (after_inv_pnp … Hg … H1 … H) -g1 -g -f1 -f //
 120 | lapply (after_inv_ppp … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 121 ]
 122 qed-.
 123
 124 lemma after_inv_pxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 125                      ∀f1,f. ↑f1 = g1 → ⫯f = g →
 126                      ∃∃f2. f1 ⊚ f2 ≡ f & ⫯f2 = g2.
 127 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 128 [ lapply (after_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 129 | elim (after_inv_ppn … Hg … H1 … H) -g1 -g -f1 -f //
 130 ]
 131 qed-.
 132
 133 lemma after_inv_xxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ↑f = g →
 134                      ∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2.
 135 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 136 [ elim (after_inv_nxp … Hg … H) -g2 -g -f //
 137 | elim (after_inv_pxp … Hg … H) -g /2 width=5 by ex3_2_intro/
 138 ]
 139 qed-.
 140
 141 lemma after_inv_xxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ⫯f = g →
 142                      (∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2) ∨
 143                      ∃∃f1. f1 ⊚ g2 ≡ f & ⫯f1 = g1.
 144 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 145 [ /4 width=5 by after_inv_nxn, or_intror, ex2_intro/
 146 | elim (after_inv_pxn … Hg … H) -g
 147   /3 width=5 by or_introl, ex3_2_intro/
 148 ]
 149 qed-.
 150
 151 lemma after_inv_pxx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 152                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 153                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 154 #g1 * * [2: #m2 ] #g2 #g #Hg #f1 #H
 155 [  elim (after_inv_pnx … Hg … H) -g1
 156   /3 width=5 by or_intror, ex3_2_intro/
 157 | elim (after_inv_ppx … Hg … H) -g1
 158   /3 width=5 by or_introl, ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 (* Basic properties *********************************************************)
 163
 164 corec lemma after_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ⊚ f1 ≡ f).
 165 #f1 #f #f2 * -f2 -f1 -f
 166 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 167 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_refl/
 168 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by after_push/
 169 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by after_next/
 170 ]
 171 qed-.
 172
 173 lemma after_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ⊚ f1 ≡ f).
 174 #f1 #f @eq_repl_sym /2 width=3 by after_eq_repl_back2/
 175 qed-.
 176
 177 corec lemma after_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ⊚ f1 ≡ f).
 178 #f2 #f #f1 * -f2 -f1 -f
 179 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 180 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by after_refl/
 181 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by after_push/
 182 | @(after_next … H2 H) /2 width=5 by/
 183 ]
 184 qed-.
 185
 186 lemma after_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ⊚ f1 ≡ f).
 187 #f2 #f @eq_repl_sym /2 width=3 by after_eq_repl_back1/
 188 qed-.
 189
 190 corec lemma after_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ⊚ f1 ≡ f).
 191 #f2 #f1 #f * -f2 -f1 -f
 192 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 193 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by after_refl/
 194 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by after_push/
 195 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=5 by after_next/
 196 ]
 197 qed-.
 198
 199 lemma after_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ⊚ f1 ≡ f).
 200 #f2 #f1 @eq_repl_sym /2 width=3 by after_eq_repl_back0/
 201 qed-.
 202
 203 (* Main properties **********************************************************)
 204
 205 corec theorem after_trans1: ∀f0,f3,f4. f0 ⊚ f3 ≡ f4 →
 206                             ∀f1,f2. f1 ⊚ f2 ≡ f0 →
 207                             ∀f. f2 ⊚ f3 ≡ f → f1 ⊚ f ≡ f4.
 208 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 209 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 210   cases (after_inv_xxp … Hg0 … H0) -g0
 211   #f1 #f2 #Hf0 #H1 #H2
 212   cases (after_inv_ppx … Hg … H2 H3) -g2 -g3
 213   #f #Hf #H /3 width=7 by after_refl/
 214 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 215   cases (after_inv_xxp … Hg0 … H0) -g0
 216   #f1 #f2 #Hf0 #H1 #H2
 217   cases (after_inv_pnx … Hg … H2 H3) -g2 -g3
 218   #f #Hf #H /3 width=7 by after_push/
 219 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 220   cases (after_inv_xxn … Hg0 … H0) -g0 *
 221   [ #f1 #f2 #Hf0 #H1 #H2
 222     cases (after_inv_nxx … Hg … H2) -g2
 223     #f #Hf #H /3 width=7 by after_push/
 224   | #f1 #Hf0 #H1 /3 width=6 by after_next/
 225   ]
 226 ]
 227 qed-.
 228
 229 corec theorem after_trans2: ∀f1,f0,f4. f1 ⊚ f0 ≡ f4 →
 230                             ∀f2, f3. f2 ⊚ f3 ≡ f0 →
 231                             ∀f. f1 ⊚ f2 ≡ f → f ⊚ f3 ≡ f4.
 232 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 233 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 234   cases (after_inv_xxp … Hg0 … H0) -g0
 235   #f2 #f3 #Hf0 #H2 #H3
 236   cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 237   #f #Hf #H /3 width=7 by after_refl/
 238 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 239   cases (after_inv_xxn … Hg0 … H0) -g0 *
 240   [ #f2 #f3 #Hf0 #H2 #H3
 241     cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 242     #f #Hf #H /3 width=7 by after_push/
 243   | #f2 #Hf0 #H2
 244     cases (after_inv_pnx … Hg … H1 H2) -g1 -g2
 245     #f #Hf #H /3 width=6 by after_next/
 246   ]
 247 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 248   cases (after_inv_nxx … Hg … H1) -g1
 249   #f #Hg #H /3 width=6 by after_next/
 250 ]
 251 qed-.
 252
 253 (* Main inversion lemmas ****************************************************)
 254
 255 corec theorem after_mono: ∀f1,f2,x,y. f1 ⊚ f2 ≡ x → f1 ⊚ f2 ≡ y → x ≗ y.
 256 #f1 #f2 #x #y * -f1 -f2 -x
 257 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 258 [ cases (after_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 259 | cases (after_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 260 | cases (after_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_next/
 261 ]
 262 qed-.
 263
 264 lemma after_mono_eq: ∀f1,f2,f. f1 ⊚ f2 ≡ f → ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 265                      f1 ≗ g1 → f2 ≗ g2 → f ≗ g.
 266 /4 width=4 by after_mono, after_eq_repl_back1, after_eq_repl_back2/ qed-.
 267
 268 (* Properties on tls ********************************************************)
 269
 270 lemma after_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 271                  f1 ⊚ f2 ≡ f → ⫱*[n]f1 ⊚ f2 ≡ ⫱*[n]f.
 272 #n elim n -n //
 273 #n #IH #f1 #f2 #f #Hf1 #Hf cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ]
 274 #g1 #Hg1 #H1 cases (after_inv_nxx … Hf … H1) -Hf /2 width=1 by/
 275 qed.
 276
 277 (* Properties on isid *******************************************************)
 278
 279 corec lemma after_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⊚ f2 ≡ f2.
 280 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 281 /3 width=7 by after_push, after_refl/
 282 qed.
 283
 284 corec lemma after_isid_dx: ∀f2. 𝐈⦃f2⦄ → ∀f1. f1 ⊚ f2 ≡ f1.
 285 #f2 * -f2 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) * #g1 #H1
 286 [ /3 width=7 by after_refl/
 287 | @(after_next … H1 H1) /3 width=3 by isid_push/
 288 ]
 289 qed.
 290
 291 (* Inversion lemmas on isid *************************************************)
 292
 293 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f1⦄ → f2 ≗ f.
 294 /3 width=6 by after_isid_sn, after_mono/ qed-.
 295
 296 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f2⦄ → f1 ≗ f.
 297 /3 width=6 by after_isid_dx, after_mono/ qed-.
 298
 299 corec lemma after_fwd_isid1: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄.
 300 #f1 #f2 #f * -f1 -f2 -f
 301 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 302 [ /4 width=6 by isid_inv_push, isid_push/ ]
 303 cases (isid_inv_next … H … H0)
 304 qed-.
 305
 306 corec lemma after_fwd_isid2: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
 307 #f1 #f2 #f * -f1 -f2 -f
 308 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 309 [ /4 width=6 by isid_inv_push, isid_push/ ]
 310 cases (isid_inv_next … H … H0)
 311 qed-.
 312
 313 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ∧ 𝐈⦃f2⦄.
 314 /3 width=4 by after_fwd_isid2, after_fwd_isid1, conj/ qed-.
 315
 316 (* Properties on isuni ******************************************************)
 317
 318 lemma after_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ⊚ ⫯f2 ≡ ⫯f1.
 319 #f1 #f2 #Hf2 #H elim H -H
 320 /5 width=7 by after_isid_dx, after_eq_repl_back2, after_next, after_push, eq_push_inv_isid/
 321 qed.
 322
 323 lemma after_uni_next2: ∀f2. 𝐔⦃f2⦄ → ∀f1,f. ⫯f2 ⊚ f1 ≡ f → f2 ⊚ ⫯f1 ≡ f.
 324 #f2 #H elim H -f2
 325 [ #f2 #Hf2 #f1 #f #Hf
 326   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 327   /4 width=7 by after_isid_inv_sn, after_isid_sn, after_eq_repl_back0, eq_next/
 328 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 329   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 330   /3 width=5 by after_next/
 331 ]
 332 qed.
 333
 334 (* Properties on uni ********************************************************)
 335
 336 lemma after_uni: ∀n1,n2. 𝐔❴n1❵ ⊚ 𝐔❴n2❵ ≡ 𝐔❴n1+n2❵.
 337 @nat_elim2
 338 /4 width=5 by after_uni_next2, after_isid_sn, after_isid_dx, after_next/
 339 qed.
 340
 341 (* Forward lemmas on at *****************************************************)
 342
 343 lemma after_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ⊚ f1 ≡ f →
 344                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 345 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 346 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 347   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 348 | elim (at_inv_xxp … Hf) -Hf //
 349   #g #H1 #H
 350 ]
 351 [2: elim (after_inv_xxn … Hf21 … H) -f *
 352     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 353 |*: elim (after_inv_xxp … Hf21 … H) -f
 354     #g2 #g1 #Hg21 #H2 #H1
 355 ]
 356 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 357 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 358 qed-.
 359
 360 lemma after_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 361                     ∀f. f2 ⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 362 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 363 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 364   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 365   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 366     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 367     [ elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 368     | elim (after_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 369     ]
 370   | elim (after_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 371   ]
 372 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 373   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 374   elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 375 ]
 376 qed-.
 377
 378 lemma after_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 379                      ∀f2. f2 ⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 380 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (after_at_fwd … Hf … H) -f
 381 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 382 qed-.
 383
 384 lemma after_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 385                      ∀f1. f2 ⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 386 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 387 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 388   #g [ #j1 ] #Hg [ #H01 ] #H00
 389   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 390   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 391   [ elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 392   | elim (after_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 393   | elim (after_inv_nxp … Hf1 … H20 H00)
 394   | /4 width=9 by after_inv_nxn, at_next/
 395   ]
 396 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 397   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 398   elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 399 ]
 400 qed-.
 401
 402 (* Properties with at *******************************************************)
 403
 404 lemma after_uni_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 405                     ∀f. f2 ⊚ 𝐔❴i1❵ ≡ f → 𝐔❴i2❵ ⊚ ⫱*[i2] f2 ≡ f.
 406 #i2 elim i2 -i2
 407 [ #i1 #f2 #Hf2 #f #Hf
 408   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 409   lapply (after_isid_inv_dx … Hf ?) -Hf
 410   /3 width=3 by after_isid_sn, after_eq_repl_back0/
 411 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 412   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 413   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 414     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 415     /3 width=5 by after_next/
 416   | #g2 #Hg2 #H2 destruct
 417     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 418     /3 width=5 by after_next/
 419   ]
 420 ]
 421 qed.
 422
 423 lemma after_uni_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 424                     ∀f. 𝐔❴i2❵ ⊚ ⫱*[i2] f2 ≡ f → f2 ⊚ 𝐔❴i1❵ ≡ f.
 425 #i2 elim i2 -i2
 426 [ #i1 #f2 #Hf2 #f #Hf
 427   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 428   lapply (after_isid_inv_sn … Hf ?) -Hf
 429   /3 width=3 by after_isid_dx, after_eq_repl_back0/
 430 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 431   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 432   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 433   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by after_push/
 434   | #g2 #Hg2 #H2 destruct /3 width=5 by after_next/
 435   ]
 436 ]
 437 qed-.
 438
 439 lemma after_uni_succ_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 440                          ∀f. f2 ⊚ 𝐔❴⫯i1❵ ≡ f → 𝐔❴⫯i2❵ ⊚ ⫱*[⫯i2] f2 ≡ f.
 441 #i2 elim i2 -i2
 442 [ #i1 #f2 #Hf2 #f #Hf
 443   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 444   elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 445   lapply (after_isid_inv_dx … Hg ?) -Hg
 446   /4 width=5 by after_isid_sn, after_eq_repl_back0, after_next/
 447 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 448   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 449   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 450     elim (after_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 451     /3 width=5 by after_next/
 452   | #g2 #Hg2 #H2 destruct
 453     elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 454     /3 width=5 by after_next/
 455   ]
 456 ]
 457 qed.
 458
 459 lemma after_uni_succ_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 460                          ∀f. 𝐔❴⫯i2❵ ⊚ ⫱*[⫯i2] f2 ≡ f → f2 ⊚ 𝐔❴⫯i1❵ ≡ f.
 461 #i2 elim i2 -i2
 462 [ #i1 #f2 #Hf2 #f #Hf
 463   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 464   elim (after_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 465   lapply (after_isid_inv_sn … Hg ?) -Hg
 466   /4 width=7 by after_isid_dx, after_eq_repl_back0, after_push/
 467 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 468   elim (after_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 469   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 470   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by after_push/
 471   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by after_next/
 472   ]
 473 ]
 474 qed-.
 475
 476 lemma after_uni_one_dx: ∀f2,f. ↑f2 ⊚ 𝐔❴⫯O❵ ≡ f → 𝐔❴⫯O❵ ⊚ f2 ≡ f.
 477 #f2 #f #H @(after_uni_succ_dx … (↑f2)) /2 width=3 by at_refl/
 478 qed.
 479
 480 lemma after_uni_one_sn: ∀f1,f. 𝐔❴⫯O❵ ⊚ f1 ≡ f → ↑f1 ⊚ 𝐔❴⫯O❵ ≡ f.
 481 /3 width=3 by after_uni_succ_sn, at_refl/ qed-.
 482
 483 (* Forward lemmas on istot **************************************************)
 484
 485 lemma after_istot_fwd: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 486 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 487 #i2 #Hf1 elim (Hf2 i2) -Hf2
 488 /3 width=7 by after_fwd_at, ex_intro/
 489 qed-.
 490
 491 lemma after_fwd_istot_dx: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 492 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 493 #i2 #Hf elim (after_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 494 qed-.
 495
 496 lemma after_fwd_istot_sn: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 497 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 498 #i #Hf elim (after_at_fwd … Hf … H) -f
 499 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 500 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 501 qed-.
 502
 503 lemma after_inv_istot: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 504 /3 width=4 by after_fwd_istot_sn, after_fwd_istot_dx, conj/ qed-.
 505
 506 lemma after_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ⊚ f1 ≡ f →
 507                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 508 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 509 /3 width=8 by after_fwd_at, ex2_intro/
 510 qed-.
 511
 512 lemma after_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 513 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 514 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 515 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 516 #i0 #Hf1 lapply (at_increasing … Hf1)
 517 #Hi20 lapply (after_fwd_at2 … i0 … Hf1 … Hf) -Hf
 518 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 519 qed-.
 520
 521 lemma after_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 522 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 523 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 524 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Hf) -f1
 525 /3 width=8 by at_inj, at_eq_repl_back/
 526 qed-.
 527
 528 corec fact after_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1.
 529 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 530 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 531 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 532 cases (H2g1 0) #n #Hn
 533 cases (after_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 534 [ cases (after_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 535   @(eq_push … H21 H22) -f21 -f22
 536 | cases (after_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 537   @(eq_next … H21 H22) -f21 -f22
 538 ]
 539 @(after_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -after_inj_O_aux
 540 /2 width=1 by after_tls, istot_tls, at_pxx_tls/
 541 qed-.
 542
 543 fact after_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1) →
 544                     ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_after_inj f1.
 545 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 546 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 547 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 548 elim (after_inv_nxx … H1f … H1) -H1f #g #H1g #H
 549 lapply (after_inv_nxn … H2f … H1 H) -f #H2g
 550 /3 width=6 by istot_inv_next/
 551 qed-.
 552
 553 theorem after_inj: ∀f1. H_after_inj f1.
 554 #f1 #H cases (H 0) /3 width=7 by after_inj_aux, after_inj_O_aux/
 555 qed-.