matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_3_2.ma".
  16 include "ground_2/notation/relations/ideq_2.ma".
  17 include "ground_2/relocation/rtmap.ma".
  18
  19 (* RELOCATION MAP ***********************************************************)
  20
  21 coinductive eq: relation rtmap ≝
  22 | eq_push: ∀f1,f2,g1,g2. eq f1 f2 → ⫯f1 = g1 → ⫯f2 = g2 → eq g1 g2
  23 | eq_next: ∀f1,f2,g1,g2. eq f1 f2 → ↑f1 = g1 → ↑f2 = g2 → eq g1 g2
  24 .
  25
  26 interpretation "extensional equivalence (rtmap)"
  27    'IdEq f1 f2 = (eq f1 f2).
  28
  29 definition eq_repl (R:relation …) ≝
  30                    ∀f1,f2. f1 ≡ f2 → R f1 f2.
  31
  32 definition eq_repl_back (R:predicate …) ≝
  33                         ∀f1. R f1 → ∀f2. f1 ≡ f2 → R f2.
  34
  35 definition eq_repl_fwd (R:predicate …) ≝
  36                        ∀f1. R f1 → ∀f2. f2 ≡ f1 → R f2.
  37
  38 (* Basic properties *********************************************************)
  39
  40 corec lemma eq_refl: reflexive … eq.
  41 #f cases (pn_split f) *
  42 #g #Hg [ @(eq_push … Hg Hg) | @(eq_next … Hg Hg) ] -Hg //
  43 qed.
  44
  45 corec lemma eq_sym: symmetric … eq.
  46 #f1 #f2 * -f1 -f2
  47 #f1 #f2 #g1 #g2 #Hf #H1 #H2
  48 [ @(eq_push … H2 H1) | @(eq_next … H2 H1) ] -g2 -g1 /2 width=1 by/
  49 qed-.
  50
  51 lemma eq_repl_sym: ∀R. eq_repl_back R → eq_repl_fwd R.
  52 /3 width=3 by eq_sym/ qed-.
  53
  54 (* Basic inversion lemmas ***************************************************)
  55
  56 lemma eq_inv_px: ∀g1,g2. g1 ≡ g2 → ∀f1. ⫯f1 = g1 →
  57                  ∃∃f2. f1 ≡ f2 & ⫯f2 = g2.
  58 #g1 #g2 * -g1 -g2
  59 #f1 #f2 #g1 #g2 #Hf * * -g1 -g2
  60 #x1 #H
  61 [ lapply (injective_push … H) -H /2 width=3 by ex2_intro/
  62 | elim (discr_push_next … H)
  63 ]
  64 qed-.
  65
  66 lemma eq_inv_nx: ∀g1,g2. g1 ≡ g2 → ∀f1. ↑f1 = g1 →
  67                  ∃∃f2. f1 ≡ f2 & ↑f2 = g2.
  68 #g1 #g2 * -g1 -g2
  69 #f1 #f2 #g1 #g2 #Hf * * -g1 -g2
  70 #x1 #H
  71 [ elim (discr_next_push … H)
  72 | lapply (injective_next … H) -H /2 width=3 by ex2_intro/
  73 ]
  74 qed-.
  75
  76 lemma eq_inv_xp: ∀g1,g2. g1 ≡ g2 → ∀f2. ⫯f2 = g2 →
  77                  ∃∃f1. f1 ≡ f2 & ⫯f1 = g1.
  78 #g1 #g2 * -g1 -g2
  79 #f1 #f2 #g1 #g2 #Hf * * -g1 -g2
  80 #x2 #H
  81 [ lapply (injective_push … H) -H /2 width=3 by ex2_intro/
  82 | elim (discr_push_next … H)
  83 ]
  84 qed-.
  85
  86 lemma eq_inv_xn: ∀g1,g2. g1 ≡ g2 → ∀f2. ↑f2 = g2 →
  87                  ∃∃f1. f1 ≡ f2 & ↑f1 = g1.
  88 #g1 #g2 * -g1 -g2
  89 #f1 #f2 #g1 #g2 #Hf * * -g1 -g2
  90 #x2 #H
  91 [ elim (discr_next_push … H)
  92 | lapply (injective_next … H) -H /2 width=3 by ex2_intro/
  93 ]
  94 qed-.
  95
  96 (* Advanced inversion lemmas ************************************************)
  97
  98 lemma eq_inv_pp: ∀g1,g2. g1 ≡ g2 → ∀f1,f2. ⫯f1 = g1 → ⫯f2 = g2 → f1 ≡ f2.
  99 #g1 #g2 #H #f1 #f2 #H1 elim (eq_inv_px … H … H1) -g1
 100 #x2 #Hx2 * -g2
 101 #H lapply (injective_push … H) -H //
 102 qed-.
 103
 104 lemma eq_inv_nn: ∀g1,g2. g1 ≡ g2 → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 → f1 ≡ f2.
 105 #g1 #g2 #H #f1 #f2 #H1 elim (eq_inv_nx … H … H1) -g1
 106 #x2 #Hx2 * -g2
 107 #H lapply (injective_next … H) -H //
 108 qed-.
 109
 110 lemma eq_inv_pn: ∀g1,g2. g1 ≡ g2 → ∀f1,f2. ⫯f1 = g1 → ↑f2 = g2 → ⊥.
 111 #g1 #g2 #H #f1 #f2 #H1 elim (eq_inv_px … H … H1) -g1
 112 #x2 #Hx2 * -g2
 113 #H elim (discr_next_push … H)
 114 qed-.
 115
 116 lemma eq_inv_np: ∀g1,g2. g1 ≡ g2 → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 → ⊥.
 117 #g1 #g2 #H #f1 #f2 #H1 elim (eq_inv_nx … H … H1) -g1
 118 #x2 #Hx2 * -g2
 119 #H elim (discr_push_next … H)
 120 qed-.
 121
 122 lemma eq_inv_gen: ∀f1,f2. f1 ≡ f2 →
 123                   (∃∃g1,g2. g1 ≡ g2 & ⫯g1 = f1 & ⫯g2 = f2) ∨
 124                   ∃∃g1,g2. g1 ≡ g2 & ↑g1 = f1 & ↑g2 = f2.
 125 #f1 elim (pn_split f1) * #g1 #H1 #f2 #Hf
 126 [ elim (eq_inv_px … Hf … H1) -Hf /3 width=5 by or_introl, ex3_2_intro/
 127 | elim (eq_inv_nx … Hf … H1) -Hf /3 width=5 by or_intror, ex3_2_intro/
 128 ]
 129 qed-.
 130
 131 (* Main properties **********************************************************)
 132
 133 corec theorem eq_trans: Transitive … eq.
 134 #f1 #f * -f1 -f
 135 #f1 #f #g1 #g #Hf1 #H1 #H #f2 #Hf2
 136 [ cases (eq_inv_px … Hf2 … H) | cases (eq_inv_nx … Hf2 … H) ] -g
 137 /3 width=5 by eq_push, eq_next/
 138 qed-.
 139
 140 theorem eq_canc_sn: ∀f2. eq_repl_back (λf. f ≡ f2).
 141 /3 width=3 by eq_trans, eq_sym/ qed-.
 142
 143 theorem eq_canc_dx: ∀f1. eq_repl_fwd (λf. f1 ≡ f).
 144 /3 width=3 by eq_trans, eq_sym/ qed-.