matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_sle.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.tcs.unibo.it                            *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_isid.ma".
  16 include "ground_2/relocation/rtmap_isdiv.ma".
  17
  18 (* RELOCATION MAP ***********************************************************)
  19
  20 coinductive sle: relation rtmap ≝
  21 | sle_push: ∀f1,f2,g1,g2. sle f1 f2 → ⫯f1 = g1 → ⫯f2 = g2 → sle g1 g2
  22 | sle_next: ∀f1,f2,g1,g2. sle f1 f2 → ↑f1 = g1 → ↑f2 = g2 → sle g1 g2
  23 | sle_weak: ∀f1,f2,g1,g2. sle f1 f2 → ⫯f1 = g1 → ↑f2 = g2 → sle g1 g2
  24 .
  25
  26 interpretation "inclusion (rtmap)"
  27    'subseteq f1 f2 = (sle f1 f2).
  28
  29 (* Basic properties *********************************************************)
  30
  31 axiom sle_eq_repl_back1: ∀f2. eq_repl_back … (λf1. f1 ⊆ f2).
  32
  33 lemma sle_eq_repl_fwd1: ∀f2. eq_repl_fwd … (λf1. f1 ⊆ f2).
  34 #f2 @eq_repl_sym /2 width=3 by sle_eq_repl_back1/
  35 qed-.
  36
  37 axiom sle_eq_repl_back2: ∀f1. eq_repl_back … (λf2. f1 ⊆ f2).
  38
  39 lemma sle_eq_repl_fwd2: ∀f1. eq_repl_fwd … (λf2. f1 ⊆ f2).
  40 #f1 @eq_repl_sym /2 width=3 by sle_eq_repl_back2/
  41 qed-.
  42
  43 corec lemma sle_refl: ∀f. f ⊆ f.
  44 #f cases (pn_split f) * #g #H
  45 [ @(sle_push … H H) | @(sle_next … H H) ] -H //
  46 qed.
  47
  48 lemma sle_refl_eq: ∀f1,f2. f1 ≡ f2 → f1 ⊆ f2.
  49 /2 width=3 by sle_eq_repl_back2/ qed.
  50
  51 (* Basic inversion lemmas ***************************************************)
  52
  53 lemma sle_inv_xp: ∀g1,g2. g1 ⊆ g2 → ∀f2. ⫯f2 = g2 →
  54                   ∃∃f1. f1 ⊆ f2 & ⫯f1 = g1.
  55 #g1 #g2 * -g1 -g2
  56 #f1 #f2 #g1 #g2 #H #H1 #H2 #x2 #Hx2 destruct
  57 [ lapply (injective_push … Hx2) -Hx2 /2 width=3 by ex2_intro/ ]
  58 elim (discr_push_next … Hx2)
  59 qed-.
  60
  61 lemma sle_inv_nx: ∀g1,g2. g1 ⊆ g2 → ∀f1. ↑f1 = g1 →
  62                   ∃∃f2. f1 ⊆ f2 & ↑f2 = g2.
  63 #g1 #g2 * -g1 -g2
  64 #f1 #f2 #g1 #g2 #H #H1 #H2 #x1 #Hx1 destruct
  65 [2: lapply (injective_next … Hx1) -Hx1 /2 width=3 by ex2_intro/ ]
  66 elim (discr_next_push … Hx1)
  67 qed-.
  68
  69 lemma sle_inv_pn: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2. ⫯f1 = g1 → ↑f2 = g2 → f1 ⊆ f2.
  70 #g1 #g2 * -g1 -g2
  71 #f1 #f2 #g1 #g2 #H #H1 #H2 #x1 #x2 #Hx1 #Hx2 destruct
  72 [ elim (discr_next_push … Hx2)
  73 | elim (discr_push_next … Hx1)
  74 | lapply (injective_push … Hx1) -Hx1
  75   lapply (injective_next … Hx2) -Hx2 //
  76 ]
  77 qed-.
  78
  79 (* Advanced inversion lemmas ************************************************)
  80
  81 lemma sle_inv_pp: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2. ⫯f1 = g1 → ⫯f2 = g2 → f1 ⊆ f2.
  82 #g1 #g2 #H #f1 #f2 #H1 #H2 elim (sle_inv_xp … H … H2) -g2
  83 #x1 #H #Hx1 destruct lapply (injective_push … Hx1) -Hx1 //
  84 qed-.
  85
  86 lemma sle_inv_nn: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 → f1 ⊆ f2.
  87 #g1 #g2 #H #f1 #f2 #H1 #H2 elim (sle_inv_nx … H … H1) -g1
  88 #x2 #H #Hx2 destruct lapply (injective_next … Hx2) -Hx2 //
  89 qed-.
  90
  91 lemma sle_inv_px: ∀g1,g2. g1 ⊆ g2 → ∀f1. ⫯f1 = g1 →
  92                   (∃∃f2. f1 ⊆ f2 & ⫯f2 = g2) ∨ ∃∃f2. f1 ⊆ f2 & ↑f2 = g2.
  93 #g1 #g2 elim (pn_split g2) * #f2 #H2 #H #f1 #H1
  94 [ lapply (sle_inv_pp … H … H1 H2) | lapply (sle_inv_pn … H … H1 H2) ] -H -H1
  95 /3 width=3 by ex2_intro, or_introl, or_intror/
  96 qed-.
  97
  98 lemma sle_inv_xn: ∀g1,g2. g1 ⊆ g2 → ∀f2. ↑f2 = g2 →
  99                   (∃∃f1. f1 ⊆ f2 & ⫯f1 = g1) ∨ ∃∃f1. f1 ⊆ f2 & ↑f1 = g1.
 100 #g1 #g2 elim (pn_split g1) * #f1 #H1 #H #f2 #H2
 101 [ lapply (sle_inv_pn … H … H1 H2) | lapply (sle_inv_nn … H … H1 H2) ] -H -H2
 102 /3 width=3 by ex2_intro, or_introl, or_intror/
 103 qed-.
 104
 105 (* Main properties **********************************************************)
 106
 107 corec theorem sle_trans: Transitive … sle.
 108 #f1 #f * -f1 -f
 109 #f1 #f #g1 #g #Hf #H1 #H #g2 #H0
 110 [ cases (sle_inv_px … H0 … H) * |*: cases (sle_inv_nx … H0 … H) ] -g
 111 /3 width=5 by sle_push, sle_next, sle_weak/
 112 qed-.
 113
 114 (* Properties with iteraded push ********************************************)
 115
 116 lemma sle_pushs: ∀f1,f2. f1 ⊆ f2 → ∀i. ⫯*[i] f1 ⊆ ⫯*[i] f2.
 117 #f1 #f2 #Hf12 #i elim i -i /2 width=5 by sle_push/
 118 qed.
 119
 120 (* Properties with tail *****************************************************)
 121
 122 lemma sle_px_tl: ∀g1,g2. g1 ⊆ g2 → ∀f1. ⫯f1 = g1 → f1 ⊆ ⫱g2.
 123 #g1 #g2 #H #f1 #H1 elim (sle_inv_px … H … H1) -H -H1 * //
 124 qed.
 125
 126 lemma sle_xn_tl: ∀g1,g2. g1 ⊆ g2 → ∀f2. ↑f2 = g2 → ⫱g1 ⊆ f2.
 127 #g1 #g2 #H #f2 #H2 elim (sle_inv_xn … H … H2) -H -H2 * //
 128 qed.
 129
 130 lemma sle_tl: ∀f1,f2. f1 ⊆ f2 → ⫱f1 ⊆ ⫱f2.
 131 #f1 elim (pn_split f1) * #g1 #H1 #f2 #H
 132 [ lapply (sle_px_tl … H … H1) -H //
 133 | elim (sle_inv_nx … H … H1) -H //
 134 ]
 135 qed.
 136
 137 (* Inversion lemmas with tail ***********************************************)
 138
 139 lemma sle_inv_tl_sn: ∀f1,f2. ⫱f1 ⊆ f2 → f1 ⊆ ↑f2.
 140 #f1 elim (pn_split f1) * #g1 #H destruct
 141 /2 width=5 by sle_next, sle_weak/
 142 qed-.
 143
 144 lemma sle_inv_tl_dx: ∀f1,f2. f1 ⊆ ⫱f2 → ⫯f1 ⊆ f2.
 145 #f1 #f2 elim (pn_split f2) * #g2 #H destruct
 146 /2 width=5 by sle_push, sle_weak/
 147 qed-.
 148
 149 (* Properties with iteraded tail ********************************************)
 150
 151 lemma sle_tls: ∀f1,f2. f1 ⊆ f2 → ∀i. ⫱*[i] f1 ⊆ ⫱*[i] f2.
 152 #f1 #f2 #Hf12 #i elim i -i /2 width=5 by sle_tl/
 153 qed.
 154
 155 (* Properties with isid *****************************************************)
 156
 157 corec lemma sle_isid_sn: ∀f1. 𝐈❪f1❫ → ∀f2. f1 ⊆ f2.
 158 #f1 * -f1
 159 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) *
 160 /3 width=5 by sle_weak, sle_push/
 161 qed.
 162
 163 (* Inversion lemmas with isid ***********************************************)
 164
 165 corec lemma sle_inv_isid_dx: ∀f1,f2. f1 ⊆ f2 → 𝐈❪f2❫ → 𝐈❪f1❫.
 166 #f1 #f2 * -f1 -f2
 167 #f1 #f2 #g1 #g2 #Hf * * #H
 168 [2,3: elim (isid_inv_next … H) // ]
 169 lapply (isid_inv_push … H ??) -H
 170 /3 width=3 by isid_push/
 171 qed-.
 172
 173 (* Properties with isdiv ****************************************************)
 174
 175 corec lemma sle_isdiv_dx: ∀f2. 𝛀❪f2❫ → ∀f1. f1 ⊆ f2.
 176 #f2 * -f2
 177 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) *
 178 /3 width=5 by sle_weak, sle_next/
 179 qed.
 180
 181 (* Inversion lemmas with isdiv **********************************************)
 182
 183 corec lemma sle_inv_isdiv_sn: ∀f1,f2. f1 ⊆ f2 → 𝛀❪f1❫ → 𝛀❪f2❫.
 184 #f1 #f2 * -f1 -f2
 185 #f1 #f2 #g1 #g2 #Hf * * #H
 186 [1,3: elim (isdiv_inv_push … H) // ]
 187 lapply (isdiv_inv_next … H ??) -H
 188 /3 width=3 by isdiv_next/
 189 qed-.