matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_sle.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.tcs.unibo.it                            *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_isid.ma".
  16
  17 (* RELOCATION MAP ***********************************************************)
  18
  19 coinductive sle: relation rtmap ≝
  20 | sle_push: ∀f1,f2,g1,g2. sle f1 f2 → ↑f1 = g1 → ↑f2 = g2 → sle g1 g2
  21 | sle_next: ∀f1,f2,g1,g2. sle f1 f2 → ⫯f1 = g1 → ⫯f2 = g2 → sle g1 g2
  22 | sle_weak: ∀f1,f2,g1,g2. sle f1 f2 → ↑f1 = g1 → ⫯f2 = g2 → sle g1 g2
  23 .
  24
  25 interpretation "inclusion (rtmap)"
  26    'subseteq t1 t2 = (sle t1 t2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 corec lemma sle_refl: ∀f. f ⊆ f.
  31 #f cases (pn_split f) * #g #H
  32 [ @(sle_push … H H) | @(sle_next … H H) ] -H //
  33 qed.
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 lemma sle_inv_xp: ∀g1,g2. g1 ⊆ g2 → ∀f2. ↑f2 = g2 →
  38                   ∃∃f1. f1 ⊆ f2 & ↑f1 = g1.
  39 #g1 #g2 * -g1 -g2
  40 #f1 #f2 #g1 #g2 #H #H1 #H2 #x2 #Hx2 destruct
  41 [ lapply (injective_push … Hx2) -Hx2 /2 width=3 by ex2_intro/ ]
  42 elim (discr_push_next … Hx2)
  43 qed-.
  44
  45 lemma sle_inv_nx: ∀g1,g2. g1 ⊆ g2 → ∀f1. ⫯f1 = g1 →
  46                   ∃∃f2. f1 ⊆ f2 & ⫯f2 = g2.
  47 #g1 #g2 * -g1 -g2
  48 #f1 #f2 #g1 #g2 #H #H1 #H2 #x1 #Hx1 destruct
  49 [2: lapply (injective_next … Hx1) -Hx1 /2 width=3 by ex2_intro/ ]
  50 elim (discr_next_push … Hx1)
  51 qed-.
  52
  53 lemma sle_inv_pn: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 → f1 ⊆ f2.
  54 #g1 #g2 * -g1 -g2
  55 #f1 #f2 #g1 #g2 #H #H1 #H2 #x1 #x2 #Hx1 #Hx2 destruct
  56 [ elim (discr_next_push … Hx2)
  57 | elim (discr_push_next … Hx1)
  58 | lapply (injective_push … Hx1) -Hx1
  59   lapply (injective_next … Hx2) -Hx2 //
  60 ]
  61 qed-.
  62
  63 (* Advanced inversion lemmas ************************************************)
  64
  65 lemma sle_inv_pp: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 → f1 ⊆ f2.
  66 #g1 #g2 #H #f1 #f2 #H1 #H2 elim (sle_inv_xp … H … H2) -g2
  67 #x1 #H #Hx1 destruct lapply (injective_push … Hx1) -Hx1 //
  68 qed-.
  69
  70 lemma sle_inv_nn: ∀g1,g2. g1 ⊆ g2 → ∀f1,f2.  ⫯f1 = g1 → ⫯f2 = g2 → f1 ⊆ f2.
  71 #g1 #g2 #H #f1 #f2 #H1 #H2 elim (sle_inv_nx … H … H1) -g1
  72 #x2 #H #Hx2 destruct lapply (injective_next … Hx2) -Hx2 //
  73 qed-.
  74
  75 lemma sle_inv_px: ∀g1,g2. g1 ⊆ g2 → ∀f1. ↑f1 = g1 →
  76                   (∃∃f2. f1 ⊆ f2 & ↑f2 = g2) ∨ ∃∃f2. f1 ⊆ f2 & ⫯f2 = g2.
  77 #g1 #g2 elim (pn_split g2) * #f2 #H2 #H #f1 #H1
  78 [ lapply (sle_inv_pp … H … H1 H2) | lapply (sle_inv_pn … H … H1 H2) ] -H -H1
  79 /3 width=3 by ex2_intro, or_introl, or_intror/
  80 qed-.
  81
  82 (* Main properties **********************************************************)
  83
  84 corec theorem sle_trans: Transitive … sle.
  85 #f1 #f * -f1 -f
  86 #f1 #f #g1 #g #Hf #H1 #H #g2 #H0
  87 [ cases (sle_inv_px … H0 … H) * |*: cases (sle_inv_nx … H0 … H) ] -g
  88 /3 width=5 by sle_push, sle_next, sle_weak/
  89 qed-.
  90
  91 (* Properties with tail *****************************************************)
  92
  93 lemma sle_px_tl: ∀g1,g2. g1 ⊆ g2 → ∀f1. ↑f1 = g1 → f1 ⊆ ⫱g2.
  94 #g1 #g2 #H #f1 #H1 elim (sle_inv_px … H … H1) -H -H1 * //
  95 qed.
  96
  97 (* Inversion lemmas with tail ***********************************************)
  98
  99 lemma sle_inv_tl_sn: ∀f1,f2. ⫱f1 ⊆ f2 → f1 ⊆ ⫯f2.
 100 #f1 elim (pn_split f1) * #g1 #H destruct
 101 /2 width=5 by sle_next, sle_weak/
 102 qed-.
 103
 104 lemma sle_inv_tl_dx: ∀f1,f2. f1 ⊆ ⫱f2 → ↑f1 ⊆ f2.
 105 #f1 #f2 elim (pn_split f2) * #g2 #H destruct
 106 /2 width=5 by sle_push, sle_weak/
 107 qed-.
 108
 109 (* Properties with isid *****************************************************)
 110
 111 corec lemma sle_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⊆ f2.
 112 #f1 * -f1
 113 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) *
 114 /3 width=5 by sle_weak, sle_push/
 115 qed.
 116
 117 (* Inversion lemmas with isid ***********************************************)
 118
 119 corec lemma sle_inv_isid_dx: ∀f1,f2. f1 ⊆ f2 → 𝐈⦃f2⦄ → 𝐈⦃f1⦄.
 120 #f1 #f2 * -f1 -f2
 121 #f1 #f2 #g1 #g2 #Hf * * #H
 122 [2,3: elim (isid_inv_next … H) // ]
 123 lapply (isid_inv_push … H ??) -H
 124 /3 width=3 by isid_push/
 125 qed-.