matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_after.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rafter_3.ma".
  16 include "ground_2/relocation/rtmap_istot.ma".
  17
  18 (* RELOCATION MAP ***********************************************************)
  19
  20 coinductive after: relation3 rtmap rtmap rtmap ≝
  21 | after_refl: ∀f1,f2,f,g1,g2,g.
  22               after f1 f2 f → ↑f1 = g1 → ↑f2 = g2 → ↑f = g → after g1 g2 g
  23 | after_push: ∀f1,f2,f,g1,g2,g.
  24               after f1 f2 f → ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → after g1 g2 g
  25 | after_next: ∀f1,f2,f,g1,g.
  26               after f1 f2 f → ⫯f1 = g1 → ⫯f = g → after g1 f2 g
  27 .
  28
  29 interpretation "relational composition (rtmap)"
  30    'RAfter f1 f2 f = (after f1 f2 f).
  31
  32 definition H_after_inj: predicate rtmap ≝
  33                         λf1. 𝐓⦃f1⦄ →
  34                         ∀f,f21,f22. f1 ⊚ f21 ≡ f → f1 ⊚ f22 ≡ f → f21 ≗ f22.
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 lemma after_inv_ppx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  39                      ∃∃f. f1 ⊚ f2 ≡ f & ↑f = g.
  40 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  41 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  42   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  43   /2 width=3 by ex2_intro/
  44 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  45   elim (discr_push_next … Hx2)
  46 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  47   elim (discr_push_next … Hx1)
  48 ]
  49 qed-.
  50
  51 lemma after_inv_pnx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  52                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  53 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  54 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  55   elim (discr_next_push … Hx2)
  56 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  57   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  58   /2 width=3 by ex2_intro/
  59 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  60   elim (discr_push_next … Hx1)
  61 ]
  62 qed-.
  63
  64 lemma after_inv_nxx: ∀g1,f2,g. g1 ⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  65                      ∃∃f. f1 ⊚ f2 ≡ f & ⫯f = g.
  66 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  67 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  68   elim (discr_next_push … Hx1)
  69 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  70   elim (discr_next_push … Hx1)
  71 | #g #Hf #H1 #H #x1 #Hx1 destruct
  72   >(injective_next … Hx1) -x1
  73   /2 width=3 by ex2_intro/
  74 ]
  75 qed-.
  76
  77 (* Advanced inversion lemmas ************************************************)
  78
  79 lemma after_inv_ppp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  80                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⊚ f2 ≡ f.
  81 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  82 #x #Hf #Hx destruct <(injective_push … Hx) -f //
  83 qed-.
  84
  85 lemma after_inv_ppn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  86                      ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  87 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_ppx … Hg … H1 H2) -g1 -g2
  88 #x #Hf #Hx destruct elim (discr_push_next … Hx)
  89 qed-.
  90
  91 lemma after_inv_pnn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  92                     ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⊚ f2 ≡ f.
  93 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
  94 #x #Hf #Hx destruct <(injective_next … Hx) -f //
  95 qed-.
  96
  97 lemma after_inv_pnp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
  98                      ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
  99 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H elim (after_inv_pnx … Hg … H1 H2) -g1 -g2
 100 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 101 qed-.
 102
 103 lemma after_inv_nxn: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 104                      ∀f1,f. ⫯f1 = g1 → ⫯f = g → f1 ⊚ f2 ≡ f.
 105 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 106 #x #Hf #Hx destruct <(injective_next … Hx) -f //
 107 qed-.
 108
 109 lemma after_inv_nxp: ∀g1,f2,g. g1 ⊚ f2 ≡ g →
 110                      ∀f1,f. ⫯f1 = g1 → ↑f = g → ⊥.
 111 #g1 #f2 #g #Hg #f1 #f #H1 #H elim (after_inv_nxx … Hg … H1) -g1
 112 #x #Hf #Hx destruct elim (discr_next_push … Hx)
 113 qed-.
 114
 115 lemma after_inv_pxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 116                      ∀f1,f. ↑f1 = g1 → ↑f = g →
 117                      ∃∃f2. f1 ⊚ f2 ≡ f & ↑f2 = g2.
 118 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 119 [ elim (after_inv_pnp … Hg … H1 … H) -g1 -g -f1 -f //
 120 | lapply (after_inv_ppp … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 121 ]
 122 qed-.
 123
 124 lemma after_inv_pxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g →
 125                      ∀f1,f. ↑f1 = g1 → ⫯f = g →
 126                      ∃∃f2. f1 ⊚ f2 ≡ f & ⫯f2 = g2.
 127 #g1 * * [2: #m2] #g2 #g #Hg #f1 #f #H1 #H
 128 [ lapply (after_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 129 | elim (after_inv_ppn … Hg … H1 … H) -g1 -g -f1 -f //
 130 ]
 131 qed-.
 132
 133 lemma after_inv_xxp: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ↑f = g →
 134                      ∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2.
 135 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 136 [ elim (after_inv_nxp … Hg … H) -g2 -g -f //
 137 | elim (after_inv_pxp … Hg … H) -g /2 width=5 by ex3_2_intro/
 138 ]
 139 qed-.
 140
 141 lemma after_inv_xxn: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f. ⫯f = g →
 142                      (∃∃f1,f2. f1 ⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2) ∨
 143                      ∃∃f1. f1 ⊚ g2 ≡ f & ⫯f1 = g1.
 144 * * [2: #m1 ] #g1 #g2 #g #Hg #f #H
 145 [ /4 width=5 by after_inv_nxn, or_intror, ex2_intro/
 146 | elim (after_inv_pxn … Hg … H) -g
 147   /3 width=5 by or_introl, ex3_2_intro/
 148 ]
 149 qed-.
 150
 151 lemma after_inv_pxx: ∀g1,g2,g. g1 ⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 152                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 153                      (∃∃f2,f. f1 ⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 154 #g1 * * [2: #m2 ] #g2 #g #Hg #f1 #H
 155 [  elim (after_inv_pnx … Hg … H) -g1
 156   /3 width=5 by or_intror, ex3_2_intro/
 157 | elim (after_inv_ppx … Hg … H) -g1
 158   /3 width=5 by or_introl, ex3_2_intro/
 159 ]
 160 qed-.
 161
 162 (* Main properties **********************************************************)
 163
 164 let corec after_trans1: ∀f0,f3,f4. f0 ⊚ f3 ≡ f4 →
 165                         ∀f1,f2. f1 ⊚ f2 ≡ f0 →
 166                         ∀f. f2 ⊚ f3 ≡ f → f1 ⊚ f ≡ f4 ≝ ?.
 167 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 168 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 169   cases (after_inv_xxp … Hg0 … H0) -g0
 170   #f1 #f2 #Hf0 #H1 #H2
 171   cases (after_inv_ppx … Hg … H2 H3) -g2 -g3
 172   #f #Hf #H /3 width=7 by after_refl/
 173 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 174   cases (after_inv_xxp … Hg0 … H0) -g0
 175   #f1 #f2 #Hf0 #H1 #H2
 176   cases (after_inv_pnx … Hg … H2 H3) -g2 -g3
 177   #f #Hf #H /3 width=7 by after_push/
 178 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 179   cases (after_inv_xxn … Hg0 … H0) -g0 *
 180   [ #f1 #f2 #Hf0 #H1 #H2
 181     cases (after_inv_nxx … Hg … H2) -g2
 182     #f #Hf #H /3 width=7 by after_push/
 183   | #f1 #Hf0 #H1 /3 width=6 by after_next/
 184   ]
 185 ]
 186 qed-.
 187
 188 let corec after_trans2: ∀f1,f0,f4. f1 ⊚ f0 ≡ f4 →
 189                         ∀f2, f3. f2 ⊚ f3 ≡ f0 →
 190                         ∀f. f1 ⊚ f2 ≡ f → f ⊚ f3 ≡ f4 ≝ ?.
 191 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 192 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 193   cases (after_inv_xxp … Hg0 … H0) -g0
 194   #f2 #f3 #Hf0 #H2 #H3
 195   cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 196   #f #Hf #H /3 width=7 by after_refl/
 197 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 198   cases (after_inv_xxn … Hg0 … H0) -g0 *
 199   [ #f2 #f3 #Hf0 #H2 #H3
 200     cases (after_inv_ppx … Hg … H1 H2) -g1 -g2
 201     #f #Hf #H /3 width=7 by after_push/
 202   | #f2 #Hf0 #H2
 203     cases (after_inv_pnx … Hg … H1 H2) -g1 -g2
 204     #f #Hf #H /3 width=6 by after_next/
 205   ]
 206 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 207   cases (after_inv_nxx … Hg … H1) -g1
 208   #f #Hg #H /3 width=6 by after_next/
 209 ]
 210 qed-.
 211
 212 (* Main inversion lemmas on after *******************************************)
 213
 214 let corec after_mono: ∀f1,f2,x,y. f1 ⊚ f2 ≡ x → f1 ⊚ f2 ≡ y → x ≗ y ≝ ?.
 215 #f1 #f2 #x #y * -f1 -f2 -x
 216 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 217 [ cases (after_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 218 | cases (after_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 219 | cases (after_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_next/
 220 ]
 221 qed-.
 222
 223 (* Properties on minus ******************************************************)
 224
 225 lemma after_minus: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 226                    f1 ⊚ f2 ≡ f → f1-n ⊚ f2 ≡ f-n.
 227 #n elim n -n //
 228 #n #IH #f1 #f2 #f #Hf1 #Hf cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ]
 229 #g1 #Hg1 #H1 cases (after_inv_nxx … Hf … H1) -Hf /2 width=1 by/
 230 qed.
 231
 232 (* Inversion lemmas on isid *************************************************)
 233
 234 let corec isid_after_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⊚ f2 ≡ f2 ≝ ?.
 235 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 236 /3 width=7 by after_push, after_refl/
 237 qed-.
 238
 239 let corec isid_after_dx: ∀f2. 𝐈⦃f2⦄ → ∀f1. f1 ⊚ f2 ≡ f1 ≝ ?.
 240 #f2 * -f2 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) * #g1 #H1
 241 [ /3 width=7 by after_refl/
 242 | @(after_next … H1 H1) /3 width=3 by isid_push/
 243 ]
 244 qed-.
 245
 246 lemma after_isid_inv_sn: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f1⦄ → f2 ≗ f.
 247 /3 width=6 by isid_after_sn, after_mono/
 248 qed-.
 249
 250 lemma after_isid_inv_dx: ∀f1,f2,f. f1 ⊚ f2 ≡ f →  𝐈⦃f2⦄ → f1 ≗ f.
 251 /3 width=6 by isid_after_dx, after_mono/
 252 qed-.
 253
 254 let corec after_fwd_isid1: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ≝ ?.
 255 #f1 #f2 #f * -f1 -f2 -f
 256 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 257 [ /4 width=6 by isid_inv_push, isid_push/ ]
 258 cases (isid_inv_next … H … H0)
 259 qed-.
 260
 261 let corec after_fwd_isid2: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f2⦄ ≝ ?.
 262 #f1 #f2 #f * -f1 -f2 -f
 263 #f1 #f2 #f #g1 [1,2: #g2 ] #g #Hf #H1 [1,2: #H2 ] #H0 #H
 264 [ /4 width=6 by isid_inv_push, isid_push/ ]
 265 cases (isid_inv_next … H … H0)
 266 qed-.
 267
 268 lemma after_inv_isid3: ∀f1,f2,f. f1 ⊚ f2 ≡ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ∧ 𝐈⦃f2⦄.
 269 /3 width=4 by after_fwd_isid2, after_fwd_isid1, conj/ qed-.
 270
 271 (* Forward lemmas on at *****************************************************)
 272
 273 lemma after_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ⊚ f1 ≡ f →
 274                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 275 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 276 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 277   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 278 | elim (at_inv_xxp … Hf) -Hf //
 279   #g #H1 #H
 280 ]
 281 [2: elim (after_inv_xxn … Hf21 … H) -f *
 282     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 283 |*: elim (after_inv_xxp … Hf21 … H) -f
 284     #g2 #g1 #Hg21 #H2 #H1
 285 ]
 286 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 287 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 288 qed-.
 289
 290 lemma after_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 291                     ∀f. f2 ⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 292 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 293 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 294   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 295   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 296     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 297     [ elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 298     | elim (after_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 299     ]
 300   | elim (after_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 301   ]
 302 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 303   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 304   elim (after_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 305 ]
 306 qed-.
 307
 308 lemma after_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 309                      ∀f2. f2 ⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 310 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (after_at_fwd … Hf … H) -f
 311 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 312 qed-.
 313
 314 lemma after_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 315                      ∀f1. f2 ⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 316 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 317 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 318   #g [ #j1 ] #Hg [ #H01 ] #H00
 319   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 320   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 321   [ elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 322   | elim (after_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 323   | elim (after_inv_nxp … Hf1 … H20 H00)
 324   | /4 width=9 by after_inv_nxn, at_next/
 325   ]
 326 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 327   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 328   elim (after_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 329 ]
 330 qed-.
 331
 332 (* Forward lemmas on istot **************************************************)
 333
 334 lemma after_istot_fwd: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 335 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 336 #i2 #Hf1 elim (Hf2 i2) -Hf2
 337 /3 width=7 by after_fwd_at, ex_intro/
 338 qed-.
 339
 340 lemma after_fwd_istot_dx: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 341 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 342 #i2 #Hf elim (after_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 343 qed-.
 344
 345 lemma after_fwd_istot_sn: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 346 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 347 #i #Hf elim (after_at_fwd … Hf … H) -f
 348 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 349 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 350 qed-.
 351
 352 lemma after_inv_istot: ∀f2,f1,f. f2 ⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 353 /3 width=4 by after_fwd_istot_sn, after_fwd_istot_dx, conj/ qed-.
 354
 355 lemma after_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ⊚ f1 ≡ f →
 356                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 357 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 358 /3 width=8 by after_fwd_at, ex2_intro/
 359 qed-.
 360
 361 lemma after_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 362 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 363 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 364 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 365 #i0 #Hf1 lapply (at_increasing … Hf1)
 366 #Hi20 lapply (after_fwd_at2 … i0 … Hf1 … Hf) -Hf
 367 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 368 qed-.
 369
 370 lemma after_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 371 #f2 #f1 #f #H #Hf elim (after_inv_istot … Hf H) -H
 372 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 373 #i1 #i2 #Hi12 elim (after_at1_fwd … Hi12 … Hf) -f1
 374 /3 width=8 by at_inj, at_eq_repl_back/
 375 qed-.
 376
 377 let corec after_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1 ≝ ?.
 378 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 379 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 380 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 381 cases (H2g1 0) #n #Hn
 382 cases (after_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 383 [ cases (after_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 384   @(eq_push … H21 H22) -f21 -f22
 385 | cases (after_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 386   @(eq_next … H21 H22) -f21 -f22
 387 ]
 388 @(after_inj_O_aux (g1-n) … (g-n)) -after_inj_O_aux
 389 /2 width=1 by after_minus, istot_minus, at_pxx_minus/
 390 qed-.
 391
 392 fact after_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_after_inj f1) →
 393                     ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_after_inj f1.
 394 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 395 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 396 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 397 elim (after_inv_nxx … H1f … H1) -H1f #g #H1g #H
 398 lapply (after_inv_nxn … H2f … H1 H) -f #H2g
 399 /3 width=6 by istot_inv_next/
 400 qed-.
 401
 402 theorem after_inj: ∀f1. H_after_inj f1.
 403 #f1 #H cases (H 0) /3 width=7 by after_inj_aux, after_inj_O_aux/
 404 qed-.