matita/matita/contribs/lambdadelta/ground_2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "ground_2/xoa_props.ma".
  17 include "ground_2/notation.ma".
  18
  19 (* PROPERTIES OF RELATIONS **************************************************)
  20
  21 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  22
  23 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  24                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  25
  26 definition confluent2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  27                        ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  28                        ∃∃a. R2 a1 a & R1 a2 a.
  29
  30 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  31                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  32                         ∃∃a. R2 a1 a & R1 a a2.
  33
  34 definition bi_confluent:  ∀A,B. ∀R: bi_relation A B. Prop ≝ λA,B,R.
  35                           ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  36                           ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  37
  38 definition LTC: ∀A:Type[0]. ∀B. (A→relation B) → (A→relation B) ≝
  39                 λA,B,R,a. TC … (R a).
  40
  41 definition s_r_trans: ∀A,B. relation2 (A→relation B) (relation A) ≝ λA,B,R1,R2.
  42                       ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → LTC … R1 L1 T1 T2.
  43
  44 definition s_rs_trans: ∀A,B. relation2 (A→relation B) (relation A) ≝ λA,B,R1,R2.
  45                        ∀L2,T1,T2. LTC … R1 L2 T1 T2 → ∀L1. R2 L1 L2 → LTC … R1 L1 T1 T2.
  46
  47 lemma TC_strip1: ∀A,R1,R2. confluent2 A R1 R2 →
  48                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  49                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  50 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  51 [ #a1 #Ha01 #a2 #Ha02
  52   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  53 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  54   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  55   elim (HR12 … Ha1 … Ha0) -HR12 -a /4 width=5/
  56 ]
  57 qed.
  58
  59 lemma TC_strip2: ∀A,R1,R2. confluent2 A R1 R2 →
  60                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  61                  ∃∃a. TC … R2 a1 a & R1 a2 a.
  62 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  63 [ #a2 #Ha02 #a1 #Ha01
  64   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  65 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  66   elim (IHa0 … Ha01) -a0 #a0 #Ha10 #Ha0
  67   elim (HR12 … Ha0 … Ha2) -HR12 -a /4 width=3/
  68 ]
  69 qed.
  70
  71 lemma TC_confluent2: ∀A,R1,R2.
  72                      confluent2 A R1 R2 → confluent2 A (TC … R1) (TC … R2).
  73 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  74 [ #a1 #Ha01 #a2 #Ha02
  75   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 -a0 /3 width=3/
  76 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  77   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  78   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 -a /4 width=5/
  79 ]
  80 qed.
  81
  82 lemma TC_strap1: ∀A,R1,R2. transitive2 A R1 R2 →
  83                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  84                  ∃∃a. R2 a1 a & TC … R1 a a2.
  85 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  86 [ #a0 #Ha10 #a2 #Ha02
  87   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  88 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  89   elim (HR12 … Ha0 … Ha02) -HR12 -a0 #a0 #Ha0 #Ha02
  90   elim (IHa … Ha0) -a /4 width=5/
  91 ]
  92 qed.
  93
  94 lemma TC_strap2: ∀A,R1,R2. transitive2 A R1 R2 →
  95                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  96                  ∃∃a. TC … R2 a1 a & R1 a a2.
  97 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  98 [ #a2 #Ha02 #a1 #Ha10
  99   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
 100 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
 101   elim (IHa … Ha10) -a0 #a0 #Ha10 #Ha0
 102   elim (HR12 … Ha0 … Ha02) -HR12 -a /4 width=3/
 103 ]
 104 qed.
 105
 106 lemma TC_transitive2: ∀A,R1,R2.
 107                       transitive2 A R1 R2 → transitive2 A (TC … R1) (TC … R2).
 108 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
 109 [ #a0 #Ha10 #a2 #Ha02
 110   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 -a0 /3 width=3/
 111 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
 112   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 -a0 #a0 #Ha0 #Ha02
 113   elim (IHa … Ha0) -a /4 width=5/
 114 ]
 115 qed.
 116
 117 definition NF: ∀A. relation A → relation A → predicate A ≝
 118    λA,R,S,a1. ∀a2. R a1 a2 → S a2 a1.
 119
 120 definition NF_dec: ∀A. relation A → relation A → Prop ≝
 121                    λA,R,S. ∀a1. NF A R S a1 ∨
 122                    ∃∃a2. R … a1 a2 & (S a2 a1 → ⊥).
 123
 124 inductive SN (A) (R,S:relation A): predicate A ≝
 125 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a2 a1 → ⊥) → SN A R S a2) → SN A R S a1
 126 .
 127
 128 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 129 #A #R #S #a1 #Ha1
 130 @SN_intro #a2 #HRa12 #HSa12
 131 elim HSa12 -HSa12 /2 width=1/
 132 qed.
 133
 134 lemma SN_to_NF: ∀A,R,S. NF_dec A R S →
 135                 ∀a1. SN A R S a1 →
 136                 ∃∃a2. star … R a1 a2 & NF A R S a2.
 137 #A #R #S #HRS #a1 #H elim H -a1
 138 #a1 #_ #IHa1 elim (HRS a1) -HRS /2 width=3/
 139 * #a0 #Ha10 #Ha01 elim (IHa1 … Ha10 Ha01) -IHa1 -Ha01 /3 width=3/
 140 qed-.
 141
 142 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 143    λA,R,S,a2. ∀a1. R a1 a2 → S a2 a1.
 144
 145 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 146 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a2 a1 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 147 .
 148
 149 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 150 #A #R #S #a2 #Ha2
 151 @SN_sn_intro #a1 #HRa12 #HSa12
 152 elim HSa12 -HSa12 /2 width=1/
 153 qed.
 154
 155 lemma bi_TC_strip: ∀A,B,R. bi_confluent A B R →
 156                    ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. bi_TC … R a0 b0 a2 b2 →
 157                    ∃∃a,b. bi_TC … R a1 b1 a b & R a2 b2 a b.
 158 #A #B #R #HR #a0 #a1 #b0 #b1 #H01 #a2 #b2 #H elim H -a2 -b2
 159 [ #a2 #b2 #H02
 160   elim (HR … H01 … H02) -HR -a0 -b0 /3 width=4/
 161 | #a2 #b2 #a3 #b3 #_ #H23 * #a #b #H1 #H2
 162   elim (HR … H23 … H2) -HR -a0 -b0 -a2 -b2 /3 width=4/
 163 ]
 164 qed.
 165
 166 lemma bi_TC_confluent: ∀A,B,R. bi_confluent A B R →
 167                        bi_confluent A B (bi_TC … R).
 168 #A #B #R #HR #a0 #a1 #b0 #b1 #H elim H -a1 -b1
 169 [ #a1 #b1 #H01 #a2 #b2 #H02
 170   elim (bi_TC_strip … HR … H01 … H02) -a0 -b0 /3 width=4/
 171 | #a1 #b1 #a3 #b3 #_ #H13 #IH #a2 #b2 #H02
 172   elim (IH … H02) -a0 -b0 #a0 #b0 #H10 #H20
 173   elim (bi_TC_strip … HR … H13 … H10) -a1 -b1 /3 width=7/
 174 ]
 175 qed.
 176
 177 lemma bi_TC_decomp_r: ∀A,B. ∀R:bi_relation A B.
 178                       ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 179                       R a1 b1 a2 b2 ∨
 180                       ∃∃a,b. bi_TC … R a1 b1 a b & R a b a2 b2.
 181 #A #B #R #a1 #a2 #b1 #b2 * -a2 -b2 /2 width=1/ /3 width=4/
 182 qed-.
 183
 184 lemma bi_TC_decomp_l: ∀A,B. ∀R:bi_relation A B.
 185                       ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 186                       R a1 b1 a2 b2 ∨
 187                       ∃∃a,b. R a1 b1 a b & bi_TC … R a b a2 b2.
 188 #A #B #R #a1 #a2 #b1 #b2 #H @(bi_TC_ind_dx … a1 b1 H) -a1 -b1
 189 [ /2 width=1/
 190 | #a1 #a #b1 #b #Hab1 #Hab2 #_ /3 width=4/
 191 ]
 192 qed-.
 193
 194 lemma s_r_trans_TC1: ∀A,B,R,S. s_r_trans A B R S → s_rs_trans A B R S.
 195 #A #B #R #S #HRS #L2 #T1 #T2 #H elim H -T2 [ /3 width=3/ ]
 196 #T #T2 #_ #HT2 #IHT1 #L1 #HL12
 197 lapply (HRS … HT2 … HL12) -HRS -HT2 /3 width=3/
 198 qed-.
 199
 200 lemma s_r_trans_TC2: ∀A,B,R,S. s_rs_trans A B R S → s_r_trans A B R (TC … S).
 201 #A #B #R #S #HRS #L2 #T1 #T2 #HT12 #L1 #H @(TC_ind_dx … L1 H) -L1 /2 width=3/ /3 width=3/
 202 qed-.