matita/matita/contribs/lambdadelta/ground_2/steps/rtc_isrt_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_3_2.ma".
  16 include "ground_2/steps/rtc_plus.ma".
  17 include "ground_2/steps/rtc_isrt.ma".
  18
  19 (* RT-TRANSITION COUNTER ****************************************************)
  20
  21 (* Properties with test for constrained rt-transition counter ***************)
  22
  23 lemma isrt_plus: ∀n1,n2,c1,c2. 𝐑𝐓❪n1,c1❫ → 𝐑𝐓❪n2,c2❫ → 𝐑𝐓❪n1+n2,c1+c2❫.
  24 #n1 #n2 #c1 #c2 * #ri1 #rs1 #H1 * #ri2 #rs2 #H2 destruct
  25 /2 width=3 by ex1_2_intro/
  26 qed.
  27
  28 lemma isrt_plus_O1: ∀n,c1,c2. 𝐑𝐓❪0,c1❫ → 𝐑𝐓❪n,c2❫ → 𝐑𝐓❪n,c1+c2❫.
  29 /2 width=1 by isrt_plus/ qed.
  30
  31 lemma isrt_plus_O2: ∀n,c1,c2. 𝐑𝐓❪n,c1❫ → 𝐑𝐓❪0,c2❫ → 𝐑𝐓❪n,c1+c2❫.
  32 #n #c1 #c2 #H1 #H2 >(plus_n_O n) /2 width=1 by isrt_plus/
  33 qed.
  34
  35 lemma isrt_succ: ∀n,c. 𝐑𝐓❪n,c❫ → 𝐑𝐓❪↑n,c+𝟘𝟙❫.
  36 /2 width=1 by isrt_plus/ qed.
  37
  38 (* Inversion properties with test for constrained rt-transition counter *****)
  39
  40 lemma isrt_inv_plus: ∀n,c1,c2. 𝐑𝐓❪n,c1 + c2❫ →
  41                      ∃∃n1,n2. 𝐑𝐓❪n1,c1❫ & 𝐑𝐓❪n2,c2❫ & n1 + n2 = n.
  42 #n #c1 #c2 * #ri #rs #H
  43 elim (plus_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #_ #_ #H1 #H2 #H3 #H4
  44 elim (plus_inv_O3 … H1) -H1 /3 width=5 by ex3_2_intro, ex1_2_intro/
  45 qed-.
  46
  47 lemma isrt_inv_plus_O_dx: ∀n,c1,c2. 𝐑𝐓❪n,c1 + c2❫ → 𝐑𝐓❪0,c2❫ → 𝐑𝐓❪n,c1❫.
  48 #n #c1 #c2 #H #H2
  49 elim (isrt_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  50 lapply (isrt_inj … Hn2 H2) -c2 #H destruct //
  51 qed-.
  52
  53 lemma isrt_inv_plus_SO_dx: ∀n,c1,c2. 𝐑𝐓❪n,c1 + c2❫ → 𝐑𝐓❪1,c2❫ →
  54                            ∃∃m. 𝐑𝐓❪m,c1❫ & n = ↑m.
  55 #n #c1 #c2 #H #H2
  56 elim (isrt_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  57 lapply (isrt_inj … Hn2 H2) -c2 #H destruct
  58 /2 width=3 by ex2_intro/
  59 qed-.