matita/matita/contribs/lambdadelta/ground_2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "ground_2/xoa_props.ma".
  17 include "ground_2/notation.ma".
  18
  19 (* PROPERTIES OF RELATIONS **************************************************)
  20
  21 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  22
  23 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  24                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  25
  26 definition confluent2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  27                        ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  28                        ∃∃a. R2 a1 a & R1 a2 a.
  29
  30 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  31                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  32                         ∃∃a. R2 a1 a & R1 a a2.
  33
  34 definition bi_confluent:  ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
  35                           ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  36                           ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  37
  38 lemma TC_strip1: ∀A,R1,R2. confluent2 A R1 R2 →
  39                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  40                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  41 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  42 [ #a1 #Ha01 #a2 #Ha02
  43   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  44 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  45   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  46   elim (HR12 … Ha1 … Ha0) -HR12 -a /4 width=5/
  47 ]
  48 qed.
  49
  50 lemma TC_strip2: ∀A,R1,R2. confluent2 A R1 R2 →
  51                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  52                  ∃∃a. TC … R2 a1 a & R1 a2 a.
  53 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  54 [ #a2 #Ha02 #a1 #Ha01
  55   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  56 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  57   elim (IHa0 … Ha01) -a0 #a0 #Ha10 #Ha0
  58   elim (HR12 … Ha0 … Ha2) -HR12 -a /4 width=3/
  59 ]
  60 qed.
  61
  62 lemma TC_confluent2: ∀A,R1,R2.
  63                      confluent2 A R1 R2 → confluent2 A (TC … R1) (TC … R2).
  64 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  65 [ #a1 #Ha01 #a2 #Ha02
  66   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 -a0 /3 width=3/
  67 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  68   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  69   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 -a /4 width=5/
  70 ]
  71 qed.
  72
  73 lemma TC_strap1: ∀A,R1,R2. transitive2 A R1 R2 →
  74                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  75                  ∃∃a. R2 a1 a & TC … R1 a a2.
  76 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  77 [ #a0 #Ha10 #a2 #Ha02
  78   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  79 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  80   elim (HR12 … Ha0 … Ha02) -HR12 -a0 #a0 #Ha0 #Ha02
  81   elim (IHa … Ha0) -a /4 width=5/
  82 ]
  83 qed.
  84
  85 lemma TC_strap2: ∀A,R1,R2. transitive2 A R1 R2 →
  86                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  87                  ∃∃a. TC … R2 a1 a & R1 a a2.
  88 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  89 [ #a2 #Ha02 #a1 #Ha10
  90   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  91 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
  92   elim (IHa … Ha10) -a0 #a0 #Ha10 #Ha0
  93   elim (HR12 … Ha0 … Ha02) -HR12 -a /4 width=3/
  94 ]
  95 qed.
  96
  97 lemma TC_transitive2: ∀A,R1,R2.
  98                       transitive2 A R1 R2 → transitive2 A (TC … R1) (TC … R2).
  99 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
 100 [ #a0 #Ha10 #a2 #Ha02
 101   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 -a0 /3 width=3/
 102 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
 103   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 -a0 #a0 #Ha0 #Ha02
 104   elim (IHa … Ha0) -a /4 width=5/
 105 ]
 106 qed.
 107
 108 definition NF: ∀A. relation A → relation A → predicate A ≝
 109    λA,R,S,a1. ∀a2. R a1 a2 → S a2 a1.
 110
 111 inductive SN (A) (R,S:relation A): predicate A ≝
 112 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a2 a1 → ⊥) → SN A R S a2) → SN A R S a1
 113 .
 114
 115 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 116 #A #R #S #a1 #Ha1
 117 @SN_intro #a2 #HRa12 #HSa12
 118 elim (HSa12 ?) -HSa12 /2 width=1/
 119 qed.
 120
 121 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 122    λA,R,S,a2. ∀a1. R a1 a2 → S a2 a1.
 123
 124 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 125 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a2 a1 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 126 .
 127
 128 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 129 #A #R #S #a2 #Ha2
 130 @SN_sn_intro #a1 #HRa12 #HSa12
 131 elim (HSa12 ?) -HSa12 /2 width=1/
 132 qed.
 133
 134 lemma bi_TC_strip: ∀A,B,R. bi_confluent A B R →
 135                    ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. bi_TC … R a0 b0 a2 b2 →
 136                    ∃∃a,b. bi_TC … R a1 b1 a b & R a2 b2 a b.
 137 #A #B #R #HR #a0 #a1 #b0 #b1 #H01 #a2 #b2 #H elim H -a2 -b2
 138 [ #a2 #b2 #H02
 139   elim (HR … H01 … H02) -HR -a0 -b0 /3 width=4/
 140 | #a2 #b2 #a3 #b3 #_ #H23 * #a #b #H1 #H2
 141   elim (HR … H23 … H2) -HR -a0 -b0 -a2 -b2 /3 width=4/
 142 ]
 143 qed.
 144
 145 lemma bi_TC_confluent: ∀A,B,R. bi_confluent A B R →
 146                        bi_confluent A B (bi_TC … R).
 147 #A #B #R #HR #a0 #a1 #b0 #b1 #H elim H -a1 -b1
 148 [ #a1 #b1 #H01 #a2 #b2 #H02
 149   elim (bi_TC_strip … HR … H01 … H02) -a0 -b0 /3 width=4/
 150 | #a1 #b1 #a3 #b3 #_ #H13 #IH #a2 #b2 #H02
 151   elim (IH … H02) -a0 -b0 #a0 #b0 #H10 #H20
 152   elim (bi_TC_strip … HR … H13 … H10) -a1 -b1 /3 width=7/
 153 ]
 154 qed.
 155
 156 lemma bi_TC_decomp_r: ∀A,B. ∀R:bi_relation A B.
 157                       ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 158                       R a1 b1 a2 b2 ∨
 159                       ∃∃a,b. bi_TC … R a1 b1 a b & R a b a2 b2.
 160 #A #B #R #a1 #a2 #b1 #b2 * -a2 -b2 /2 width=1/ /3 width=4/
 161 qed-.
 162
 163 lemma bi_TC_decomp_l: ∀A,B. ∀R:bi_relation A B.
 164                       ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 165                       R a1 b1 a2 b2 ∨
 166                       ∃∃a,b. R a1 b1 a b & bi_TC … R a b a2 b2.
 167 #A #B #R #a1 #a2 #b1 #b2 #H @(bi_TC_ind_dx ?????????? H) -a1 -b1
 168 [ /2 width=1/
 169 | #a1 #a #b1 #b #Hab1 #Hab2 #_ /3 width=4/
 170 ]
 171 qed-.