matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_coafter.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rcoafter_3.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "ground_2/relocation/rtmap_istot.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive coafter: relation3 rtmap rtmap rtmap ≝
  22 | coafter_refl: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  23                 ↑f1 = g1 → ↑f2 = g2 → ↑f = g → coafter g1 g2 g
  24 | coafter_push: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  25                 ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → coafter g1 g2 g
  26 | coafter_next: ∀f1,f2,f,g1,g. coafter f1 f2 f →
  27                 ⫯f1 = g1 → ↑f = g → coafter g1 f2 g
  28 .
  29
  30 interpretation "relational co-composition (rtmap)"
  31    'RCoAfter f1 f2 f = (coafter f1 f2 f).
  32
  33 definition H_coafter_inj: predicate rtmap ≝
  34                           λf1. 𝐓⦃f1⦄ →
  35                           ∀f,f21,f22. f1 ~⊚ f21 ≡ f → f1 ~⊚ f22 ≡ f → f21 ≗ f22.
  36
  37 definition H_coafter_fwd_isid2: predicate rtmap ≝
  38                                 λf1. ∀f2,f. f1 ~⊚ f2 ≡ f → 𝐓⦃f1⦄ → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 lemma coafter_inv_ppx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  43                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  44 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  45 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  46   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  47   /2 width=3 by ex2_intro/
  48 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  49   elim (discr_push_next … Hx2)
  50 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  51   elim (discr_push_next … Hx1)
  52 ]
  53 qed-.
  54
  55 lemma coafter_inv_pnx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  56                        ∃∃f. f1 ~⊚ f2 ≡ f & ⫯f = g.
  57 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  58 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  59   elim (discr_next_push … Hx2)
  60 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  61   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  62   /2 width=3 by ex2_intro/
  63 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  64   elim (discr_push_next … Hx1)
  65 ]
  66 qed-.
  67
  68 lemma coafter_inv_nxx: ∀g1,f2,g. g1 ~⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  69                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  70 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  71 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  72   elim (discr_next_push … Hx1)
  73 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  74   elim (discr_next_push … Hx1)
  75 | #g #Hf #H1 #H #x1 #Hx1 destruct
  76   >(injective_next … Hx1) -x1
  77   /2 width=3 by ex2_intro/
  78 ]
  79 qed-.
  80
  81 (* Advanced inversion lemmas ************************************************)
  82
  83 lemma coafter_inv_ppp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  84                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ~⊚ f2 ≡ f.
  85 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  86 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  87 <(injective_push … Hx) -f //
  88 qed-.
  89
  90 lemma coafter_inv_ppn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  91                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  92 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  93 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  94 elim (discr_push_next … Hx)
  95 qed-.
  96
  97 lemma coafter_inv_pnn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  98                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ~⊚ f2 ≡ f.
  99 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 100 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 101 <(injective_next … Hx) -f //
 102 qed-.
 103
 104 lemma coafter_inv_pnp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 105                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
 106 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 107 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 108 elim (discr_next_push … Hx)
 109 qed-.
 110
 111 lemma coafter_inv_nxp: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 112                        ∀f1,f. ⫯f1 = g1 → ↑f = g → f1 ~⊚ f2 ≡ f.
 113 #g1 #f2 #g #Hg #f1 #f #H1 #H
 114 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 115 <(injective_push … Hx) -f //
 116 qed-.
 117
 118 lemma coafter_inv_nxn: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 119                        ∀f1,f. ⫯f1 = g1 → ⫯f = g → ⊥.
 120 #g1 #f2 #g #Hg #f1 #f #H1 #H
 121 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 122 elim (discr_push_next … Hx)
 123 qed-.
 124
 125 lemma coafter_inv_pxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 126                        ∀f1,f. ↑f1 = g1 → ↑f = g →
 127                        ∃∃f2. f1 ~⊚ f2 ≡ f & ↑f2 = g2.
 128 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 129 [ lapply (coafter_inv_ppp … Hg … H1 H2 H) -g1 -g /2 width=3 by ex2_intro/
 130 | elim (coafter_inv_pnp … Hg … H1 H2 H)
 131 ]
 132 qed-.
 133
 134 lemma coafter_inv_pxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 135                        ∀f1,f. ↑f1 = g1 → ⫯f = g →
 136                        ∃∃f2. f1 ~⊚ f2 ≡ f & ⫯f2 = g2.
 137 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 138 [ elim (coafter_inv_ppn … Hg … H1 H2 H)
 139 | lapply (coafter_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 140 ]
 141 qed-.
 142
 143 lemma coafter_inv_xxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ⫯f = g →
 144                        ∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2.
 145 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 146 [ elim (coafter_inv_pxn … Hg … H1 H) -g /2 width=5 by ex3_2_intro/
 147 | elim (coafter_inv_nxn … Hg … H1 H)
 148 ]
 149 qed-.
 150
 151 lemma coafter_inv_xxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ↑f = g →
 152                        (∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2) ∨
 153                        ∃∃f1. f1 ~⊚ g2 ≡ f & ⫯f1 = g1.
 154 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 155 [ elim (coafter_inv_pxp … Hg … H1 H) -g
 156   /3 width=5 by or_introl, ex3_2_intro/
 157 | /4 width=5 by coafter_inv_nxp, or_intror, ex2_intro/
 158 ]
 159 qed-.
 160
 161 lemma coafter_inv_pxx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 162                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 163                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 164 #g1 #g2 #g #Hg #f1 #H1 elim (pn_split g2) * #f2 #H2
 165 [ elim (coafter_inv_ppx … Hg … H1 H2) -g1
 166   /3 width=5 by or_introl, ex3_2_intro/
 167 | elim (coafter_inv_pnx … Hg … H1 H2) -g1
 168   /3 width=5 by or_intror, ex3_2_intro/
 169 ]
 170 qed-.
 171
 172 (* Basic properties *********************************************************)
 173
 174 corec lemma coafter_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ~⊚ f1 ≡ f).
 175 #f1 #f #f2 * -f2 -f1 -f
 176 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 177 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_refl/
 178 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_push/
 179 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by coafter_next/
 180 ]
 181 qed-.
 182
 183 lemma coafter_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ~⊚ f1 ≡ f).
 184 #f1 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back2/
 185 qed-.
 186
 187 corec lemma coafter_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ~⊚ f1 ≡ f).
 188 #f2 #f #f1 * -f2 -f1 -f
 189 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 190 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by coafter_refl/
 191 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by coafter_push/
 192 | @(coafter_next … H2 H) /2 width=5 by/
 193 ]
 194 qed-.
 195
 196 lemma coafter_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ~⊚ f1 ≡ f).
 197 #f2 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back1/
 198 qed-.
 199
 200 corec lemma coafter_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ~⊚ f1 ≡ f).
 201 #f2 #f1 #f * -f2 -f1 -f
 202 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 203 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by coafter_refl/
 204 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by coafter_push/
 205 | cases (eq_inv_px …  H0 …  H01) -g01 /3 width=5 by coafter_next/
 206 ]
 207 qed-.
 208
 209 lemma coafter_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ~⊚ f1 ≡ f).
 210 #f2 #f1 @eq_repl_sym /2 width=3 by coafter_eq_repl_back0/
 211 qed-.
 212
 213 (* Main properties **********************************************************)
 214 (*
 215 corec theorem coafter_trans1: ∀f0,f3,f4. f0 ~⊚ f3 ≡ f4 →
 216                             ∀f1,f2. f1 ~⊚ f2 ≡ f0 →
 217                             ∀f. f2 ~⊚ f3 ≡ f → f1 ~⊚ f ≡ f4.
 218 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 219 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 220   cases (coafter_inv_xxp … Hg0 … H0) -g0
 221   #f1 #f2 #Hf0 #H1 #H2
 222   cases (coafter_inv_ppx … Hg … H2 H3) -g2 -g3
 223   #f #Hf #H /3 width=7 by coafter_refl/
 224 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 225   cases (coafter_inv_xxp … Hg0 … H0) -g0
 226   #f1 #f2 #Hf0 #H1 #H2
 227   cases (coafter_inv_pnx … Hg … H2 H3) -g2 -g3
 228   #f #Hf #H /3 width=7 by coafter_push/
 229 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 230   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 231   [ #f1 #f2 #Hf0 #H1 #H2
 232     cases (coafter_inv_nxx … Hg … H2) -g2
 233     #f #Hf #H /3 width=7 by coafter_push/
 234   | #f1 #Hf0 #H1 /3 width=6 by coafter_next/
 235   ]
 236 ]
 237 qed-.
 238
 239 corec theorem coafter_trans2: ∀f1,f0,f4. f1 ~⊚ f0 ≡ f4 →
 240                             ∀f2, f3. f2 ~⊚ f3 ≡ f0 →
 241                             ∀f. f1 ~⊚ f2 ≡ f → f ~⊚ f3 ≡ f4.
 242 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 243 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 244   cases (coafter_inv_xxp … Hg0 … H0) -g0
 245   #f2 #f3 #Hf0 #H2 #H3
 246   cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 247   #f #Hf #H /3 width=7 by coafter_refl/
 248 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 249   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 250   [ #f2 #f3 #Hf0 #H2 #H3
 251     cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 252     #f #Hf #H /3 width=7 by coafter_push/
 253   | #f2 #Hf0 #H2
 254     cases (coafter_inv_pnx … Hg … H1 H2) -g1 -g2
 255     #f #Hf #H /3 width=6 by coafter_next/
 256   ]
 257 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 258   cases (coafter_inv_nxx … Hg … H1) -g1
 259   #f #Hg #H /3 width=6 by coafter_next/
 260 ]
 261 qed-.
 262 *)
 263 (* Main inversion lemmas ****************************************************)
 264
 265 corec theorem coafter_mono: ∀f1,f2,x,y. f1 ~⊚ f2 ≡ x → f1 ~⊚ f2 ≡ y → x ≗ y.
 266 #f1 #f2 #x #y * -f1 -f2 -x
 267 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 268 [ cases (coafter_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 269 | cases (coafter_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 270 | cases (coafter_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_push/
 271 ]
 272 qed-.
 273
 274 lemma coafter_mono_eq: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 275                        f1 ≗ g1 → f2 ≗ g2 → f ≗ g.
 276 /4 width=4 by coafter_mono, coafter_eq_repl_back1, coafter_eq_repl_back2/ qed-.
 277
 278 (* Properties on tls ********************************************************)
 279
 280 lemma coafter_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 281                    f1 ~⊚ f2 ≡ f → ⫱*[n]f1 ~⊚ f2 ≡ ⫱*[n]f.
 282 #n elim n -n //
 283 #n #IH #f1 #f2 #f #Hf1 #Hf
 284 cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ] #g1 #Hg1 #H1
 285 cases (coafter_inv_nxx … Hf … H1) -Hf /2 width=1 by/
 286 qed.
 287
 288 (* Properties on isid *******************************************************)
 289
 290 corec lemma coafter_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ~⊚ f2 ≡ f2.
 291 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 292 /3 width=7 by coafter_push, coafter_refl/
 293 qed.
 294
 295 corec lemma coafter_isid_dx: ∀f2,f. 𝐈⦃f2⦄ → 𝐈⦃f⦄ → ∀f1. f1 ~⊚ f2 ≡ f.
 296 #f2 #f * -f2 #f2 #g2 #Hf2 #H2 * -f #f #g #Hf #H #f1 cases (pn_split f1) * #g1 #H1
 297 [ /3 width=7 by coafter_refl/
 298 | @(coafter_next … H1 … H) /3 width=3 by isid_push/
 299 ]
 300 qed.
 301
 302 (* Inversion lemmas on isid *************************************************)
 303
 304 lemma coafter_isid_inv_sn: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f1⦄ → f2 ≗ f.
 305 /3 width=6 by coafter_isid_sn, coafter_mono/ qed-.
 306
 307 lemma coafter_isid_inv_dx: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f2⦄ → 𝐈⦃f⦄.
 308 /4 width=4 by eq_id_isid, coafter_isid_dx, coafter_mono/ qed-.
 309 (*
 310 (* Properties on isuni ******************************************************)
 311
 312 lemma coafter_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ~⊚ ⫯f2 ≡ ⫯f1.
 313 #f1 #f2 #Hf2 #H elim H -H
 314 /5 width=7 by coafter_isid_dx, coafter_eq_repl_back2, coafter_next, coafter_push, eq_push_inv_isid/
 315 qed.
 316
 317 lemma coafter_uni_next2: ∀f2. 𝐔⦃f2⦄ → ∀f1,f. ⫯f2 ~⊚ f1 ≡ f → f2 ~⊚ ⫯f1 ≡ f.
 318 #f2 #H elim H -f2
 319 [ #f2 #Hf2 #f1 #f #Hf
 320   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 321   /4 width=7 by coafter_isid_inv_sn, coafter_isid_sn, coafter_eq_repl_back0, eq_next/
 322 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 323   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 324   /3 width=5 by coafter_next/
 325 ]
 326 qed.
 327
 328 (* Properties on uni ********************************************************)
 329
 330 lemma coafter_uni: ∀n1,n2. 𝐔❴n1❵ ~⊚ 𝐔❴n2❵ ≡ 𝐔❴n1+n2❵.
 331 @nat_elim2
 332 /4 width=5 by coafter_uni_next2, coafter_isid_sn, coafter_isid_dx, coafter_next/
 333 qed.
 334
 335 (* Forward lemmas on at *****************************************************)
 336
 337 lemma coafter_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ~⊚ f1 ≡ f →
 338                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 339 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 340 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 341   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 342 | elim (at_inv_xxp … Hf) -Hf //
 343   #g #H1 #H
 344 ]
 345 [2: elim (coafter_inv_xxn … Hf21 … H) -f *
 346     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 347 |*: elim (coafter_inv_xxp … Hf21 … H) -f
 348     #g2 #g1 #Hg21 #H2 #H1
 349 ]
 350 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 351 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 352 qed-.
 353
 354 lemma coafter_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 355                     ∀f. f2 ~⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 356 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 357 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 358   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 359   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 360     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 361     [ elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 362     | elim (coafter_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 363     ]
 364   | elim (coafter_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 365   ]
 366 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 367   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 368   elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 369 ]
 370 qed-.
 371
 372 lemma coafter_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 373                      ∀f2. f2 ~⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 374 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (coafter_at_fwd … Hf … H) -f
 375 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 376 qed-.
 377
 378 lemma coafter_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 379                      ∀f1. f2 ~⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 380 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 381 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 382   #g [ #j1 ] #Hg [ #H01 ] #H00
 383   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 384   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 385   [ elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 386   | elim (coafter_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 387   | elim (coafter_inv_nxp … Hf1 … H20 H00)
 388   | /4 width=9 by coafter_inv_nxn, at_next/
 389   ]
 390 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 391   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 392   elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 393 ]
 394 qed-.
 395
 396 (* Properties with at *******************************************************)
 397
 398 lemma coafter_uni_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 399                     ∀f. f2 ~⊚ 𝐔❴i1❵ ≡ f → 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f.
 400 #i2 elim i2 -i2
 401 [ #i1 #f2 #Hf2 #f #Hf
 402   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 403   lapply (coafter_isid_inv_dx … Hf ?) -Hf
 404   /3 width=3 by coafter_isid_sn, coafter_eq_repl_back0/
 405 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 406   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 407   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 408     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 409     /3 width=5 by coafter_next/
 410   | #g2 #Hg2 #H2 destruct
 411     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 412     /3 width=5 by coafter_next/
 413   ]
 414 ]
 415 qed.
 416
 417 lemma coafter_uni_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 418                     ∀f. 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f → f2 ~⊚ 𝐔❴i1❵ ≡ f.
 419 #i2 elim i2 -i2
 420 [ #i1 #f2 #Hf2 #f #Hf
 421   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 422   lapply (coafter_isid_inv_sn … Hf ?) -Hf
 423   /3 width=3 by coafter_isid_dx, coafter_eq_repl_back0/
 424 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 425   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 426   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 427   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by coafter_push/
 428   | #g2 #Hg2 #H2 destruct /3 width=5 by coafter_next/
 429   ]
 430 ]
 431 qed-.
 432
 433 lemma coafter_uni_succ_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 434                          ∀f. f2 ~⊚ 𝐔❴⫯i1❵ ≡ f → 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f.
 435 #i2 elim i2 -i2
 436 [ #i1 #f2 #Hf2 #f #Hf
 437   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 438   elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 439   lapply (coafter_isid_inv_dx … Hg ?) -Hg
 440   /4 width=5 by coafter_isid_sn, coafter_eq_repl_back0, coafter_next/
 441 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 442   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 443   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 444     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 445     /3 width=5 by coafter_next/
 446   | #g2 #Hg2 #H2 destruct
 447     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 448     /3 width=5 by coafter_next/
 449   ]
 450 ]
 451 qed.
 452
 453 lemma coafter_uni_succ_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 454                          ∀f. 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f → f2 ~⊚ 𝐔❴⫯i1❵ ≡ f.
 455 #i2 elim i2 -i2
 456 [ #i1 #f2 #Hf2 #f #Hf
 457   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 458   elim (coafter_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 459   lapply (coafter_isid_inv_sn … Hg ?) -Hg
 460   /4 width=7 by coafter_isid_dx, coafter_eq_repl_back0, coafter_push/
 461 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 462   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 463   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 464   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by coafter_push/
 465   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by coafter_next/
 466   ]
 467 ]
 468 qed-.
 469
 470 lemma coafter_uni_one_dx: ∀f2,f. ↑f2 ~⊚ 𝐔❴⫯O❵ ≡ f → 𝐔❴⫯O❵ ~⊚ f2 ≡ f.
 471 #f2 #f #H @(coafter_uni_succ_dx … (↑f2)) /2 width=3 by at_refl/
 472 qed.
 473
 474 lemma coafter_uni_one_sn: ∀f1,f. 𝐔❴⫯O❵ ~⊚ f1 ≡ f → ↑f1 ~⊚ 𝐔❴⫯O❵ ≡ f.
 475 /3 width=3 by coafter_uni_succ_sn, at_refl/ qed-.
 476 *)
 477 (* Forward lemmas with istot ************************************************)
 478 (*
 479 lemma coafter_istot_fwd: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 480 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 481 #i2 #Hf1 elim (Hf2 i2) -Hf2
 482 /3 width=7 by coafter_fwd_at, ex_intro/
 483 qed-.
 484
 485 lemma coafter_fwd_istot_dx: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 486 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 487 #i2 #Hf elim (coafter_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 488 qed-.
 489
 490 lemma coafter_fwd_istot_sn: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 491 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 492 #i #Hf elim (coafter_at_fwd … Hf … H) -f
 493 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 494 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 495 qed-.
 496
 497 lemma coafter_inv_istot: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 498 /3 width=4 by coafter_fwd_istot_sn, coafter_fwd_istot_dx, conj/ qed-.
 499
 500 lemma coafter_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ~⊚ f1 ≡ f →
 501                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 502 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 503 /3 width=8 by coafter_fwd_at, ex2_intro/
 504 qed-.
 505
 506 lemma coafter_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 507 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 508 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 509 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 510 #i0 #Hf1 lapply (at_increasing … Hf1)
 511 #Hi20 lapply (coafter_fwd_at2 … i0 … Hf1 … Hf) -Hf
 512 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 513 qed-.
 514
 515 lemma coafter_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 516 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 517 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 518 #i1 #i2 #Hi12 elim (coafter_at1_fwd … Hi12 … Hf) -f1
 519 /3 width=8 by at_inj, at_eq_repl_back/
 520 qed-.
 521 *)
 522 corec fact coafter_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1.
 523 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 524 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 525 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 526 cases (H2g1 0) #n #Hn
 527 cases (coafter_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 528 [ cases (coafter_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 529   @(eq_push … H21 H22) -f21 -f22
 530 | cases (coafter_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 531   @(eq_next … H21 H22) -f21 -f22
 532 ]
 533 @(coafter_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -coafter_inj_O_aux
 534 /2 width=1 by coafter_tls, istot_tls, at_pxx_tls/
 535 qed-.
 536
 537 fact coafter_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1) →
 538                       ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_inj f1.
 539 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 540 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 541 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 542 elim (coafter_inv_nxx … H1f … H1) -H1f #g #H1g #H
 543 lapply (coafter_inv_nxp … H2f … H1 H) -f #H2g
 544 /3 width=6 by istot_inv_next/
 545 qed-.
 546
 547 theorem coafter_inj: ∀f1. H_coafter_inj f1.
 548 #f1 #H cases (H 0) /3 width=7 by coafter_inj_aux, coafter_inj_O_aux/
 549 qed-.
 550
 551 corec fact coafter_fwd_isid2_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 →
 552                                     H_coafter_fwd_isid2 f1.
 553 #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 554 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 555 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 556 cases (H2g1 0) #n #Hn
 557 cases (coafter_inv_pxx … H … H1) -H * #g2 #g #H #H2 #H0
 558 [ lapply (isid_inv_push … Hf … H0) -Hf #Hg
 559   @(isid_push … H2)
 560   /3 width=7 by coafter_tls, istot_tls, at_pxx_tls, isid_tls/
 561 | cases (isid_inv_next … Hf … H0)
 562 ]
 563 qed-.
 564
 565 fact coafter_fwd_isid2_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_fwd_isid2 f1) →
 566                             ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_fwd_isid2 f1.
 567 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 568 #i2 #IH #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 569 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
 570 elim (coafter_inv_nxx … H … H1) -H #g #Hg #H0
 571 @(IH … Hg1 … Hg) /2 width=3 by istot_inv_next, isid_inv_push/ (**) (* full auto fails *)
 572 qed-.
 573
 574 lemma coafter_fwd_isid2: ∀f1. H_coafter_fwd_isid2 f1.
 575 #f1 #f2 #f #Hf #H cases (H 0)
 576 /3 width=7 by coafter_fwd_isid2_aux, coafter_fwd_isid2_O_aux/
 577 qed-.
 578
 579 lemma coafter_inv_sor: ∀f. 𝐅⦃f⦄ → ∀f2. 𝐓⦃f2⦄ → ∀f1. f2 ~⊚ f1 ≡ f → ∀fa,fb. fa ⋓ fb ≡ f →
 580                        ∃∃f1a,f1b. f2 ~⊚ f1a ≡ fa & f2 ~⊚ f1b ≡ fb & f1a ⋓ f1b ≡ f1.
 581 @isfin_ind
 582 [ #f #Hf #f2 #Hf2 #f1 #H1f #fa #fb #H2f
 583   elim (sor_inv_isid3 … H2f) -H2f //
 584   lapply (coafter_fwd_isid2 … H1f ??) -H1f //
 585   /3 width=5 by ex3_2_intro, coafter_isid_dx, sor_isid/
 586 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 587   elim (sor_inv_xxp … H2) -H2 [ |*: // ] #ga #gb #H2f
 588   elim (coafter_inv_xxp … H1) -H1 [1,3: * |*: // ] #g2 [ #g1 ] #H1f #Hgf2
 589   [ lapply (istot_inv_push … Hf2 … Hgf2) | lapply (istot_inv_next … Hf2 … Hgf2) ] -Hf2 #Hg2
 590   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 591   /3 width=11 by sor_pp, ex3_2_intro, coafter_refl, coafter_next/
 592 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 593   elim (coafter_inv_xxn … H1) -H1 [ |*: // ] #g2 #g1 #H1f #Hgf2
 594   lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 595   elim (sor_inv_xxn … H2) -H2 [1,3,4: * |*: // ] #ga #gb #H2f
 596   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 597   /3 width=11 by sor_np, sor_pn, sor_nn, ex3_2_intro, coafter_refl, coafter_push/
 598 ]
 599 qed-.