matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_coafter.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/rcoafter_3.ma".
  16 include "ground_2/relocation/rtmap_sor.ma".
  17 include "ground_2/relocation/rtmap_istot.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive coafter: relation3 rtmap rtmap rtmap ≝
  22 | coafter_refl: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  23                 ↑f1 = g1 → ↑f2 = g2 → ↑f = g → coafter g1 g2 g
  24 | coafter_push: ∀f1,f2,f,g1,g2,g. coafter f1 f2 f →
  25                 ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → coafter g1 g2 g
  26 | coafter_next: ∀f1,f2,f,g1,g. coafter f1 f2 f →
  27                 ⫯f1 = g1 → ↑f = g → coafter g1 f2 g
  28 .
  29
  30 interpretation "relational co-composition (rtmap)"
  31    'RCoAfter f1 f2 f = (coafter f1 f2 f).
  32
  33 definition H_coafter_inj: predicate rtmap ≝
  34                           λf1. 𝐓⦃f1⦄ →
  35                           ∀f,f21,f22. f1 ~⊚ f21 ≡ f → f1 ~⊚ f22 ≡ f → f21 ≗ f22.
  36
  37 definition H_coafter_fwd_isid2: predicate rtmap ≝
  38                                 λf1. ∀f2,f. f1 ~⊚ f2 ≡ f → 𝐓⦃f1⦄ → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
  39
  40 definition H_coafter_isfin2_fwd: predicate rtmap ≝
  41                                  λf1. ∀f2. 𝐅⦃f2⦄ → 𝐓⦃f1⦄ → ∀f. f1 ~⊚ f2 ≡ f →  𝐅⦃f⦄.
  42
  43 (* Basic inversion lemmas ***************************************************)
  44
  45 lemma coafter_inv_ppx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  46                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  47 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  48 [ #g2 #g #Hf #H1 #H2 #H #x1 #x2 #Hx1 #Hx2 destruct
  49   >(injective_push … Hx1) >(injective_push … Hx2) -x2 -x1
  50   /2 width=3 by ex2_intro/
  51 | #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  52   elim (discr_push_next … Hx2)
  53 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  54   elim (discr_push_next … Hx1)
  55 ]
  56 qed-.
  57
  58 lemma coafter_inv_pnx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  59                        ∃∃f. f1 ~⊚ f2 ≡ f & ⫯f = g.
  60 #g1 #g2 #g * -g1 -g2 -g #f1 #f2 #f #g1
  61 [ #g2 #g #_ #_ #H2 #_ #x1 #x2 #_ #Hx2 destruct
  62   elim (discr_next_push … Hx2)
  63 | #g2 #g #Hf #H1 #H2 #H3 #x1 #x2 #Hx1 #Hx2 destruct
  64   >(injective_push … Hx1) >(injective_next … Hx2) -x2 -x1
  65   /2 width=3 by ex2_intro/
  66 | #g #_ #H1 #_ #x1 #x2 #Hx1 #_ destruct
  67   elim (discr_push_next … Hx1)
  68 ]
  69 qed-.
  70
  71 lemma coafter_inv_nxx: ∀g1,f2,g. g1 ~⊚ f2 ≡ g → ∀f1. ⫯f1 = g1 →
  72                        ∃∃f. f1 ~⊚ f2 ≡ f & ↑f = g.
  73 #g1 #f2 #g * -g1 -f2 -g #f1 #f2 #f #g1
  74 [ #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  75   elim (discr_next_push … Hx1)
  76 | #g2 #g #_ #H1 #_ #_ #x1 #Hx1 destruct
  77   elim (discr_next_push … Hx1)
  78 | #g #Hf #H1 #H #x1 #Hx1 destruct
  79   >(injective_next … Hx1) -x1
  80   /2 width=3 by ex2_intro/
  81 ]
  82 qed-.
  83
  84 (* Advanced inversion lemmas ************************************************)
  85
  86 lemma coafter_inv_ppp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  87                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ~⊚ f2 ≡ f.
  88 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  89 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  90 <(injective_push … Hx) -f //
  91 qed-.
  92
  93 lemma coafter_inv_ppn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
  94                        ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ⫯f = g → ⊥.
  95 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
  96 elim (coafter_inv_ppx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
  97 elim (discr_push_next … Hx)
  98 qed-.
  99
 100 lemma coafter_inv_pnn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 101                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ~⊚ f2 ≡ f.
 102 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 103 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 104 <(injective_next … Hx) -f //
 105 qed-.
 106
 107 lemma coafter_inv_pnp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 108                        ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
 109 #g1 #g2 #g #Hg #f1 #f2 #f #H1 #H2 #H
 110 elim (coafter_inv_pnx … Hg … H1 H2) -g1 -g2 #x #Hf #Hx destruct
 111 elim (discr_next_push … Hx)
 112 qed-.
 113
 114 lemma coafter_inv_nxp: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 115                        ∀f1,f. ⫯f1 = g1 → ↑f = g → f1 ~⊚ f2 ≡ f.
 116 #g1 #f2 #g #Hg #f1 #f #H1 #H
 117 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 118 <(injective_push … Hx) -f //
 119 qed-.
 120
 121 lemma coafter_inv_nxn: ∀g1,f2,g. g1 ~⊚ f2 ≡ g →
 122                        ∀f1,f. ⫯f1 = g1 → ⫯f = g → ⊥.
 123 #g1 #f2 #g #Hg #f1 #f #H1 #H
 124 elim (coafter_inv_nxx … Hg … H1) -g1 #x #Hf #Hx destruct
 125 elim (discr_push_next … Hx)
 126 qed-.
 127
 128 lemma coafter_inv_pxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 129                        ∀f1,f. ↑f1 = g1 → ↑f = g →
 130                        ∃∃f2. f1 ~⊚ f2 ≡ f & ↑f2 = g2.
 131 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 132 [ lapply (coafter_inv_ppp … Hg … H1 H2 H) -g1 -g /2 width=3 by ex2_intro/
 133 | elim (coafter_inv_pnp … Hg … H1 H2 H)
 134 ]
 135 qed-.
 136
 137 lemma coafter_inv_pxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 138                        ∀f1,f. ↑f1 = g1 → ⫯f = g →
 139                        ∃∃f2. f1 ~⊚ f2 ≡ f & ⫯f2 = g2.
 140 #g1 #g2 #g #Hg #f1 #f #H1 #H elim (pn_split g2) * #f2 #H2
 141 [ elim (coafter_inv_ppn … Hg … H1 H2 H)
 142 | lapply (coafter_inv_pnn … Hg … H1 … H) -g1 -g /2 width=3 by ex2_intro/
 143 ]
 144 qed-.
 145
 146 lemma coafter_inv_xxn: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ⫯f = g →
 147                        ∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ⫯f2 = g2.
 148 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 149 [ elim (coafter_inv_pxn … Hg … H1 H) -g /2 width=5 by ex3_2_intro/
 150 | elim (coafter_inv_nxn … Hg … H1 H)
 151 ]
 152 qed-.
 153
 154 lemma coafter_inv_xxp: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f. ↑f = g →
 155                        (∃∃f1,f2. f1 ~⊚ f2 ≡ f & ↑f1 = g1 & ↑f2 = g2) ∨
 156                        ∃∃f1. f1 ~⊚ g2 ≡ f & ⫯f1 = g1.
 157 #g1 #g2 #g #Hg #f #H elim (pn_split g1) * #f1 #H1
 158 [ elim (coafter_inv_pxp … Hg … H1 H) -g
 159   /3 width=5 by or_introl, ex3_2_intro/
 160 | /4 width=5 by coafter_inv_nxp, or_intror, ex2_intro/
 161 ]
 162 qed-.
 163
 164 lemma coafter_inv_pxx: ∀g1,g2,g. g1 ~⊚ g2 ≡ g → ∀f1. ↑f1 = g1 →
 165                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ↑f2 = g2 & ↑f = g) ∨
 166                        (∃∃f2,f. f1 ~⊚ f2 ≡ f & ⫯f2 = g2 & ⫯f = g).
 167 #g1 #g2 #g #Hg #f1 #H1 elim (pn_split g2) * #f2 #H2
 168 [ elim (coafter_inv_ppx … Hg … H1 H2) -g1
 169   /3 width=5 by or_introl, ex3_2_intro/
 170 | elim (coafter_inv_pnx … Hg … H1 H2) -g1
 171   /3 width=5 by or_intror, ex3_2_intro/
 172 ]
 173 qed-.
 174
 175 (* Basic properties *********************************************************)
 176
 177 corec lemma coafter_eq_repl_back2: ∀f1,f. eq_repl_back (λf2. f2 ~⊚ f1 ≡ f).
 178 #f1 #f #f2 * -f2 -f1 -f
 179 #f21 #f1 #f #g21 [1,2: #g1 ] #g #Hf #H21 [1,2: #H1 ] #H #g22 #H0
 180 [ cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_refl/
 181 | cases (eq_inv_px …  H0 …  H21) -g21 /3 width=7 by coafter_push/
 182 | cases (eq_inv_nx …  H0 …  H21) -g21 /3 width=5 by coafter_next/
 183 ]
 184 qed-.
 185
 186 lemma coafter_eq_repl_fwd2: ∀f1,f. eq_repl_fwd (λf2. f2 ~⊚ f1 ≡ f).
 187 #f1 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back2/
 188 qed-.
 189
 190 corec lemma coafter_eq_repl_back1: ∀f2,f. eq_repl_back (λf1. f2 ~⊚ f1 ≡ f).
 191 #f2 #f #f1 * -f2 -f1 -f
 192 #f2 #f11 #f #g2 [1,2: #g11 ] #g #Hf #H2 [1,2: #H11 ] #H #g2 #H0
 193 [ cases (eq_inv_px …  H0 …  H11) -g11 /3 width=7 by coafter_refl/
 194 | cases (eq_inv_nx …  H0 …  H11) -g11 /3 width=7 by coafter_push/
 195 | @(coafter_next … H2 H) /2 width=5 by/
 196 ]
 197 qed-.
 198
 199 lemma coafter_eq_repl_fwd1: ∀f2,f. eq_repl_fwd (λf1. f2 ~⊚ f1 ≡ f).
 200 #f2 #f @eq_repl_sym /2 width=3 by coafter_eq_repl_back1/
 201 qed-.
 202
 203 corec lemma coafter_eq_repl_back0: ∀f1,f2. eq_repl_back (λf. f2 ~⊚ f1 ≡ f).
 204 #f2 #f1 #f * -f2 -f1 -f
 205 #f2 #f1 #f01 #g2 [1,2: #g1 ] #g01 #Hf01 #H2 [1,2: #H1 ] #H01 #g02 #H0
 206 [ cases (eq_inv_px …  H0 …  H01) -g01 /3 width=7 by coafter_refl/
 207 | cases (eq_inv_nx …  H0 …  H01) -g01 /3 width=7 by coafter_push/
 208 | cases (eq_inv_px …  H0 …  H01) -g01 /3 width=5 by coafter_next/
 209 ]
 210 qed-.
 211
 212 lemma coafter_eq_repl_fwd0: ∀f2,f1. eq_repl_fwd (λf. f2 ~⊚ f1 ≡ f).
 213 #f2 #f1 @eq_repl_sym /2 width=3 by coafter_eq_repl_back0/
 214 qed-.
 215
 216 (* Main properties **********************************************************)
 217 (*
 218 corec theorem coafter_trans1: ∀f0,f3,f4. f0 ~⊚ f3 ≡ f4 →
 219                             ∀f1,f2. f1 ~⊚ f2 ≡ f0 →
 220                             ∀f. f2 ~⊚ f3 ≡ f → f1 ~⊚ f ≡ f4.
 221 #f0 #f3 #f4 * -f0 -f3 -f4 #f0 #f3 #f4 #g0 [1,2: #g3 ] #g4
 222 [ #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 223   cases (coafter_inv_xxp … Hg0 … H0) -g0
 224   #f1 #f2 #Hf0 #H1 #H2
 225   cases (coafter_inv_ppx … Hg … H2 H3) -g2 -g3
 226   #f #Hf #H /3 width=7 by coafter_refl/
 227 | #Hf4 #H0 #H3 #H4 #g1 #g2 #Hg0 #g #Hg
 228   cases (coafter_inv_xxp … Hg0 … H0) -g0
 229   #f1 #f2 #Hf0 #H1 #H2
 230   cases (coafter_inv_pnx … Hg … H2 H3) -g2 -g3
 231   #f #Hf #H /3 width=7 by coafter_push/
 232 | #Hf4 #H0 #H4 #g1 #g2 #Hg0 #g #Hg
 233   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 234   [ #f1 #f2 #Hf0 #H1 #H2
 235     cases (coafter_inv_nxx … Hg … H2) -g2
 236     #f #Hf #H /3 width=7 by coafter_push/
 237   | #f1 #Hf0 #H1 /3 width=6 by coafter_next/
 238   ]
 239 ]
 240 qed-.
 241
 242 corec theorem coafter_trans2: ∀f1,f0,f4. f1 ~⊚ f0 ≡ f4 →
 243                             ∀f2, f3. f2 ~⊚ f3 ≡ f0 →
 244                             ∀f. f1 ~⊚ f2 ≡ f → f ~⊚ f3 ≡ f4.
 245 #f1 #f0 #f4 * -f1 -f0 -f4 #f1 #f0 #f4 #g1 [1,2: #g0 ] #g4
 246 [ #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 247   cases (coafter_inv_xxp … Hg0 … H0) -g0
 248   #f2 #f3 #Hf0 #H2 #H3
 249   cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 250   #f #Hf #H /3 width=7 by coafter_refl/
 251 | #Hf4 #H1 #H0 #H4 #g2 #g3 #Hg0 #g #Hg
 252   cases (coafter_inv_xxn … Hg0 … H0) -g0 *
 253   [ #f2 #f3 #Hf0 #H2 #H3
 254     cases (coafter_inv_ppx … Hg … H1 H2) -g1 -g2
 255     #f #Hf #H /3 width=7 by coafter_push/
 256   | #f2 #Hf0 #H2
 257     cases (coafter_inv_pnx … Hg … H1 H2) -g1 -g2
 258     #f #Hf #H /3 width=6 by coafter_next/
 259   ]
 260 | #Hf4 #H1 #H4 #f2 #f3 #Hf0 #g #Hg
 261   cases (coafter_inv_nxx … Hg … H1) -g1
 262   #f #Hg #H /3 width=6 by coafter_next/
 263 ]
 264 qed-.
 265 *)
 266 (* Main inversion lemmas ****************************************************)
 267
 268 corec theorem coafter_mono: ∀f1,f2,x,y. f1 ~⊚ f2 ≡ x → f1 ~⊚ f2 ≡ y → x ≗ y.
 269 #f1 #f2 #x #y * -f1 -f2 -x
 270 #f1 #f2 #x #g1 [1,2: #g2 ] #g #Hx #H1 [1,2: #H2 ] #H0x #Hy
 271 [ cases (coafter_inv_ppx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_push/
 272 | cases (coafter_inv_pnx … Hy … H1 H2) -g1 -g2 /3 width=8 by eq_next/
 273 | cases (coafter_inv_nxx … Hy … H1) -g1 /3 width=8 by eq_push/
 274 ]
 275 qed-.
 276
 277 lemma coafter_mono_eq: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → ∀g1,g2,g. g1 ~⊚ g2 ≡ g →
 278                        f1 ≗ g1 → f2 ≗ g2 → f ≗ g.
 279 /4 width=4 by coafter_mono, coafter_eq_repl_back1, coafter_eq_repl_back2/ qed-.
 280
 281 (* Inversion lemmas with tail ***********************************************)
 282
 283 lemma coafter_inv_tl1: ∀g2,g1,g. g2 ~⊚ ⫱g1 ≡ g →
 284                        ∃∃f. ↑g2 ~⊚ g1 ≡ f & ⫱f = g.
 285 #g2 #g1 #g elim (pn_split g1) * #f1 #H1 #H destruct
 286 [ /3 width=7 by coafter_refl, ex2_intro/
 287 | @(ex2_intro … (⫯g)) /2 width=7 by coafter_push/ (**) (* full auto fails *)
 288 ]
 289 qed-.
 290
 291 lemma coafter_inv_tl0: ∀g2,g1,g. g2 ~⊚ g1 ≡ ⫱g →
 292                        ∃∃f1. ↑g2 ~⊚ f1 ≡ g & ⫱f1 = g1.
 293 #g2 #g1 #g elim (pn_split g) * #f #H0 #H destruct
 294 [ /3 width=7 by coafter_refl, ex2_intro/
 295 | @(ex2_intro … (⫯g1)) /2 width=7 by coafter_push/ (**) (* full auto fails *)
 296 ]
 297 qed-.
 298
 299 (* Properties on tls ********************************************************)
 300
 301 lemma coafter_tls: ∀n,f1,f2,f. @⦃0, f1⦄ ≡ n →
 302                    f1 ~⊚ f2 ≡ f → ⫱*[n]f1 ~⊚ f2 ≡ ⫱*[n]f.
 303 #n elim n -n //
 304 #n #IH #f1 #f2 #f #Hf1 #Hf
 305 cases (at_inv_pxn … Hf1) -Hf1 [ |*: // ] #g1 #Hg1 #H1
 306 cases (coafter_inv_nxx … Hf … H1) -Hf /2 width=1 by/
 307 qed.
 308
 309 (* Properties on isid *******************************************************)
 310
 311 corec lemma coafter_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ~⊚ f2 ≡ f2.
 312 #f1 * -f1 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) * #g2 #H2
 313 /3 width=7 by coafter_push, coafter_refl/
 314 qed.
 315
 316 corec lemma coafter_isid_dx: ∀f2,f. 𝐈⦃f2⦄ → 𝐈⦃f⦄ → ∀f1. f1 ~⊚ f2 ≡ f.
 317 #f2 #f * -f2 #f2 #g2 #Hf2 #H2 * -f #f #g #Hf #H #f1 cases (pn_split f1) * #g1 #H1
 318 [ /3 width=7 by coafter_refl/
 319 | @(coafter_next … H1 … H) /3 width=3 by isid_push/
 320 ]
 321 qed.
 322
 323 (* Inversion lemmas on isid *************************************************)
 324
 325 lemma coafter_isid_inv_sn: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f1⦄ → f2 ≗ f.
 326 /3 width=6 by coafter_isid_sn, coafter_mono/ qed-.
 327
 328 lemma coafter_isid_inv_dx: ∀f1,f2,f. f1 ~⊚ f2 ≡ f → 𝐈⦃f2⦄ → 𝐈⦃f⦄.
 329 /4 width=4 by eq_id_isid, coafter_isid_dx, coafter_mono/ qed-.
 330 (*
 331 (* Properties on isuni ******************************************************)
 332
 333 lemma coafter_isid_isuni: ∀f1,f2. 𝐈⦃f2⦄ → 𝐔⦃f1⦄ → f1 ~⊚ ⫯f2 ≡ ⫯f1.
 334 #f1 #f2 #Hf2 #H elim H -H
 335 /5 width=7 by coafter_isid_dx, coafter_eq_repl_back2, coafter_next, coafter_push, eq_push_inv_isid/
 336 qed.
 337
 338 lemma coafter_uni_next2: ∀f2. 𝐔⦃f2⦄ → ∀f1,f. ⫯f2 ~⊚ f1 ≡ f → f2 ~⊚ ⫯f1 ≡ f.
 339 #f2 #H elim H -f2
 340 [ #f2 #Hf2 #f1 #f #Hf
 341   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 342   /4 width=7 by coafter_isid_inv_sn, coafter_isid_sn, coafter_eq_repl_back0, eq_next/
 343 | #f2 #_ #g2 #H2 #IH #f1 #f #Hf
 344   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
 345   /3 width=5 by coafter_next/
 346 ]
 347 qed.
 348
 349 (* Properties on uni ********************************************************)
 350
 351 lemma coafter_uni: ∀n1,n2. 𝐔❴n1❵ ~⊚ 𝐔❴n2❵ ≡ 𝐔❴n1+n2❵.
 352 @nat_elim2
 353 /4 width=5 by coafter_uni_next2, coafter_isid_sn, coafter_isid_dx, coafter_next/
 354 qed.
 355
 356 (* Forward lemmas on at *****************************************************)
 357
 358 lemma coafter_at_fwd: ∀i,i1,f. @⦃i1, f⦄ ≡ i → ∀f2,f1. f2 ~⊚ f1 ≡ f →
 359                     ∃∃i2. @⦃i1, f1⦄ ≡ i2 & @⦃i2, f2⦄ ≡ i.
 360 #i elim i -i [2: #i #IH ] #i1 #f #Hf #f2 #f1 #Hf21
 361 [ elim (at_inv_xxn … Hf) -Hf [1,3:* |*: // ]
 362   [1: #g #j1 #Hg #H0 #H |2,4: #g #Hg #H ]
 363 | elim (at_inv_xxp … Hf) -Hf //
 364   #g #H1 #H
 365 ]
 366 [2: elim (coafter_inv_xxn … Hf21 … H) -f *
 367     [ #g2 #g1 #Hg21 #H2 #H1 | #g2 #Hg21 #H2 ]
 368 |*: elim (coafter_inv_xxp … Hf21 … H) -f
 369     #g2 #g1 #Hg21 #H2 #H1
 370 ]
 371 [4: -Hg21 |*: elim (IH … Hg … Hg21) -g -IH ]
 372 /3 width=9 by at_refl, at_push, at_next, ex2_intro/
 373 qed-.
 374
 375 lemma coafter_fwd_at: ∀i,i2,i1,f1,f2. @⦃i1, f1⦄ ≡ i2 → @⦃i2, f2⦄ ≡ i →
 376                     ∀f. f2 ~⊚ f1 ≡ f → @⦃i1, f⦄ ≡ i.
 377 #i elim i -i [2: #i #IH ] #i2 #i1 #f1 #f2 #Hf1 #Hf2 #f #Hf
 378 [ elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 379   #g2 [ #j2 ] #Hg2 [ #H22 ] #H20
 380   [ elim (at_inv_xxn … Hf1 … H22) -i2 *
 381     #g1 [ #j1 ] #Hg1 [ #H11 ] #H10
 382     [ elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /3 width=7 by at_push/
 383     | elim (coafter_inv_pnx … Hf … H20 H10) -f1 -f2 /3 width=6 by at_next/
 384     ]
 385   | elim (coafter_inv_nxx … Hf … H20) -f2 /3 width=7 by at_next/
 386   ]
 387 | elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H22 #H20
 388   elim (at_inv_xxp … Hf1 … H22) -i2 #g1 #H11 #H10
 389   elim (coafter_inv_ppx … Hf … H20 H10) -f1 -f2 /2 width=2 by at_refl/
 390 ]
 391 qed-.
 392
 393 lemma coafter_fwd_at2: ∀f,i1,i. @⦃i1, f⦄ ≡ i → ∀f1,i2. @⦃i1, f1⦄ ≡ i2 →
 394                      ∀f2. f2 ~⊚ f1 ≡ f → @⦃i2, f2⦄ ≡ i.
 395 #f #i1 #i #Hf #f1 #i2 #Hf1 #f2 #H elim (coafter_at_fwd … Hf … H) -f
 396 #j1 #H #Hf2 <(at_mono … Hf1 … H) -i1 -i2 //
 397 qed-.
 398
 399 lemma coafter_fwd_at1: ∀i,i2,i1,f,f2. @⦃i1, f⦄ ≡ i → @⦃i2, f2⦄ ≡ i →
 400                      ∀f1. f2 ~⊚ f1 ≡ f → @⦃i1, f1⦄ ≡ i2.
 401 #i elim i -i [2: #i #IH ] #i2 #i1 #f #f2 #Hf #Hf2 #f1 #Hf1
 402 [ elim (at_inv_xxn … Hf) -Hf [1,3: * |*: // ]
 403   #g [ #j1 ] #Hg [ #H01 ] #H00
 404   elim (at_inv_xxn … Hf2) -Hf2 [1,3,5,7: * |*: // ]
 405   #g2 [1,3: #j2 ] #Hg2 [1,2: #H22 ] #H20
 406   [ elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=7 by at_push/
 407   | elim (coafter_inv_pxn … Hf1 … H20 H00) -f2 -f /3 width=5 by at_next/
 408   | elim (coafter_inv_nxp … Hf1 … H20 H00)
 409   | /4 width=9 by coafter_inv_nxn, at_next/
 410   ]
 411 | elim (at_inv_xxp … Hf) -Hf // #g #H01 #H00
 412   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H21 #H20
 413   elim (coafter_inv_pxp … Hf1 … H20 H00) -f2 -f /3 width=2 by at_refl/
 414 ]
 415 qed-.
 416
 417 (* Properties with at *******************************************************)
 418
 419 lemma coafter_uni_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 420                     ∀f. f2 ~⊚ 𝐔❴i1❵ ≡ f → 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f.
 421 #i2 elim i2 -i2
 422 [ #i1 #f2 #Hf2 #f #Hf
 423   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 424   lapply (coafter_isid_inv_dx … Hf ?) -Hf
 425   /3 width=3 by coafter_isid_sn, coafter_eq_repl_back0/
 426 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 427   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 428   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 429     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 430     /3 width=5 by coafter_next/
 431   | #g2 #Hg2 #H2 destruct
 432     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 433     /3 width=5 by coafter_next/
 434   ]
 435 ]
 436 qed.
 437
 438 lemma coafter_uni_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 439                     ∀f. 𝐔❴i2❵ ~⊚ ⫱*[i2] f2 ≡ f → f2 ~⊚ 𝐔❴i1❵ ≡ f.
 440 #i2 elim i2 -i2
 441 [ #i1 #f2 #Hf2 #f #Hf
 442   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 443   lapply (coafter_isid_inv_sn … Hf ?) -Hf
 444   /3 width=3 by coafter_isid_dx, coafter_eq_repl_back0/
 445 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 446   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 447   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 448   [ #g2 #j1 #Hg2 #H1 #H2 destruct /3 width=7 by coafter_push/
 449   | #g2 #Hg2 #H2 destruct /3 width=5 by coafter_next/
 450   ]
 451 ]
 452 qed-.
 453
 454 lemma coafter_uni_succ_dx: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 455                          ∀f. f2 ~⊚ 𝐔❴⫯i1❵ ≡ f → 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f.
 456 #i2 elim i2 -i2
 457 [ #i1 #f2 #Hf2 #f #Hf
 458   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 459   elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H
 460   lapply (coafter_isid_inv_dx … Hg ?) -Hg
 461   /4 width=5 by coafter_isid_sn, coafter_eq_repl_back0, coafter_next/
 462 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 463   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 464   [ #g2 #j1 #Hg2 #H1 #H2 destruct
 465     elim (coafter_inv_pnx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 466     /3 width=5 by coafter_next/
 467   | #g2 #Hg2 #H2 destruct
 468     elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 469     /3 width=5 by coafter_next/
 470   ]
 471 ]
 472 qed.
 473
 474 lemma coafter_uni_succ_sn: ∀i2,i1,f2. @⦃i1, f2⦄ ≡ i2 →
 475                          ∀f. 𝐔❴⫯i2❵ ~⊚ ⫱*[⫯i2] f2 ≡ f → f2 ~⊚ 𝐔❴⫯i1❵ ≡ f.
 476 #i2 elim i2 -i2
 477 [ #i1 #f2 #Hf2 #f #Hf
 478   elim (at_inv_xxp … Hf2) -Hf2 // #g2 #H1 #H2 destruct
 479   elim (coafter_inv_nxx … Hf) -Hf [ |*: // ] #g #Hg #H destruct
 480   lapply (coafter_isid_inv_sn … Hg ?) -Hg
 481   /4 width=7 by coafter_isid_dx, coafter_eq_repl_back0, coafter_push/
 482 | #i2 #IH #i1 #f2 #Hf2 #f #Hf
 483   elim (coafter_inv_nxx … Hf) -Hf [2,3: // ] #g #Hg #H destruct
 484   elim (at_inv_xxn … Hf2) -Hf2 [1,3: * |*: // ]
 485   [ #g2 #j1 #Hg2 #H1 #H2 destruct <tls_xn in Hg; /3 width=7 by coafter_push/
 486   | #g2 #Hg2 #H2 destruct <tls_xn in Hg; /3 width=5 by coafter_next/
 487   ]
 488 ]
 489 qed-.
 490
 491 lemma coafter_uni_one_dx: ∀f2,f. ↑f2 ~⊚ 𝐔❴⫯O❵ ≡ f → 𝐔❴⫯O❵ ~⊚ f2 ≡ f.
 492 #f2 #f #H @(coafter_uni_succ_dx … (↑f2)) /2 width=3 by at_refl/
 493 qed.
 494
 495 lemma coafter_uni_one_sn: ∀f1,f. 𝐔❴⫯O❵ ~⊚ f1 ≡ f → ↑f1 ~⊚ 𝐔❴⫯O❵ ≡ f.
 496 /3 width=3 by coafter_uni_succ_sn, at_refl/ qed-.
 497 *)
 498 (* Forward lemmas with istot ************************************************)
 499 (*
 500 lemma coafter_istot_fwd: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f2⦄ → 𝐓⦃f1⦄ → 𝐓⦃f⦄.
 501 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
 502 #i2 #Hf1 elim (Hf2 i2) -Hf2
 503 /3 width=7 by coafter_fwd_at, ex_intro/
 504 qed-.
 505
 506 lemma coafter_fwd_istot_dx: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f1⦄.
 507 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 508 #i2 #Hf elim (coafter_at_fwd … Hf … H) -f /2 width=2 by ex_intro/
 509 qed-.
 510
 511 lemma coafter_fwd_istot_sn: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄.
 512 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
 513 #i #Hf elim (coafter_at_fwd … Hf … H) -f
 514 #i2 #Hf1 #Hf2 lapply (at_increasing … Hf1) -f1
 515 #Hi12 elim (at_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
 516 qed-.
 517
 518 lemma coafter_inv_istot: ∀f2,f1,f. f2 ~⊚ f1 ≡ f → 𝐓⦃f⦄ → 𝐓⦃f2⦄ ∧ 𝐓⦃f1⦄.
 519 /3 width=4 by coafter_fwd_istot_sn, coafter_fwd_istot_dx, conj/ qed-.
 520
 521 lemma coafter_at1_fwd: ∀f1,i1,i2. @⦃i1, f1⦄ ≡ i2 → ∀f2. 𝐓⦃f2⦄ → ∀f. f2 ~⊚ f1 ≡ f →
 522                      ∃∃i. @⦃i2, f2⦄ ≡ i & @⦃i1, f⦄ ≡ i.
 523 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
 524 /3 width=8 by coafter_fwd_at, ex2_intro/
 525 qed-.
 526
 527 lemma coafter_fwd_isid_sn: ∀f2,f1,f. 𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f1 ≗ f → 𝐈⦃f2⦄.
 528 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 529 #Hf2 #Hf1 #H @isid_at_total // -Hf2
 530 #i2 #i #Hf2 elim (Hf1 i2) -Hf1
 531 #i0 #Hf1 lapply (at_increasing … Hf1)
 532 #Hi20 lapply (coafter_fwd_at2 … i0 … Hf1 … Hf) -Hf
 533 /3 width=7 by at_eq_repl_back, at_mono, at_id_le/
 534 qed-.
 535
 536 lemma coafter_fwd_isid_dx: ∀f2,f1,f.  𝐓⦃f⦄ → f2 ~⊚ f1 ≡ f → f2 ≗ f → 𝐈⦃f1⦄.
 537 #f2 #f1 #f #H #Hf elim (coafter_inv_istot … Hf H) -H
 538 #Hf2 #Hf1 #H2 @isid_at_total // -Hf1
 539 #i1 #i2 #Hi12 elim (coafter_at1_fwd … Hi12 … Hf) -f1
 540 /3 width=8 by at_inj, at_eq_repl_back/
 541 qed-.
 542 *)
 543 corec fact coafter_inj_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1.
 544 #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 545 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 546 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 547 cases (H2g1 0) #n #Hn
 548 cases (coafter_inv_pxx … H1f … H1) -H1f * #g21 #g #H1g #H21 #H
 549 [ cases (coafter_inv_pxp … H2f … H1 H) -f1 -f #g22 #H2g #H22
 550   @(eq_push … H21 H22) -f21 -f22
 551 | cases (coafter_inv_pxn … H2f … H1 H) -f1 -f #g22 #H2g #H22
 552   @(eq_next … H21 H22) -f21 -f22
 553 ]
 554 @(coafter_inj_O_aux (⫱*[n]g1) … (⫱*[n]g)) -coafter_inj_O_aux
 555 /2 width=1 by coafter_tls, istot_tls, at_pxx_tls/
 556 qed-.
 557
 558 fact coafter_inj_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_inj f1) →
 559                       ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_inj f1.
 560 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 561 #i2 #IH #f1 #H1f1 #H2f1 #f #f21 #f22 #H1f #H2f
 562 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #H1g1 #H1
 563 elim (coafter_inv_nxx … H1f … H1) -H1f #g #H1g #H
 564 lapply (coafter_inv_nxp … H2f … H1 H) -f #H2g
 565 /3 width=6 by istot_inv_next/
 566 qed-.
 567
 568 theorem coafter_inj: ∀f1. H_coafter_inj f1.
 569 #f1 #H cases (H 0) /3 width=7 by coafter_inj_aux, coafter_inj_O_aux/
 570 qed-.
 571
 572 corec fact coafter_fwd_isid2_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 →
 573                                     H_coafter_fwd_isid2 f1.
 574 #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 575 cases (at_inv_pxp … H1f1) -H1f1 [ |*: // ] #g1 #H1
 576 lapply (istot_inv_push … H2f1 … H1) -H2f1 #H2g1
 577 cases (H2g1 0) #n #Hn
 578 cases (coafter_inv_pxx … H … H1) -H * #g2 #g #H #H2 #H0
 579 [ lapply (isid_inv_push … Hf … H0) -Hf #Hg
 580   @(isid_push … H2)
 581   /3 width=7 by coafter_tls, istot_tls, at_pxx_tls, isid_tls/
 582 | cases (isid_inv_next … Hf … H0)
 583 ]
 584 qed-.
 585
 586 fact coafter_fwd_isid2_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_fwd_isid2 f1) →
 587                             ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_fwd_isid2 f1.
 588 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 589 #i2 #IH #f1 #H1f1 #f2 #f #H #H2f1 #Hf
 590 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
 591 elim (coafter_inv_nxx … H … H1) -H #g #Hg #H0
 592 @(IH … Hg1 … Hg) /2 width=3 by istot_inv_next, isid_inv_push/ (**) (* full auto fails *)
 593 qed-.
 594
 595 lemma coafter_fwd_isid2: ∀f1. H_coafter_fwd_isid2 f1.
 596 #f1 #f2 #f #Hf #H cases (H 0)
 597 /3 width=7 by coafter_fwd_isid2_aux, coafter_fwd_isid2_O_aux/
 598 qed-.
 599
 600 fact coafter_isfin2_fwd_O_aux: ∀f1. @⦃0, f1⦄ ≡ 0 →
 601                                H_coafter_isfin2_fwd f1.
 602 #f1 #Hf1 #f2 #H
 603 generalize in match Hf1; generalize in match f1; -f1
 604 @(isfin_ind … H) -f2
 605 [ /3 width=4 by coafter_isid_inv_dx, isfin_isid/ ]
 606 #f2 #_ #IH #f1 #H #Hf1 #f #Hf
 607 elim (at_inv_pxp … H) -H [ |*: // ] #g1 #H1
 608 lapply (istot_inv_push … Hf1 … H1) -Hf1 #Hg1
 609 elim (Hg1 0) #n #Hn
 610 [ elim (coafter_inv_ppx … Hf) | elim (coafter_inv_pnx … Hf)
 611 ] -Hf [1,6: |*: // ] #g #Hg #H0 destruct
 612 /5 width=6 by isfin_next, isfin_push, isfin_inv_tls, istot_tls, at_pxx_tls, coafter_tls/
 613 qed-.
 614
 615 fact coafter_isfin2_fwd_aux: (∀f1. @⦃0, f1⦄ ≡ 0 → H_coafter_isfin2_fwd f1) →
 616                             ∀i2,f1. @⦃0, f1⦄ ≡ i2 → H_coafter_isfin2_fwd f1.
 617 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
 618 #i2 #IH #f1 #H1f1 #f2 #Hf2 #H2f1 #f #Hf
 619 elim (at_inv_pxn … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
 620 elim (coafter_inv_nxx … Hf … H1) -Hf #g #Hg #H0
 621 lapply (IH … Hg1 … Hg) -i2 -Hg
 622 /2 width=4 by istot_inv_next, isfin_push/ (**) (* full auto fails *)
 623 qed-.
 624
 625 lemma coafter_isfin2_fwd: ∀f1. H_coafter_isfin2_fwd f1.
 626 #f1 #f2 #Hf2 #Hf1 cases (Hf1 0)
 627 /3 width=7 by coafter_isfin2_fwd_aux, coafter_isfin2_fwd_O_aux/
 628 qed-.
 629
 630 lemma coafter_inv_sor: ∀f. 𝐅⦃f⦄ → ∀f2. 𝐓⦃f2⦄ → ∀f1. f2 ~⊚ f1 ≡ f → ∀fa,fb. fa ⋓ fb ≡ f →
 631                        ∃∃f1a,f1b. f2 ~⊚ f1a ≡ fa & f2 ~⊚ f1b ≡ fb & f1a ⋓ f1b ≡ f1.
 632 @isfin_ind
 633 [ #f #Hf #f2 #Hf2 #f1 #H1f #fa #fb #H2f
 634   elim (sor_inv_isid3 … H2f) -H2f //
 635   lapply (coafter_fwd_isid2 … H1f ??) -H1f //
 636   /3 width=5 by ex3_2_intro, coafter_isid_dx, sor_isid/
 637 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 638   elim (sor_inv_xxp … H2) -H2 [ |*: // ] #ga #gb #H2f
 639   elim (coafter_inv_xxp … H1) -H1 [1,3: * |*: // ] #g2 [ #g1 ] #H1f #Hgf2
 640   [ lapply (istot_inv_push … Hf2 … Hgf2) | lapply (istot_inv_next … Hf2 … Hgf2) ] -Hf2 #Hg2
 641   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 642   /3 width=11 by sor_pp, ex3_2_intro, coafter_refl, coafter_next/
 643 | #f #_ #IH #f2 #Hf2 #f1 #H1 #fa #fb #H2
 644   elim (coafter_inv_xxn … H1) -H1 [ |*: // ] #g2 #g1 #H1f #Hgf2
 645   lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 646   elim (sor_inv_xxn … H2) -H2 [1,3,4: * |*: // ] #ga #gb #H2f
 647   elim (IH … Hg2 … H1f … H2f) -f -Hg2
 648   /3 width=11 by sor_np, sor_pn, sor_nn, ex3_2_intro, coafter_refl, coafter_push/
 649 ]
 650 qed-.
 651
 652 (* Properties with istot ****************************************************)
 653
 654 lemma coafter_sor: ∀f. 𝐅⦃f⦄ → ∀f2. 𝐓⦃f2⦄ → ∀f1. f2 ~⊚ f1 ≡ f → ∀f1a,f1b. f1a ⋓ f1b ≡ f1 →
 655                    ∃∃fa,fb. f2 ~⊚ f1a ≡ fa & f2 ~⊚ f1b ≡ fb & fa ⋓ fb ≡ f.
 656 @isfin_ind
 657 [ #f #Hf #f2 #Hf2 #f1 #Hf #f1a #f1b #Hf1
 658   lapply (coafter_fwd_isid2 … Hf ??) -Hf // #H2f1
 659   elim (sor_inv_isid3 … Hf1) -Hf1 //
 660   /3 width=5 by coafter_isid_dx, sor_refl, ex3_2_intro/
 661 | #f #_ #IH #f2 #Hf2 #f1 #H1 #f1a #f1b #H2
 662   elim (coafter_inv_xxp … H1) -H1 [1,3: * |*: // ]
 663   [ #g2 #g1 #Hf #Hgf2 #Hgf1
 664     elim (sor_inv_xxp … H2) -H2 [ |*: // ] #ga #gb #Hg1
 665     lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 666     elim (IH … Hf … Hg1) // -f1 -g1 -IH -Hg2
 667     /3 width=11 by coafter_refl, sor_pp, ex3_2_intro/
 668   | #g2 #Hf #Hgf2
 669     lapply (istot_inv_next … Hf2 … Hgf2) -Hf2 #Hg2
 670     elim (IH … Hf … H2) // -f1 -IH -Hg2
 671     /3 width=11 by coafter_next, sor_pp, ex3_2_intro/
 672   ]
 673 | #f #_ #IH #f2 #Hf2 #f1 #H1 #f1a #f1b #H2
 674   elim (coafter_inv_xxn … H1) -H1 [ |*: // ] #g2 #g1 #Hf #Hgf2 #Hgf1
 675   lapply (istot_inv_push … Hf2 … Hgf2) -Hf2 #Hg2
 676   elim (sor_inv_xxn … H2) -H2 [1,3,4: * |*: // ] #ga #gb #Hg1
 677   elim (IH … Hf … Hg1) // -f1 -g1 -IH -Hg2
 678   /3 width=11 by coafter_refl, coafter_push, sor_np, sor_pn, sor_nn, ex3_2_intro/
 679 ]
 680 qed-.