matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_coafter.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rcoafter_3.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "ground_2/relocation/rtmap_after.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive coafter: relation3 rtmap rtmap rtmap ≝
  22 | coafter_refl: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  23                 ↑f1 = g1 → ↑f2 = g2 → ↑f = g → coafter g1 g2 g
  24 | coafter_push: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  25                 ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → coafter g1 g2 g
  26 | coafter_next: ∀f1,f2,f,g1,g. coafter f1 f2 f →
  27                 ⫯f1 = g1 → ↑f = g → coafter g1 f2 g
  28 .
  29
  30 interpretation "relational co-composition (rtmap)"
  31    'RCoAfter f1 f2 f = (coafter f1 f2 f).
  32
  33 definition H_coafter_inj: predicate rtmap ≝
  34                           λf1. 𝐓⦃f1⦄ →
  35                           ∀f,f21,f22. f1 ~⊚ f21 ≡ f → f1 ~⊚ f22 ≡ f → f21 ≗ f22.
  36
  37 definition H_coafter_fwd_isid2: predicate rtmap ≝
  38                                 λf1. ∀f2,f. f1 ~⊚ f2 ≡ f → 𝐓⦃f1⦄ → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
  39
  40 definition H_coafter_isfin2_fwd: predicate rtmap ≝
  41                                  λf1. ∀f2. 𝐅⦃f2⦄ → 𝐓⦃f1⦄ → ∀f. f1 ~⊚ f2 ≡ f →  𝐅⦃f⦄.
  42
  43 (* Basic inversion lemmas ***************************************************)
  44
  45 lemma coafter_inv_ppx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  46                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  47 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  48 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  49   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  50   /2 width=3 by ex2_intro/
  51 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  52   elim (discr_push_next … Hx2)
  53 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  54   elim (discr_push_next … Hx1)
  55 ]
  56 qed-.
  57
  58 lemma coafter_inv_pnx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  59                        ∃∃f. f1 ~⊚ f2 ≡ f & ⫯f = g.
  60 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  61 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  62   elim (discr_next_push … Hx2)
  63 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  64   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  65   /2 width=3 by ex2_intro/
  66 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  67   elim (discr_push_next … Hx1)
  68 ]
  69 qed-.
  70
  71 lemma coafter_inv_nxx: ∀g1,f2,g. g1 ~⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  72                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  73 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  74 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  75   elim (discr_next_push … Hx1)
  76 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  77   elim (discr_next_push … Hx1)
  78 | #g #Hf #H1 #H #x1 #Hx1 destruct
  79   >(injective_next … Hx1) -x1
  80   /2 width=3 by ex2_intro/
  81 ]
  82 qed-.
  83
  84 (* Advanced inversion lemmas ************************************************)
  85
  86 lemma coafter_inv_ppp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  87                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ~⊚ f2 ≡ f.
  88 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  89 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  90 <(injective_push … Hx) -f //
  91 qed-.
  92
  93 lemma coafter_inv_ppn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  94                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  95 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  96 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  97 elim (discr_push_next … Hx)
  98 qed-.
  99
 100 lemma coafter_inv_pnn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 101                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ~⊚ f2 ≡ f.
 102 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 103 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 104 <(injective_next … Hx) -f //
 105 qed-.
 106
 107 lemma coafter_inv_pnp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 108                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
 109 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 110 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 111 elim (discr_next_push … Hx)
 112 qed-.
 113
 114 lemma coafter_inv_nxp: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 115                        ∀f1,f. ⫯f1 = g1 → ↑f = g → f1 ~⊚ f2 ≡ f.
 116 #g1 #f2 #g #Hg #f1 #f #H1 #H
 117 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 118 <(injective_push … Hx) -f //
 119 qed-.
 120
 121 lemma coafter_inv_nxn: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 122                        ∀f1,f. ⫯f1 = g1 → ⫯f = g → ⊥.
 123 #g1 #f2 #g #Hg #f1 #f #H1 #H
 124 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 125 elim (discr_push_next … Hx)
 126 qed-.
 127
 128 lemma coafter_inv_pxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 129                        ∀f1,f. ↑f1 = g1 → ↑f = g →
 130                        ∃∃f2. f1 ~⊚ f2 ≡ f & ↑f2 = g2.
 131 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 132 [ lapply (coafter_inv_ppp … Hg … H1 H2 H) -g1 -g /2 width=3 by ex2_intro/
 133 | elim (coafter_inv_pnp … Hg … H1 H2 H)
 134 ]
 135 qed-.
 136
 137 lemma coafter_inv_pxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 138                        ∀f1,f. ↑f1 = g1 → ⫯f = g →
 139                        ∃∃f2. f1 ~⊚ f2 ≡ f & ⫯f2 = g2.
 140 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 141 [ elim (coafter_inv_ppn … Hg … H1 H2 H)
 142 | lapply (coafter_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 143 ]
 144 qed-.
 145
 146 lemma coafter_inv_xxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ⫯f = g →
 147                        ∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2.
 148 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 149 [ elim (coafter_inv_pxn … Hg … H1 H) -g /2 width=5 by ex3_2_intro/
 150 | elim (coafter_inv_nxn … Hg … H1 H)
 151 ]
 152 qed-.
 153
 154 lemma coafter_inv_xxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ↑f = g →
 155                        (∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2) ∨
 156                        ∃∃f1. f1 ~⊚ g2 ≡ f & ⫯f1 = g1.
 157 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 158 [ elim (coafter_inv_pxp … Hg … H1 H) -g
 159   /3 width=5 by or_introl, ex3_2_intro/
 160 | /4 width=5 by coafter_inv_nxp, or_intror, ex2_intro/
 161 ]
 162 qed-.
 163
 164 lemma coafter_inv_pxx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 165                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 166                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 167 #g1 #g2 #g #Hg #f1 #H1 elim (pn_split g2) * #f2 #H2
 168 [ elim (coafter_inv_ppx … Hg … H1 H2) -g1
 169   /3 width=5 by or_introl, ex3_2_intro/
 170 | elim (coafter_inv_pnx … Hg … H1 H2) -g1
 171   /3 width=5 by or_intror, ex3_2_intro/
 172 ]
 173 qed-.
 174
 175 (* Basic properties *********************************************************)
 176
 177 corec lemma coafter_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ~⊚ f1 ≡ f).
 178 #f1 #f #f2 * -f2 -f1 -f
 179 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 180 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_refl/
 181 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_push/
 182 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by coafter_next/
 183 ]
 184 qed-.
 185
 186 lemma coafter_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ~⊚ f1 ≡ f).
 187 #f1 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back2/
 188 qed-.
 189
 190 corec lemma coafter_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ~⊚ f1 ≡ f).
 191 #f2 #f #f1 * -f2 -f1 -f
 192 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 193 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by coafter_refl/
 194 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by coafter_push/
 195 | @(coafter_next … H2 H) /2 width=5 by/
 196 ]
 197 qed-.
 198
 199 lemma coafter_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ~⊚ f1 ≡ f).
 200 #f2 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back1/
 201 qed-.
 202
 203 corec lemma coafter_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ~⊚ f1 ≡ f).
 204 #f2 #f1 #f * -f2 -f1 -f
 205 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 206 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by coafter_refl/
 207 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by coafter_push/
 208 | cases (eq_inv_px …  H0 …  H01) -g01 /3 width=5 by coafter_next/
 209 ]
 210 qed-.
 211
 212 lemma coafter_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ~⊚ f1 ≡ f).
 213 #f2 #f1 @eq_repl_sym /2 width=3 by coafter_eq_repl_back0/
 214 qed-.
 215
 216 (* Main inversion lemmas ****************************************************)
 217
 218 corec theorem coafter_mono: ∀f1,f2,x,y. f1 ~⊚ f2 ≡ x → f1 ~⊚ f2 ≡ y → x ≗ y.
 219 #f1 #f2 #x #y * -f1 -f2 -x
 220 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 221 [ cases (coafter_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 222 | cases (coafter_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 223 | cases (coafter_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_push/
 224 ]
 225 qed-.
 226
 227 lemma coafter_mono_eq: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 228                        f1 ≗ g1 → f2 ≗ g2 → f ≗ g.
 229 /4 width=4 by coafter_mono, coafter_eq_repl_back1, coafter_eq_repl_back2/ qed-.
 230
 231 (* Inversion lemmas with pushs **********************************************)
 232
 233 lemma coafter_fwd_pushs: ∀n,g2,g1,g. g2 ~⊚ g1 ≡ g → @⦃0, g2⦄ ≡ n →
 234                          ∃f. ↑*[n]f = g.
 235 #n elim n -n /2 width=2 by ex_intro/
 236 #n #IH #g2 #g1 #g #Hg #Hg2
 237 cases (at_inv_pxn … Hg2) -Hg2 [ |*: // ] #f2 #Hf2 #H2
 238 cases (coafter_inv_nxx … Hg … H2) -Hg -H2 #f #Hf #H0 destruct
 239 elim (IH … Hf Hf2) -g1 -g2 -f2 /2 width=2 by ex_intro/
 240 qed-.
 241
 242 (* Inversion lemmas with tail ***********************************************)
 243
 244 lemma coafter_inv_tl1: ∀g2,g1,g. g2 ~⊚ ⫱g1 ≡ g →
 245                        ∃∃f. ↑g2 ~⊚ g1 ≡ f & ⫱f = g.
 246 #g2 #g1 #g elim (pn_split g1) * #f1 #H1 #H destruct
 247 [ /3 width=7 by coafter_refl, ex2_intro/
 248 | @(ex2_intro … (⫯g)) /2 width=7 by coafter_push/ (**) (* full auto fails *)
 249 ]
 250 qed-.
 251
 252 lemma coafter_inv_tl0: ∀g2,g1,g. g2 ~⊚ g1 ≡ ⫱g →
 253                        ∃∃f1. ↑g2 ~⊚ f1 ≡ g & ⫱f1 = g1.
 254 #g2 #g1 #g elim (pn_split g) * #f #H0 #H destruct
 255 [ /3 width=7 by coafter_refl, ex2_intro/
 256 | @(ex2_intro … (⫯g1)) /2 width=7 by coafter_push/ (**) (* full auto fails *)
 257 ]
 258 qed-.
 259
 260 (* Properties with iterated tail ********************************************)
 261
 262 lemma coafter_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 263                    f1 ~⊚ f2 ≡ f → ⫱*[n]f1 ~⊚ f2 ≡ ⫱*[n]f.
 264 #n elim n -n //
 265 #n #IH #f1 #f2 #f #Hf1 #Hf
 266 cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ] #g1 #Hg1 #H1
 267 cases (coafter_inv_nxx … Hf … H1) -Hf #g #Hg #H0 destruct
 268 <tls_xn <tls_xn /2 width=1 by/
 269 qed.
 270
 271 lemma coafter_tls_succ: ∀g2,g1,g. g2 ~⊚ g1 ≡ g →
 272                         ∀n. @⦃0, g2⦄ ≡ n → ⫱*[⫯n]g2 ~⊚ ⫱g1 ≡ ⫱*[⫯n]g.
 273 #g2 #g1 #g #Hg #n #Hg2
 274 lapply (coafter_tls … Hg2 … Hg) -Hg #Hg
 275 lapply (at_pxx_tls … Hg2) -Hg2 #H
 276 elim (at_inv_pxp … H) -H [ |*: // ] #f2 #H2
 277 elim (coafter_inv_pxx … Hg … H2) -Hg * #f1 #f #Hf #H1 #H0 destruct
 278 <tls_S <tls_S <H2 <H0 -g2 -g -n //
 279 qed.
 280
 281 lemma coafter_fwd_xpx_pushs: ∀g2,f1,g,n. g2 ~⊚ ↑f1 ≡ g → @⦃0, g2⦄ ≡ n →
 282                              ∃f. ↑*[⫯n]f = g.
 283 #g2 #g1 #g #n #Hg #Hg2
 284 elim (coafter_fwd_pushs … Hg Hg2) #f #H0 destruct
 285 lapply (coafter_tls … Hg2 Hg) -Hg <tls_pushs #Hf
 286 lapply (at_pxx_tls … Hg2) -Hg2 #H
 287 elim (at_inv_pxp … H) -H [ |*: // ] #f2 #H2
 288 elim (coafter_inv_pxx … Hf … H2) -Hf -H2 * #f1 #g #_ #H1 #H0 destruct
 289 [ /2 width=2 by ex_intro/
 290 | elim (discr_next_push … H1)
 291 ]
 292 qed-.
 293
 294 lemma coafter_fwd_xnx_pushs: ∀g2,f1,g,n. g2 ~⊚ ⫯f1 ≡ g → @⦃0, g2⦄ ≡ n →
 295                              ∃f. ↑*[n] ⫯f = g.
 296 #g2 #g1 #g #n #Hg #Hg2
 297 elim (coafter_fwd_pushs … Hg Hg2) #f #H0 destruct
 298 lapply (coafter_tls … Hg2 Hg) -Hg <tls_pushs #Hf
 299 lapply (at_pxx_tls … Hg2) -Hg2 #H
 300 elim (at_inv_pxp … H) -H [ |*: // ] #f2 #H2
 301 elim (coafter_inv_pxx … Hf … H2) -Hf -H2 * #f1 #g #_ #H1 #H0 destruct
 302 [ elim (discr_push_next … H1)
 303 | /2 width=2 by ex_intro/
 304 ]
 305 qed-.
 306
 307 (* Properties with test for identity ****************************************)
 308
 309 corec lemma coafter_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ~⊚ f2 ≡ f2.
 310 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 311 /3 width=7 by coafter_push, coafter_refl/
 312 qed.
 313
 314 corec lemma coafter_isid_dx: ∀f2,f. 𝐈⦃f2⦄ → 𝐈⦃f⦄ → ∀f1. f1 ~⊚ f2 ≡ f.
 315 #f2 #f * -f2 #f2 #g2 #Hf2 #H2 * -f #f #g #Hf #H #f1 cases (pn_split f1) * #g1 #H1
 316 [ /3 width=7 by coafter_refl/
 317 | @(coafter_next … H1 … H) /3 width=3 by isid_push/
 318 ]
 319 qed.
 320
 321 (* Inversion lemmas with test for identity **********************************)
 322
 323 lemma coafter_isid_inv_sn: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f1⦄ → f2 ≗ f.
 324 /3 width=6 by coafter_isid_sn, coafter_mono/ qed-.
 325
 326 lemma coafter_isid_inv_dx: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f2⦄ → 𝐈⦃f⦄.
 327 /4 width=4 by eq_id_isid, coafter_isid_dx, coafter_mono/ qed-.
 328
 329 (* Properties with uniform relocations **************************************)
 330
 331 lemma coafter_uni_sn: ∀i,f. 𝐔❴i❵ ~⊚ f ≡ ↑*[i] f.
 332 #i elim i -i /2 width=5 by coafter_isid_sn, coafter_next/
 333 qed.
 334 (*
 335 (* Properties on isuni ******************************************************)
 336
 337 lemma coafter_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ~⊚ ⫯f2 ≡ ⫯f1.
 338 #f1 #f2 #Hf2 #H elim H -H
 339 /5 width=7 by coafter_isid_dx, coafter_eq_repl_back2, coafter_next, coafter_push, eq_push_inv_isid/
 340 qed.
 341
 342 lemma coafter_uni_next2: ∀f2. 𝐔⦃f2⦄ → ∀f1,f. ⫯f2 ~⊚ f1 ≡ f → f2 ~⊚ ⫯f1 ≡ f.
 343 #f2 #H elim H -f2
 344 [ #f2 #Hf2 #f1 #f #Hf
 345   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 346   /4 width=7 by coafter_isid_inv_sn, coafter_isid_sn, coafter_eq_repl_back0, eq_next/
 347 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 348   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 349   /3 width=5 by coafter_next/
 350 ]
 351 qed.
 352
 353 (* Properties on uni ********************************************************)
 354
 355 lemma coafter_uni: ∀n1,n2. 𝐔❴n1❵ ~⊚ 𝐔❴n2❵ ≡ 𝐔❴n1+n2❵.
 356 @nat_elim2
 357 /4 width=5 by coafter_uni_next2, coafter_isid_sn, coafter_isid_dx, coafter_next/
 358 qed.
 359
 360 (* Forward lemmas on at *****************************************************)
 361
 362 lemma coafter_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ~⊚ f1 ≡ f →
 363                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 364 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 365 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 366   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 367 | elim (at_inv_xxp … Hf) -Hf //
 368   #g #H1 #H
 369 ]
 370 [2: elim (coafter_inv_xxn … Hf21 … H) -f *
 371     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 372 |*: elim (coafter_inv_xxp … Hf21 … H) -f
 373     #g2 #g1 #Hg21 #H2 #H1
 374 ]
 375 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 376 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 377 qed-.
 378
 379 lemma coafter_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 380                     ∀f. f2 ~⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 381 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 382 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 383   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 384   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 385     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 386     [ elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 387     | elim (coafter_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 388     ]
 389   | elim (coafter_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 390   ]
 391 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 392   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 393   elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 394 ]
 395 qed-.
 396
 397 lemma coafter_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 398                      ∀f2. f2 ~⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 399 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (coafter_at_fwd … Hf … H) -f
 400 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 401 qed-.
 402
 403 lemma coafter_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 404                      ∀f1. f2 ~⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 405 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 406 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 407   #g [ #j1 ] #Hg [ #H01 ] #H00
 408   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 409   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 410   [ elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 411   | elim (coafter_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 412   | elim (coafter_inv_nxp … Hf1 … H20 H00)
 413   | /4 width=9 by coafter_inv_nxn, at_next/
 414   ]
 415 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 416   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 417   elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 418 ]
 419 qed-.
 420
 421 (* Properties with at *******************************************************)
 422
 423 lemma coafter_uni_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 424                     ∀f. f2 ~⊚ 𝐔❴i1❵ ≡ f → 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f.
 425 #i2 elim i2 -i2
 426 [ #i1 #f2 #Hf2 #f #Hf
 427   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 428   lapply (coafter_isid_inv_dx … Hf ?) -Hf
 429   /3 width=3 by coafter_isid_sn, coafter_eq_repl_back0/
 430 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 431   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 432   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 433     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 434     /3 width=5 by coafter_next/
 435   | #g2 #Hg2 #H2 destruct
 436     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 437     /3 width=5 by coafter_next/
 438   ]
 439 ]
 440 qed.
 441
 442 lemma coafter_uni_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 443                     ∀f. 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f → f2 ~⊚ 𝐔❴i1❵ ≡ f.
 444 #i2 elim i2 -i2
 445 [ #i1 #f2 #Hf2 #f #Hf
 446   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 447   lapply (coafter_isid_inv_sn … Hf ?) -Hf
 448   /3 width=3 by coafter_isid_dx, coafter_eq_repl_back0/
 449 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 450   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 451   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 452   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by coafter_push/
 453   | #g2 #Hg2 #H2 destruct /3 width=5 by coafter_next/
 454   ]
 455 ]
 456 qed-.
 457
 458 lemma coafter_uni_succ_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 459                          ∀f. f2 ~⊚ 𝐔❴⫯i1❵ ≡ f → 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f.
 460 #i2 elim i2 -i2
 461 [ #i1 #f2 #Hf2 #f #Hf
 462   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 463   elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 464   lapply (coafter_isid_inv_dx … Hg ?) -Hg
 465   /4 width=5 by coafter_isid_sn, coafter_eq_repl_back0, coafter_next/
 466 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 467   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 468   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 469     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 470     /3 width=5 by coafter_next/
 471   | #g2 #Hg2 #H2 destruct
 472     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 473     /3 width=5 by coafter_next/
 474   ]
 475 ]
 476 qed.
 477
 478 lemma coafter_uni_succ_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 479                          ∀f. 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f → f2 ~⊚ 𝐔❴⫯i1❵ ≡ f.
 480 #i2 elim i2 -i2
 481 [ #i1 #f2 #Hf2 #f #Hf
 482   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 483   elim (coafter_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 484   lapply (coafter_isid_inv_sn … Hg ?) -Hg
 485   /4 width=7 by coafter_isid_dx, coafter_eq_repl_back0, coafter_push/
 486 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 487   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 488   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 489   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by coafter_push/
 490   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by coafter_next/
 491   ]
 492 ]
 493 qed-.
 494
 495 lemma coafter_uni_one_dx: ∀f2,f. ↑f2 ~⊚ 𝐔❴⫯O❵ ≡ f → 𝐔❴⫯O❵ ~⊚ f2 ≡ f.
 496 #f2 #f #H @(coafter_uni_succ_dx … (↑f2)) /2 width=3 by at_refl/
 497 qed.
 498
 499 lemma coafter_uni_one_sn: ∀f1,f. 𝐔❴⫯O❵ ~⊚ f1 ≡ f → ↑f1 ~⊚ 𝐔❴⫯O❵ ≡ f.
 500 /3 width=3 by coafter_uni_succ_sn, at_refl/ qed-.
 501 *)
 502 (* Forward lemmas with istot ************************************************)
 503 (*
 504 lemma coafter_istot_fwd: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 505 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 506 #i2 #Hf1 elim (Hf2 i2) -Hf2
 507 /3 width=7 by coafter_fwd_at, ex_intro/
 508 qed-.
 509
 510 lemma coafter_fwd_istot_dx: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 511 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 512 #i2 #Hf elim (coafter_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 513 qed-.
 514
 515 lemma coafter_fwd_istot_sn: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 516 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 517 #i #Hf elim (coafter_at_fwd … Hf … H) -f
 518 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 519 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 520 qed-.
 521
 522 lemma coafter_inv_istot: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 523 /3 width=4 by coafter_fwd_istot_sn, coafter_fwd_istot_dx, conj/ qed-.
 524
 525 lemma coafter_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ~⊚ f1 ≡ f →
 526                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 527 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 528 /3 width=8 by coafter_fwd_at, ex2_intro/
 529 qed-.
 530
 531 lemma coafter_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 532 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 533 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 534 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 535 #i0 #Hf1 lapply (at_increasing … Hf1)
 536 #Hi20 lapply (coafter_fwd_at2 … i0 … Hf1 … Hf) -Hf
 537 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 538 qed-.
 539
 540 lemma coafter_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 541 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 542 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 543 #i1 #i2 #Hi12 elim (coafter_at1_fwd … Hi12 … Hf) -f1
 544 /3 width=8 by at_inj, at_eq_repl_back/
 545 qed-.
 546 *)
 547 corec fact coafter_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1.
 548 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 549 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 550 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 551 cases (H2g1 0) #n #Hn
 552 cases (coafter_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 553 [ cases (coafter_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 554   @(eq_push … H21 H22) -f21 -f22
 555 | cases (coafter_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 556   @(eq_next … H21 H22) -f21 -f22
 557 ]
 558 @(coafter_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -coafter_inj_O_aux
 559 /2 width=1 by coafter_tls, istot_tls, at_pxx_tls/
 560 qed-.
 561
 562 fact coafter_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1) →
 563                       ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_inj f1.
 564 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 565 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 566 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 567 elim (coafter_inv_nxx … H1f … H1) -H1f #g #H1g #H
 568 lapply (coafter_inv_nxp … H2f … H1 H) -f #H2g
 569 /3 width=6 by istot_inv_next/
 570 qed-.
 571
 572 theorem coafter_inj: ∀f1. H_coafter_inj f1.
 573 #f1 #H cases (H 0) /3 width=7 by coafter_inj_aux, coafter_inj_O_aux/
 574 qed-.
 575
 576 corec fact coafter_fwd_isid2_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 →
 577                                     H_coafter_fwd_isid2 f1.
 578 #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 579 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 580 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 581 cases (H2g1 0) #n #Hn
 582 cases (coafter_inv_pxx … H … H1) -H * #g2 #g #H #H2 #H0
 583 [ lapply (isid_inv_push … Hf … H0) -Hf #Hg
 584   @(isid_push … H2)
 585   /3 width=7 by coafter_tls, istot_tls, at_pxx_tls, isid_tls/
 586 | cases (isid_inv_next … Hf … H0)
 587 ]
 588 qed-.
 589
 590 fact coafter_fwd_isid2_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_fwd_isid2 f1) →
 591                             ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_fwd_isid2 f1.
 592 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 593 #i2 #IH #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 594 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
 595 elim (coafter_inv_nxx … H … H1) -H #g #Hg #H0
 596 @(IH … Hg1 … Hg) /2 width=3 by istot_inv_next, isid_inv_push/ (**) (* full auto fails *)
 597 qed-.
 598
 599 lemma coafter_fwd_isid2: ∀f1. H_coafter_fwd_isid2 f1.
 600 #f1 #f2 #f #Hf #H cases (H 0)
 601 /3 width=7 by coafter_fwd_isid2_aux, coafter_fwd_isid2_O_aux/
 602 qed-.
 603
 604 fact coafter_isfin2_fwd_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 →
 605                                H_coafter_isfin2_fwd f1.
 606 #f1 #Hf1 #f2 #H
 607 generalize in match Hf1; generalize in match f1; -f1
 608 @(isfin_ind … H) -f2
 609 [ /3 width=4 by coafter_isid_inv_dx, isfin_isid/ ]
 610 #f2 #_ #IH #f1 #H #Hf1 #f #Hf
 611 elim (at_inv_pxp … H) -H [ |*: // ] #g1 #H1
 612 lapply (istot_inv_push … Hf1 … H1) -Hf1 #Hg1
 613 elim (Hg1 0) #n #Hn
 614 [ elim (coafter_inv_ppx … Hf) | elim (coafter_inv_pnx … Hf)
 615 ] -Hf [1,6: |*: // ] #g #Hg #H0 destruct
 616 /5 width=6 by isfin_next, isfin_push, isfin_inv_tls, istot_tls, at_pxx_tls, coafter_tls/
 617 qed-.
 618
 619 fact coafter_isfin2_fwd_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_isfin2_fwd f1) →
 620                              ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_isfin2_fwd f1.
 621 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 622 #i2 #IH #f1 #H1f1 #f2 #Hf2 #H2f1 #f #Hf
 623 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
 624 elim (coafter_inv_nxx … Hf … H1) -Hf #g #Hg #H0
 625 lapply (IH … Hg1 … Hg) -i2 -Hg
 626 /2 width=4 by istot_inv_next, isfin_push/ (**) (* full auto fails *)
 627 qed-.
 628
 629 lemma coafter_isfin2_fwd: ∀f1. H_coafter_isfin2_fwd f1.
 630 #f1 #f2 #Hf2 #Hf1 cases (Hf1 0)
 631 /3 width=7 by coafter_isfin2_fwd_aux, coafter_isfin2_fwd_O_aux/
 632 qed-.
 633
 634 lemma coafter_inv_sor: ∀f. 𝐅⦃f⦄ → ∀f2. 𝐓⦃f2⦄ → ∀f1. f2 ~⊚ f1 ≡ f → ∀fa,fb. fa ⋓ fb ≡ f →
 635                        ∃∃f1a,f1b. f2 ~⊚ f1a ≡ fa & f2 ~⊚ f1b ≡ fb & f1a ⋓ f1b ≡ f1.
 636 @isfin_ind
 637 [ #f #Hf #f2 #Hf2 #f1 #H1f #fa #fb #H2f
 638   elim (sor_inv_isid3 … H2f) -H2f //
 639   lapply (coafter_fwd_isid2 … H1f ??) -H1f //
 640   /3 width=5 by ex3_2_intro, coafter_isid_dx, sor_isid/
 641 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 642   elim (sor_inv_xxp … H2) -H2 [ |*: // ] #ga #gb #H2f
 643   elim (coafter_inv_xxp … H1) -H1 [1,3: * |*: // ] #g2 [ #g1 ] #H1f #Hgf2
 644   [ lapply (istot_inv_push … Hf2 … Hgf2) | lapply (istot_inv_next … Hf2 … Hgf2) ] -Hf2 #Hg2
 645   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 646   /3 width=11 by sor_pp, ex3_2_intro, coafter_refl, coafter_next/
 647 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 648   elim (coafter_inv_xxn … H1) -H1 [ |*: // ] #g2 #g1 #H1f #Hgf2
 649   lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 650   elim (sor_inv_xxn … H2) -H2 [1,3,4: * |*: // ] #ga #gb #H2f
 651   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 652   /3 width=11 by sor_np, sor_pn, sor_nn, ex3_2_intro, coafter_refl, coafter_push/
 653 ]
 654 qed-.
 655
 656 (* Properties with istot ****************************************************)
 657
 658 lemma coafter_sor: ∀f. 𝐅⦃f⦄ → ∀f2. 𝐓⦃f2⦄ → ∀f1. f2 ~⊚ f1 ≡ f → ∀f1a,f1b. f1a ⋓ f1b ≡ f1 →
 659                    ∃∃fa,fb. f2 ~⊚ f1a ≡ fa & f2 ~⊚ f1b ≡ fb & fa ⋓ fb ≡ f.
 660 @isfin_ind
 661 [ #f #Hf #f2 #Hf2 #f1 #Hf #f1a #f1b #Hf1
 662   lapply (coafter_fwd_isid2 … Hf ??) -Hf // #H2f1
 663   elim (sor_inv_isid3 … Hf1) -Hf1 //
 664   /3 width=5 by coafter_isid_dx, sor_refl, ex3_2_intro/
 665 | #f #_ #IH #f2 #Hf2 #f1 #H1 #f1a #f1b #H2
 666   elim (coafter_inv_xxp … H1) -H1 [1,3: * |*: // ]
 667   [ #g2 #g1 #Hf #Hgf2 #Hgf1
 668     elim (sor_inv_xxp … H2) -H2 [ |*: // ] #ga #gb #Hg1
 669     lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 670     elim (IH … Hf … Hg1) // -f1 -g1 -IH -Hg2
 671     /3 width=11 by coafter_refl, sor_pp, ex3_2_intro/
 672   | #g2 #Hf #Hgf2
 673     lapply (istot_inv_next … Hf2 … Hgf2) -Hf2 #Hg2
 674     elim (IH … Hf … H2) // -f1 -IH -Hg2
 675     /3 width=11 by coafter_next, sor_pp, ex3_2_intro/
 676   ]
 677 | #f #_ #IH #f2 #Hf2 #f1 #H1 #f1a #f1b #H2
 678   elim (coafter_inv_xxn … H1) -H1 [ |*: // ] #g2 #g1 #Hf #Hgf2 #Hgf1
 679   lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 680   elim (sor_inv_xxn … H2) -H2 [1,3,4: * |*: // ] #ga #gb #Hg1
 681   elim (IH … Hf … Hg1) // -f1 -g1 -IH -Hg2
 682   /3 width=11 by coafter_refl, coafter_push, sor_np, sor_pn, sor_nn, ex3_2_intro/
 683 ]
 684 qed-.
 685
 686 (* Properties with after ****************************************************)
 687 (*
 688 corec theorem coafter_trans1: ∀f0,f3,f4. f0 ~⊚ f3 ≡ f4 →
 689                             ∀f1,f2. f1 ~⊚ f2 ≡ f0 →
 690                             ∀f. f2 ~⊚ f3 ≡ f → f1 ~⊚ f ≡ f4.
 691 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 692 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 693   cases (coafter_inv_xxp … Hg0 … H0) -g0
 694   #f1 #f2 #Hf0 #H1 #H2
 695   cases (coafter_inv_ppx … Hg … H2 H3) -g2 -g3
 696   #f #Hf #H /3 width=7 by coafter_refl/
 697 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 698   cases (coafter_inv_xxp … Hg0 … H0) -g0
 699   #f1 #f2 #Hf0 #H1 #H2
 700   cases (coafter_inv_pnx … Hg … H2 H3) -g2 -g3
 701   #f #Hf #H /3 width=7 by coafter_push/
 702 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 703   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 704   [ #f1 #f2 #Hf0 #H1 #H2
 705     cases (coafter_inv_nxx … Hg … H2) -g2
 706     #f #Hf #H /3 width=7 by coafter_push/
 707   | #f1 #Hf0 #H1 /3 width=6 by coafter_next/
 708   ]
 709 ]
 710 qed-.
 711
 712 corec theorem coafter_trans2: ∀f1,f0,f4. f1 ~⊚ f0 ≡ f4 →
 713                             ∀f2, f3. f2 ~⊚ f3 ≡ f0 →
 714                             ∀f. f1 ~⊚ f2 ≡ f → f ~⊚ f3 ≡ f4.
 715 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 716 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 717   cases (coafter_inv_xxp … Hg0 … H0) -g0
 718   #f2 #f3 #Hf0 #H2 #H3
 719   cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 720   #f #Hf #H /3 width=7 by coafter_refl/
 721 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 722   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 723   [ #f2 #f3 #Hf0 #H2 #H3
 724     cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 725     #f #Hf #H /3 width=7 by coafter_push/
 726   | #f2 #Hf0 #H2
 727     cases (coafter_inv_pnx … Hg … H1 H2) -g1 -g2
 728     #f #Hf #H /3 width=6 by coafter_next/
 729   ]
 730 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 731   cases (coafter_inv_nxx … Hg … H1) -g1
 732   #f #Hg #H /3 width=6 by coafter_next/
 733 ]
 734 qed-.
 735 *)