matita/matita/contribs/lambdadelta/ground_2/relocation/rtmap_sor.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/relations/runion_3.ma".
  16 include "ground_2/relocation/rtmap_isfin.ma".
  17 include "ground_2/relocation/rtmap_sle.ma".
  18
  19 coinductive sor: relation3 rtmap rtmap rtmap ≝
  20 | sor_pp: ∀f1,f2,f,g1,g2,g. sor f1 f2 f → ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → sor g1 g2 g
  21 | sor_np: ∀f1,f2,f,g1,g2,g. sor f1 f2 f → ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → sor g1 g2 g
  22 | sor_pn: ∀f1,f2,f,g1,g2,g. sor f1 f2 f → ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → sor g1 g2 g
  23 | sor_nn: ∀f1,f2,f,g1,g2,g. sor f1 f2 f → ↑f1 = g1 → ↑f2 = g2 → ↑f = g → sor g1 g2 g
  24 .
  25
  26 interpretation "union (rtmap)"
  27    'RUnion f1 f2 f = (sor f1 f2 f).
  28
  29 (* Basic inversion lemmas ***************************************************)
  30
  31 lemma sor_inv_ppx: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ⫯f2 = g2 →
  32                    ∃∃f. f1 ⋓ f2 ≘ f & ⫯f = g.
  33 #g1 #g2 #g * -g1 -g2 -g
  34 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #x1 #x2 #Hx1 #Hx2 destruct
  35 try (>(injective_push … Hx1) -x1) try (>(injective_next … Hx1) -x1)
  36 try elim (discr_push_next … Hx1) try elim (discr_next_push … Hx1)
  37 try (>(injective_push … Hx2) -x2) try (>(injective_next … Hx2) -x2)
  38 try elim (discr_push_next … Hx2) try elim (discr_next_push … Hx2)
  39 /2 width=3 by ex2_intro/
  40 qed-.
  41
  42 lemma sor_inv_npx: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f1,f2. ↑f1 = g1 → ⫯f2 = g2 →
  43                    ∃∃f. f1 ⋓ f2 ≘ f & ↑f = g.
  44 #g1 #g2 #g * -g1 -g2 -g
  45 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #x1 #x2 #Hx1 #Hx2 destruct
  46 try (>(injective_push … Hx1) -x1) try (>(injective_next … Hx1) -x1)
  47 try elim (discr_push_next … Hx1) try elim (discr_next_push … Hx1)
  48 try (>(injective_push … Hx2) -x2) try (>(injective_next … Hx2) -x2)
  49 try elim (discr_push_next … Hx2) try elim (discr_next_push … Hx2)
  50 /2 width=3 by ex2_intro/
  51 qed-.
  52
  53 lemma sor_inv_pnx: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f1,f2. ⫯f1 = g1 → ↑f2 = g2 →
  54                    ∃∃f. f1 ⋓ f2 ≘ f & ↑f = g.
  55 #g1 #g2 #g * -g1 -g2 -g
  56 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #x1 #x2 #Hx1 #Hx2 destruct
  57 try (>(injective_push … Hx1) -x1) try (>(injective_next … Hx1) -x1)
  58 try elim (discr_push_next … Hx1) try elim (discr_next_push … Hx1)
  59 try (>(injective_push … Hx2) -x2) try (>(injective_next … Hx2) -x2)
  60 try elim (discr_push_next … Hx2) try elim (discr_next_push … Hx2)
  61 /2 width=3 by ex2_intro/
  62 qed-.
  63
  64 lemma sor_inv_nnx: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f1,f2. ↑f1 = g1 → ↑f2 = g2 →
  65                    ∃∃f. f1 ⋓ f2 ≘ f & ↑f = g.
  66 #g1 #g2 #g * -g1 -g2 -g
  67 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #x1 #x2 #Hx1 #Hx2 destruct
  68 try (>(injective_push … Hx1) -x1) try (>(injective_next … Hx1) -x1)
  69 try elim (discr_push_next … Hx1) try elim (discr_next_push … Hx1)
  70 try (>(injective_push … Hx2) -x2) try (>(injective_next … Hx2) -x2)
  71 try elim (discr_push_next … Hx2) try elim (discr_next_push … Hx2)
  72 /2 width=3 by ex2_intro/
  73 qed-.
  74
  75 (* Advanced inversion lemmas ************************************************)
  76
  77 lemma sor_inv_ppn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
  78                    ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ↑f = g → ⊥.
  79 #g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
  80 elim (sor_inv_ppx … H … H1 H2) -g1 -g2 #x #_ #H destruct
  81 /2 width=3 by discr_push_next/
  82 qed-.
  83
  84 lemma sor_inv_nxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
  85                    ∀f1,f. ↑f1 = g1 → ⫯f = g → ⊥.
  86 #g1 #g2 #g #H #f1 #f #H1 #H0
  87 elim (pn_split g2) * #f2 #H2
  88 [ elim (sor_inv_npx … H … H1 H2)
  89 | elim (sor_inv_nnx … H … H1 H2)
  90 ] -g1 -g2 #x #_ #H destruct
  91 /2 width=3 by discr_next_push/
  92 qed-.
  93
  94 lemma sor_inv_xnp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
  95                    ∀f2,f. ↑f2 = g2 → ⫯f = g → ⊥.
  96 #g1 #g2 #g #H #f2 #f #H2 #H0
  97 elim (pn_split g1) * #f1 #H1
  98 [ elim (sor_inv_pnx … H … H1 H2)
  99 | elim (sor_inv_nnx … H … H1 H2)
 100 ] -g1 -g2 #x #_ #H destruct
 101 /2 width=3 by discr_next_push/
 102 qed-.
 103
 104 lemma sor_inv_ppp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 105                    ∀f1,f2,f. ⫯f1 = g1 → ⫯f2 = g2 → ⫯f = g → f1 ⋓ f2 ≘ f.
 106 #g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
 107 elim (sor_inv_ppx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
 108 <(injective_push … H) -f //
 109 qed-.
 110
 111 lemma sor_inv_npn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 112                    ∀f1,f2,f. ↑f1 = g1 → ⫯f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
 113 #g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
 114 elim (sor_inv_npx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
 115 <(injective_next … H) -f //
 116 qed-.
 117
 118 lemma sor_inv_pnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 119                    ∀f1,f2,f. ⫯f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
 120 #g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
 121 elim (sor_inv_pnx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
 122 <(injective_next … H) -f //
 123 qed-.
 124
 125 lemma sor_inv_nnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 126                    ∀f1,f2,f. ↑f1 = g1 → ↑f2 = g2 → ↑f = g → f1 ⋓ f2 ≘ f.
 127 #g1 #g2 #g #H #f1 #f2 #f #H1 #H2 #H0
 128 elim (sor_inv_nnx … H … H1 H2) -g1 -g2 #x #Hx #H destruct
 129 <(injective_next … H) -f //
 130 qed-.
 131
 132 lemma sor_inv_pxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 133                    ∀f1,f. ⫯f1 = g1 → ⫯f = g →
 134                    ∃∃f2. f1 ⋓ f2 ≘ f & ⫯f2 = g2.
 135 #g1 #g2 #g #H #f1 #f #H1 #H0
 136 elim (pn_split g2) * #f2 #H2
 137 [ /3 width=7 by sor_inv_ppp, ex2_intro/
 138 | elim (sor_inv_xnp … H … H2 H0)
 139 ]
 140 qed-.
 141
 142 lemma sor_inv_xpp: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 143                    ∀f2,f. ⫯f2 = g2 → ⫯f = g →
 144                    ∃∃f1. f1 ⋓ f2 ≘ f & ⫯f1 = g1.
 145 #g1 #g2 #g #H #f2 #f #H2 #H0
 146 elim (pn_split g1) * #f1 #H1
 147 [ /3 width=7 by sor_inv_ppp, ex2_intro/
 148 | elim (sor_inv_nxp … H … H1 H0)
 149 ]
 150 qed-.
 151
 152 lemma sor_inv_pxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 153                    ∀f1,f. ⫯f1 = g1 → ↑f = g →
 154                    ∃∃f2. f1 ⋓ f2 ≘ f & ↑f2 = g2.
 155 #g1 #g2 #g #H #f1 #f #H1 #H0
 156 elim (pn_split g2) * #f2 #H2
 157 [ elim (sor_inv_ppn … H … H1 H2 H0)
 158 | /3 width=7 by sor_inv_pnn, ex2_intro/
 159 ]
 160 qed-.
 161
 162 lemma sor_inv_xpn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 163                    ∀f2,f. ⫯f2 = g2 → ↑f = g →
 164                    ∃∃f1. f1 ⋓ f2 ≘ f & ↑f1 = g1.
 165 #g1 #g2 #g #H #f2 #f #H2 #H0
 166 elim (pn_split g1) * #f1 #H1
 167 [ elim (sor_inv_ppn … H … H1 H2 H0)
 168 | /3 width=7 by sor_inv_npn, ex2_intro/
 169 ]
 170 qed-.
 171
 172 lemma sor_inv_xxp: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f. ⫯f = g →
 173                    ∃∃f1,f2. f1 ⋓ f2 ≘ f & ⫯f1 = g1 & ⫯f2 = g2.
 174 #g1 #g2 #g #H #f #H0
 175 elim (pn_split g1) * #f1 #H1
 176 [ elim (sor_inv_pxp … H … H1 H0) -g /2 width=5 by ex3_2_intro/
 177 | elim (sor_inv_nxp … H … H1 H0)
 178 ]
 179 qed-.
 180
 181 lemma sor_inv_nxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 182                    ∀f1,f. ↑f1 = g1 → ↑f = g →
 183                    (∃∃f2. f1 ⋓ f2 ≘ f & ⫯f2 = g2) ∨
 184                    ∃∃f2. f1 ⋓ f2 ≘ f & ↑f2 = g2.
 185 #g1 #g2 elim (pn_split g2) *
 186 /4 width=7 by sor_inv_npn, sor_inv_nnn, ex2_intro, or_intror, or_introl/
 187 qed-.
 188
 189 lemma sor_inv_xnn: ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 190                    ∀f2,f. ↑f2 = g2 → ↑f = g →
 191                    (∃∃f1. f1 ⋓ f2 ≘ f & ⫯f1 = g1) ∨
 192                    ∃∃f1. f1 ⋓ f2 ≘ f & ↑f1 = g1.
 193 #g1 elim (pn_split g1) *
 194 /4 width=7 by sor_inv_pnn, sor_inv_nnn, ex2_intro, or_intror, or_introl/
 195 qed-.
 196
 197 lemma sor_inv_xxn: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f. ↑f = g →
 198                    ∨∨ ∃∃f1,f2. f1 ⋓ f2 ≘ f & ↑f1 = g1 & ⫯f2 = g2
 199                     | ∃∃f1,f2. f1 ⋓ f2 ≘ f & ⫯f1 = g1 & ↑f2 = g2
 200                     | ∃∃f1,f2. f1 ⋓ f2 ≘ f & ↑f1 = g1 & ↑f2 = g2.
 201 #g1 #g2 #g #H #f #H0
 202 elim (pn_split g1) * #f1 #H1
 203 [ elim (sor_inv_pxn … H … H1 H0) -g
 204   /3 width=5 by or3_intro1, ex3_2_intro/
 205 | elim (sor_inv_nxn … H … H1 H0) -g *
 206   /3 width=5 by or3_intro0, or3_intro2, ex3_2_intro/
 207 ]
 208 qed-.
 209
 210 (* Main inversion lemmas ****************************************************)
 211
 212 corec theorem sor_mono: ∀f1,f2,x,y. f1 ⋓ f2 ≘ x → f1 ⋓ f2 ≘ y → x ≡ y.
 213 #f1 #f2 #x #y * -f1 -f2 -x
 214 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #H
 215 [ cases (sor_inv_ppx … H … H1 H2)
 216 | cases (sor_inv_npx … H … H1 H2)
 217 | cases (sor_inv_pnx … H … H1 H2)
 218 | cases (sor_inv_nnx … H … H1 H2)
 219 ] -g1 -g2
 220 /3 width=5 by eq_push, eq_next/
 221 qed-.
 222
 223 (* Basic properties *********************************************************)
 224
 225 corec lemma sor_eq_repl_back1: ∀f2,f. eq_repl_back … (λf1. f1 ⋓ f2 ≘ f).
 226 #f2 #f #f1 * -f1 -f2 -f
 227 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0 #x #Hx
 228 try cases (eq_inv_px … Hx … H1) try cases (eq_inv_nx … Hx … H1) -g1
 229 /3 width=7 by sor_pp, sor_np, sor_pn, sor_nn/
 230 qed-.
 231
 232 lemma sor_eq_repl_fwd1: ∀f2,f. eq_repl_fwd … (λf1. f1 ⋓ f2 ≘ f).
 233 #f2 #f @eq_repl_sym /2 width=3 by sor_eq_repl_back1/
 234 qed-.
 235
 236 corec lemma sor_eq_repl_back2: ∀f1,f. eq_repl_back … (λf2. f1 ⋓ f2 ≘ f).
 237 #f1 #f #f2 * -f1 -f2 -f
 238 #f1 #f2 #f #g1 #g2 #g #Hf #H #H2 #H0 #x #Hx
 239 try cases (eq_inv_px … Hx … H2) try cases (eq_inv_nx … Hx … H2) -g2
 240 /3 width=7 by sor_pp, sor_np, sor_pn, sor_nn/
 241 qed-.
 242
 243 lemma sor_eq_repl_fwd2: ∀f1,f. eq_repl_fwd … (λf2. f1 ⋓ f2 ≘ f).
 244 #f1 #f @eq_repl_sym /2 width=3 by sor_eq_repl_back2/
 245 qed-.
 246
 247 corec lemma sor_eq_repl_back3: ∀f1,f2. eq_repl_back … (λf. f1 ⋓ f2 ≘ f).
 248 #f1 #f2 #f * -f1 -f2 -f
 249 #f1 #f2 #f #g1 #g2 #g #Hf #H #H2 #H0 #x #Hx
 250 try cases (eq_inv_px … Hx … H0) try cases (eq_inv_nx … Hx … H0) -g
 251 /3 width=7 by sor_pp, sor_np, sor_pn, sor_nn/
 252 qed-.
 253
 254 lemma sor_eq_repl_fwd3: ∀f1,f2. eq_repl_fwd … (λf. f1 ⋓ f2 ≘ f).
 255 #f1 #f2 @eq_repl_sym /2 width=3 by sor_eq_repl_back3/
 256 qed-.
 257
 258 corec lemma sor_idem: ∀f. f ⋓ f ≘ f.
 259 #f cases (pn_split f) * #g #H
 260 [ @(sor_pp … H H H) | @(sor_nn … H H H) ] -H //
 261 qed.
 262
 263 corec lemma sor_comm: ∀f1,f2,f. f1 ⋓ f2 ≘ f → f2 ⋓ f1 ≘ f.
 264 #f1 #f2 #f * -f1 -f2 -f
 265 #f1 #f2 #f #g1 #g2 #g #Hf * * * -g1 -g2 -g
 266 [ @sor_pp | @sor_pn | @sor_np | @sor_nn ] /2 width=7 by/
 267 qed-.
 268
 269 (* Properties with tail *****************************************************)
 270
 271 lemma sor_tl: ∀f1,f2,f. f1 ⋓ f2 ≘ f → ⫱f1 ⋓ ⫱f2 ≘ ⫱f.
 272 #f1 cases (pn_split f1) * #g1 #H1
 273 #f2 cases (pn_split f2) * #g2 #H2
 274 #f #Hf
 275 [ cases (sor_inv_ppx … Hf … H1 H2)
 276 | cases (sor_inv_pnx … Hf … H1 H2)
 277 | cases (sor_inv_npx … Hf … H1 H2)
 278 | cases (sor_inv_nnx … Hf … H1 H2)
 279 ] -Hf #g #Hg #H destruct //
 280 qed.
 281
 282 lemma sor_xxn_tl: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f. ↑f = g →
 283                   (∃∃f1,f2. f1 ⋓ f2 ≘ f & ↑f1 = g1 & ⫱g2 = f2) ∨
 284                   (∃∃f1,f2. f1 ⋓ f2 ≘ f & ⫱g1 = f1 & ↑f2 = g2).
 285 #g1 #g2 #g #H #f #H0 elim (sor_inv_xxn … H … H0) -H -H0 *
 286 /3 width=5 by ex3_2_intro, or_introl, or_intror/
 287 qed-.
 288
 289 lemma sor_xnx_tl: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f2. ↑f2 = g2 →
 290                   ∃∃f1,f. f1 ⋓ f2 ≘ f & ⫱g1 = f1 & ↑f = g.
 291 #g1 elim (pn_split g1) * #f1 #H1 #g2 #g #H #f2 #H2
 292 [ elim (sor_inv_pnx … H … H1 H2) | elim (sor_inv_nnx … H … H1 H2) ] -g2
 293 /3 width=5 by ex3_2_intro/
 294 qed-.
 295
 296 lemma sor_nxx_tl: ∀g1,g2,g. g1 ⋓ g2 ≘ g → ∀f1. ↑f1 = g1 →
 297                   ∃∃f2,f. f1 ⋓ f2 ≘ f & ⫱g2 = f2 & ↑f = g.
 298 #g1 #g2 elim (pn_split g2) * #f2 #H2 #g #H #f1 #H1
 299 [ elim (sor_inv_npx … H … H1 H2) | elim (sor_inv_nnx … H … H1 H2) ] -g1
 300 /3 width=5 by ex3_2_intro/
 301 qed-.
 302
 303 (* Properties with iterated tail ********************************************)
 304
 305 lemma sor_tls: ∀f1,f2,f. f1 ⋓ f2 ≘ f →
 306                ∀n. ⫱*[n]f1 ⋓ ⫱*[n]f2 ≘ ⫱*[n]f.
 307 #f1 #f2 #f #Hf #n elim n -n /2 width=1 by sor_tl/
 308 qed.
 309
 310 (* Properies with test for identity *****************************************)
 311
 312 corec lemma sor_isid_sn: ∀f1. 𝐈⦃f1⦄ → ∀f2. f1 ⋓ f2 ≘ f2.
 313 #f1 * -f1
 314 #f1 #g1 #Hf1 #H1 #f2 cases (pn_split f2) *
 315 /3 width=7 by sor_pp, sor_pn/
 316 qed.
 317
 318 corec lemma sor_isid_dx: ∀f2. 𝐈⦃f2⦄ → ∀f1. f1 ⋓ f2 ≘ f1.
 319 #f2 * -f2
 320 #f2 #g2 #Hf2 #H2 #f1 cases (pn_split f1) *
 321 /3 width=7 by sor_pp, sor_np/
 322 qed.
 323
 324 lemma sor_isid: ∀f1,f2,f. 𝐈⦃f1⦄ → 𝐈⦃f2⦄ → 𝐈⦃f⦄ → f1 ⋓ f2 ≘ f.
 325 /4 width=3 by sor_eq_repl_back2, sor_eq_repl_back1, isid_inv_eq_repl/ qed.
 326
 327 (* Inversion lemmas with tail ***********************************************)
 328
 329 lemma sor_inv_tl_sn: ∀f1,f2,f. ⫱f1 ⋓ f2 ≘ f → f1 ⋓ ↑f2 ≘ ↑f.
 330 #f1 #f2 #f elim (pn_split f1) *
 331 #g1 #H destruct /2 width=7 by sor_pn, sor_nn/
 332 qed-.
 333
 334 lemma sor_inv_tl_dx: ∀f1,f2,f. f1 ⋓ ⫱f2 ≘ f → ↑f1 ⋓ f2 ≘ ↑f.
 335 #f1 #f2 #f elim (pn_split f2) *
 336 #g2 #H destruct /2 width=7 by sor_np, sor_nn/
 337 qed-.
 338
 339 (* Inversion lemmas with test for identity **********************************)
 340
 341 lemma sor_isid_inv_sn: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐈⦃f1⦄ → f2 ≡ f.
 342 /3 width=4 by sor_isid_sn, sor_mono/
 343 qed-.
 344
 345 lemma sor_isid_inv_dx: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐈⦃f2⦄ → f1 ≡ f.
 346 /3 width=4 by sor_isid_dx, sor_mono/
 347 qed-.
 348
 349 corec lemma sor_fwd_isid1: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄.
 350 #f1 #f2 #f * -f1 -f2 -f
 351 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H #Hg
 352 [ /4 width=6 by isid_inv_push, isid_push/ ]
 353 cases (isid_inv_next … Hg … H)
 354 qed-.
 355
 356 corec lemma sor_fwd_isid2: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f2⦄.
 357 #f1 #f2 #f * -f1 -f2 -f
 358 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H #Hg
 359 [ /4 width=6 by isid_inv_push, isid_push/ ]
 360 cases (isid_inv_next … Hg … H)
 361 qed-.
 362
 363 lemma sor_inv_isid3: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐈⦃f⦄ → 𝐈⦃f1⦄ ∧ 𝐈⦃f2⦄.
 364 /3 width=4 by sor_fwd_isid2, sor_fwd_isid1, conj/ qed-.
 365
 366 (* Properties with finite colength assignment *******************************)
 367
 368 lemma sor_fcla_ex: ∀f1,n1. 𝐂⦃f1⦄ ≘ n1 → ∀f2,n2. 𝐂⦃f2⦄ ≘ n2 →
 369                    ∃∃f,n. f1 ⋓ f2 ≘ f & 𝐂⦃f⦄ ≘ n & (n1 ∨ n2) ≤ n & n ≤ n1 + n2.
 370 #f1 #n1 #Hf1 elim Hf1 -f1 -n1 /3 width=6 by sor_isid_sn, ex4_2_intro/
 371 #f1 #n1 #Hf1 #IH #f2 #n2 * -f2 -n2 /3 width=6 by fcla_push, fcla_next, ex4_2_intro, sor_isid_dx/
 372 #f2 #n2 #Hf2 elim (IH … Hf2) -IH -Hf2 -Hf1 [2,4: #f #n <plus_n_Sm ] (**) (* full auto fails *)
 373 [ /3 width=7 by fcla_next, sor_pn, max_S2_le_S, le_S_S, ex4_2_intro/
 374 | /4 width=7 by fcla_next, sor_nn, le_S, le_S_S, ex4_2_intro/
 375 | /3 width=7 by fcla_push, sor_pp, ex4_2_intro/
 376 | /3 width=7 by fcla_next, sor_np, max_S1_le_S, le_S_S, ex4_2_intro/
 377 ]
 378 qed-.
 379
 380 lemma sor_fcla: ∀f1,n1. 𝐂⦃f1⦄ ≘ n1 → ∀f2,n2. 𝐂⦃f2⦄ ≘ n2 → ∀f. f1 ⋓ f2 ≘ f →
 381                 ∃∃n. 𝐂⦃f⦄ ≘ n & (n1 ∨ n2) ≤ n & n ≤ n1 + n2.
 382 #f1 #n1 #Hf1 #f2 #n2 #Hf2 #f #Hf elim (sor_fcla_ex … Hf1 … Hf2) -Hf1 -Hf2
 383 /4 width=6 by sor_mono, fcla_eq_repl_back, ex3_intro/
 384 qed-.
 385
 386 (* Forward lemmas with finite colength **************************************)
 387
 388 lemma sor_fwd_fcla_sn_ex: ∀f,n. 𝐂⦃f⦄ ≘ n → ∀f1,f2. f1 ⋓ f2 ≘ f →
 389                           ∃∃n1.  𝐂⦃f1⦄ ≘ n1 & n1 ≤ n.
 390 #f #n #H elim H -f -n
 391 [ /4 width=4 by sor_fwd_isid1, fcla_isid, ex2_intro/
 392 | #f #n #_ #IH #f1 #f2 #H
 393   elim (sor_inv_xxp … H) -H [ |*: // ] #g1 #g2 #Hf #H1 #H2 destruct
 394   elim (IH … Hf) -f /3 width=3 by fcla_push, ex2_intro/
 395 | #f #n #_ #IH #f1 #f2 #H
 396   elim (sor_inv_xxn … H) -H [1,3,4: * |*: // ] #g1 #g2 #Hf #H1 #H2 destruct
 397   elim (IH … Hf) -f /3 width=3 by fcla_push, fcla_next, le_S_S, le_S, ex2_intro/
 398 ]
 399 qed-.
 400
 401 lemma sor_fwd_fcla_dx_ex: ∀f,n. 𝐂⦃f⦄ ≘ n → ∀f1,f2. f1 ⋓ f2 ≘ f →
 402                           ∃∃n2.  𝐂⦃f2⦄ ≘ n2 & n2 ≤ n.
 403 /3 width=4 by sor_fwd_fcla_sn_ex, sor_comm/ qed-.
 404
 405 (* Properties with test for finite colength *********************************)
 406
 407 lemma sor_isfin_ex: ∀f1,f2. 𝐅⦃f1⦄ → 𝐅⦃f2⦄ → ∃∃f. f1 ⋓ f2 ≘ f & 𝐅⦃f⦄.
 408 #f1 #f2 * #n1 #H1 * #n2 #H2 elim (sor_fcla_ex … H1 … H2) -H1 -H2
 409 /3 width=4 by ex2_intro, ex_intro/
 410 qed-.
 411
 412 lemma sor_isfin: ∀f1,f2. 𝐅⦃f1⦄ → 𝐅⦃f2⦄ → ∀f. f1 ⋓ f2 ≘ f → 𝐅⦃f⦄.
 413 #f1 #f2 #Hf1 #Hf2 #f #Hf elim (sor_isfin_ex … Hf1 … Hf2) -Hf1 -Hf2
 414 /3 width=6 by sor_mono, isfin_eq_repl_back/
 415 qed-.
 416
 417 (* Forward lemmas with test for finite colength *****************************)
 418
 419 lemma sor_fwd_isfin_sn: ∀f. 𝐅⦃f⦄ → ∀f1,f2. f1 ⋓ f2 ≘ f → 𝐅⦃f1⦄.
 420 #f * #n #Hf #f1 #f2 #H
 421 elim (sor_fwd_fcla_sn_ex … Hf … H) -f -f2 /2 width=2 by ex_intro/
 422 qed-.
 423
 424 lemma sor_fwd_isfin_dx: ∀f. 𝐅⦃f⦄ → ∀f1,f2. f1 ⋓ f2 ≘ f → 𝐅⦃f2⦄.
 425 #f * #n #Hf #f1 #f2 #H
 426 elim (sor_fwd_fcla_dx_ex … Hf … H) -f -f1 /2 width=2 by ex_intro/
 427 qed-.
 428
 429 (* Inversion lemmas with test for finite colength ***************************)
 430
 431 lemma sor_inv_isfin3: ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐅⦃f⦄ → 𝐅⦃f1⦄ ∧ 𝐅⦃f2⦄.
 432 /3 width=4 by sor_fwd_isfin_dx, sor_fwd_isfin_sn, conj/ qed-.
 433
 434 (* Inversion lemmas with inclusion ******************************************)
 435
 436 corec lemma sor_inv_sle_sn: ∀f1,f2,f. f1 ⋓ f2 ≘ f → f1 ⊆ f.
 437 #f1 #f2 #f * -f1 -f2 -f
 438 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0
 439 /3 width=5 by sle_push, sle_next, sle_weak/
 440 qed-.
 441
 442 corec lemma sor_inv_sle_dx: ∀f1,f2,f. f1 ⋓ f2 ≘ f → f2 ⊆ f.
 443 #f1 #f2 #f * -f1 -f2 -f
 444 #f1 #f2 #f #g1 #g2 #g #Hf #H1 #H2 #H0
 445 /3 width=5 by sle_push, sle_next, sle_weak/
 446 qed-.
 447
 448 lemma sor_inv_sle_sn_trans: ∀f1,f2,f. f1 ⋓ f2 ≘ f → ∀g. g ⊆ f1 → g ⊆ f.
 449 /3 width=4 by sor_inv_sle_sn, sle_trans/ qed-.
 450
 451 lemma sor_inv_sle_dx_trans: ∀f1,f2,f. f1 ⋓ f2 ≘ f → ∀g. g ⊆ f2 → g ⊆ f.
 452 /3 width=4 by sor_inv_sle_dx, sle_trans/ qed-.
 453
 454 axiom sor_inv_sle: ∀f1,f2,f. f1 ⋓ f2 ≘ f → ∀g. f1 ⊆ g → f2 ⊆ g → f ⊆ g.
 455
 456 (* Properties with inclusion ************************************************)
 457
 458 corec lemma sor_sle_dx: ∀f1,f2. f1 ⊆ f2 → f1 ⋓ f2 ≘ f2.
 459 #f1 #f2 * -f1 -f2 /3 width=7 by sor_pp, sor_nn, sor_pn/
 460 qed.
 461
 462 corec lemma sor_sle_sn: ∀f1,f2. f1 ⊆ f2 → f2 ⋓ f1 ≘ f2.
 463 #f1 #f2 * -f1 -f2 /3 width=7 by sor_pp, sor_nn, sor_np/
 464 qed.
 465
 466 (* Main properties **********************************************************)
 467
 468 axiom monotonic_sle_sor: ∀f1,g1. f1 ⊆ g1 → ∀f2,g2. f2 ⊆ g2 →
 469                          ∀f. f1 ⋓ f2 ≘ f → ∀g. g1 ⋓ g2 ≘ g → f ⊆ g.
 470
 471 axiom sor_assoc_dx: ∀f0,f3,f4. f0 ⋓ f3 ≘ f4 →
 472                     ∀f1,f2. f1 ⋓ f2 ≘ f0 →
 473                     ∀f. f2 ⋓ f3 ≘ f → f1 ⋓ f ≘ f4.
 474
 475 axiom sor_assoc_sn: ∀f1,f0,f4. f1 ⋓ f0 ≘ f4 →
 476                     ∀f2, f3. f2 ⋓ f3 ≘ f0 →
 477                     ∀f. f1 ⋓ f2 ≘ f → f ⋓ f3 ≘ f4.
 478
 479 lemma sor_comm_23: ∀f0,f1,f2,f3,f4,f.
 480                    f0⋓f4 ≘ f1 → f1⋓f2 ≘ f → f0⋓f2 ≘ f3 → f3⋓f4 ≘ f.
 481 /4 width=6 by sor_comm, sor_assoc_dx/ qed-.
 482
 483 corec theorem sor_comm_23_idem: ∀f0,f1,f2. f0 ⋓ f1 ≘ f2 →
 484                                 ∀f. f1 ⋓ f2 ≘ f → f1 ⋓ f0 ≘ f.
 485 #f0 #f1 #f2 * -f0 -f1 -f2
 486 #f0 #f1 #f2 #g0 #g1 #g2 #Hf2 #H0 #H1 #H2 #g #Hg
 487 [ cases (sor_inv_ppx … Hg … H1 H2)
 488 | cases (sor_inv_pnx … Hg … H1 H2)
 489 | cases (sor_inv_nnx … Hg … H1 H2)
 490 | cases (sor_inv_nnx … Hg … H1 H2)
 491 ] -g2 #f #Hf #H
 492 /3 width=7 by sor_nn, sor_np, sor_pn, sor_pp/
 493 qed-.
 494
 495 corec theorem sor_coll_dx: ∀f1,f2,f. f1 ⋓ f2 ≘ f → ∀g1,g2,g. g1 ⋓ g2 ≘ g →
 496                            ∀g0. g1 ⋓ g0 ≘ f1 → g2 ⋓ g0 ≘ f2 → g ⋓ g0 ≘ f.
 497 #f1 #f2 #f cases (pn_split f) * #x #Hx #Hf #g1 #g2 #g #Hg #g0 #Hf1 #Hf2
 498 [ cases (sor_inv_xxp … Hf … Hx) -Hf #x1 #x2 #Hf #Hx1 #Hx2
 499   cases (sor_inv_xxp … Hf1 … Hx1) -f1 #y1 #y0 #Hf1 #Hy1 #Hy0
 500   cases (sor_inv_xpp … Hf2 … Hy0 … Hx2) -f2 #y2 #Hf2 #Hy2
 501   cases (sor_inv_ppx … Hg … Hy1 Hy2) -g1 -g2 #y #Hg #Hy
 502   @(sor_pp … Hy Hy0 Hx) -g -g0 -f /2 width=8 by/
 503 | cases (pn_split g) * #y #Hy
 504   [ cases (sor_inv_xxp … Hg … Hy) -Hg #y1 #y2 #Hg #Hy1 #Hy2
 505     cases (sor_xxn_tl … Hf … Hx) * #x1 #x2 #_ #Hx1 #Hx2
 506     [ cases (sor_inv_pxn … Hf1 … Hy1 Hx1) -g1 #y0 #Hf1 #Hy0
 507       cases (sor_inv_pnx … Hf2 … Hy2 Hy0) -g2 -x2 #x2 #Hf2 #Hx2
 508     | cases (sor_inv_pxn … Hf2 … Hy2 Hx2) -g2 #y0 #Hf2 #Hy0
 509       cases (sor_inv_pnx … Hf1 … Hy1 Hy0) -g1 -x1 #x1 #Hf1 #Hx1
 510     ]
 511     lapply (sor_inv_nnn … Hf … Hx1 Hx2 Hx) -f1 -f2 #Hf
 512     @(sor_pn … Hy Hy0 Hx) -g -g0 -f /2 width=8 by/
 513   | lapply (sor_tl … Hf) -Hf #Hf
 514     lapply (sor_tl … Hg) -Hg #Hg
 515     lapply (sor_tl … Hf1) -Hf1 #Hf1
 516     lapply (sor_tl … Hf2) -Hf2 #Hf2
 517     cases (pn_split g0) * #y0 #Hy0
 518     [ @(sor_np … Hy Hy0 Hx) /2 width=8 by/
 519     | @(sor_nn … Hy Hy0 Hx) /2 width=8 by/
 520     ]
 521   ]
 522 ]
 523 qed-.
 524
 525 corec theorem sor_distr_dx: ∀g0,g1,g2,g. g1 ⋓ g2 ≘ g →
 526                             ∀f1,f2,f. g1 ⋓ g0 ≘ f1 → g2 ⋓ g0 ≘ f2 → g ⋓ g0 ≘ f →
 527                             f1 ⋓ f2 ≘ f.
 528 #g0 cases (pn_split g0) * #y0 #H0 #g1 #g2 #g
 529 [ * -g1 -g2 -g #y1 #y2 #y #g1 #g2 #g #Hy #Hy1 #Hy2 #Hy #f1 #f2 #f #Hf1 #Hf2 #Hf
 530   [ cases (sor_inv_ppx … Hf1 … Hy1 H0) -g1
 531     cases (sor_inv_ppx … Hf2 … Hy2 H0) -g2
 532     cases (sor_inv_ppx … Hf … Hy H0) -g
 533   | cases (sor_inv_npx … Hf1 … Hy1 H0) -g1
 534     cases (sor_inv_ppx … Hf2 … Hy2 H0) -g2
 535     cases (sor_inv_npx … Hf … Hy H0) -g
 536   | cases (sor_inv_ppx … Hf1 … Hy1 H0) -g1
 537     cases (sor_inv_npx … Hf2 … Hy2 H0) -g2
 538     cases (sor_inv_npx … Hf … Hy H0) -g
 539   | cases (sor_inv_npx … Hf1 … Hy1 H0) -g1
 540     cases (sor_inv_npx … Hf2 … Hy2 H0) -g2
 541     cases (sor_inv_npx … Hf … Hy H0) -g
 542   ] -g0 #y #Hy #H #y2 #Hy2 #H2 #y1 #Hy1 #H1
 543   /3 width=8 by sor_nn, sor_np, sor_pn, sor_pp/
 544 | #H #f1 #f2 #f #Hf1 #Hf2 #Hf
 545   cases (sor_xnx_tl … Hf1 … H0) -Hf1
 546   cases (sor_xnx_tl … Hf2 … H0) -Hf2
 547   cases (sor_xnx_tl … Hf … H0) -Hf
 548   -g0 #y #x #Hx #Hy #H #y2 #x2 #Hx2 #Hy2 #H2 #y1 #x1 #Hx1 #Hy1 #H1
 549   /4 width=8 by sor_tl, sor_nn/
 550 ]
 551 qed-.