matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_istot.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/istotal_1.ma".
  16 include "ground_2/relocation/rtmap_at.ma".
  17
  18 (* RELOCATION MAP ***********************************************************)
  19
  20 definition istot: predicate rtmap ≝ λf. ∀i. ∃j. @⦃i, f⦄ ≡ j.
  21
  22 interpretation "test for totality (rtmap)"
  23    'IsTotal f = (istot f).
  24
  25 (* Basic inversion lemmas ***************************************************)
  26
  27 lemma istot_inv_push: ∀g. 𝐓⦃g⦄ → ∀f. ↑f = g → 𝐓⦃f⦄.
  28 #g #Hg #f #H #i elim (Hg (⫯i)) -Hg
  29 #j #Hg elim (at_inv_npx … Hg … H) -Hg -H /2 width=3 by ex_intro/
  30 qed-.
  31
  32 lemma istot_inv_next: ∀g. 𝐓⦃g⦄ → ∀f. ⫯f = g → 𝐓⦃f⦄.
  33 #g #Hg #f #H #i elim (Hg i) -Hg
  34 #j #Hg elim (at_inv_xnx … Hg … H) -Hg -H /2 width=2 by ex_intro/
  35 qed-.
  36
  37 (* Advanced forward lemmas on at ********************************************)
  38
  39 let corec at_ext: ∀f1,f2. 𝐓⦃f1⦄ → 𝐓⦃f2⦄ →
  40                   (∀i,i1,i2. @⦃i, f1⦄ ≡ i1 → @⦃i, f2⦄ ≡ i2 → i1 = i2) → f1 ≗ f2 ≝ ?.
  41 #f1 cases (pn_split f1) * #g1 #H1
  42 #f2 cases (pn_split f2) * #g2 #H2
  43 #Hf1 #Hf2 #Hi
  44 [ @(eq_push … H1 H2) @at_ext -at_ext /2 width=3 by istot_inv_push/ -Hf1 -Hf2
  45   #i #i1 #i2 #Hg1 #Hg2 lapply (Hi (⫯i) (⫯i1) (⫯i2) ??) /2 width=7 by at_push/
  46 | cases (Hf2 0) -Hf1 -Hf2 -at_ext
  47   #j2 #Hf2 cases (at_increasing_strict … Hf2 … H2) -H2
  48   lapply (Hi 0 0 j2 … Hf2) /2 width=2 by at_refl/ -Hi -Hf2 -H1
  49   #H2 #H cases (lt_le_false … H) -H //
  50 | cases (Hf1 0) -Hf1 -Hf2 -at_ext
  51   #j1 #Hf1 cases (at_increasing_strict … Hf1 … H1) -H1
  52   lapply (Hi 0 j1 0 Hf1 ?) /2 width=2 by at_refl/ -Hi -Hf1 -H2
  53   #H1 #H cases (lt_le_false … H) -H //
  54 | @(eq_next … H1 H2) @at_ext -at_ext /2 width=3 by istot_inv_next/ -Hf1 -Hf2
  55   #i #i1 #i2 #Hg1 #Hg2 lapply (Hi i (⫯i1) (⫯i2) ??) /2 width=5 by at_next/
  56 ]
  57 qed-.
  58
  59 (* Main properties on at ****************************************************)
  60
  61 lemma at_dec: ∀f,i1,i2. 𝐓⦃f⦄ → Decidable (@⦃i1, f⦄ ≡ i2).
  62 #f #i1 #i2 #Hf lapply (Hf i1) -Hf *
  63 #j2 #Hf elim (eq_nat_dec i2 j2)
  64 [ #H destruct /2 width=1 by or_introl/
  65 | /4 width=6 by at_mono, or_intror/
  66 ]
  67 qed-.
  68
  69 lemma is_at_dec_le: ∀f,i2,i. 𝐓⦃f⦄ → (∀i1. i1 + i ≤ i2 → @⦃i1, f⦄ ≡ i2 → ⊥) → Decidable (∃i1. @⦃i1, f⦄ ≡ i2).
  70 #f #i2 #i #Hf elim i -i
  71 [ #Ht @or_intror * /3 width=3 by at_increasing/
  72 | #i #IH #Ht elim (at_dec f (i2-i) i2) /3 width=2 by ex_intro, or_introl/
  73   #Hi2 @IH -IH #i1 #H #Hi elim (le_to_or_lt_eq … H) -H /2 width=3 by/
  74   #H destruct -Ht /2 width=1 by/
  75 ]
  76 qed-.
  77
  78 lemma is_at_dec: ∀f,i2. 𝐓⦃f⦄ → Decidable (∃i1. @⦃i1, f⦄ ≡ i2).
  79 #f #i2 #Hf @(is_at_dec_le ?? (⫯i2)) /2 width=4 by lt_le_false/
  80 qed-.
  81
  82 (* Advanced properties on isid **********************************************)
  83
  84 lemma isid_at_total: ∀f. 𝐓⦃f⦄ → (∀i1,i2. @⦃i1, f⦄ ≡ i2 → i1 = i2) → 𝐈⦃f⦄.
  85 #f #H1f #H2f @isid_at
  86 #i lapply (H1f i) -H1f *
  87 #j #Hf >(H2f … Hf) in ⊢ (???%); -H2f //
  88 qed.