matita/matita/contribs/lambdadelta/ground_2/steps/rtc_ist_max.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_3_2.ma".
  16 include "ground_2/steps/rtc_max.ma".
  17 include "ground_2/steps/rtc_ist.ma".
  18
  19 (* RT-TRANSITION COUNTER ****************************************************)
  20
  21 (* Properties with test for t-transition counter ****************************)
  22
  23 lemma ist_max: ∀n1,n2,c1,c2. 𝐓❪n1,c1❫ → 𝐓❪n2,c2❫ → 𝐓❪n1∨n2,c1∨c2❫.
  24 #n1 #n2 #c1 #c2 #H1 #H2 destruct //
  25 qed.
  26
  27 lemma ist_max_O1: ∀n,c1,c2. 𝐓❪0,c1❫ → 𝐓❪n,c2❫ → 𝐓❪n,c1∨c2❫.
  28 /2 width=1 by ist_max/ qed.
  29
  30 lemma ist_max_O2: ∀n,c1,c2. 𝐓❪n,c1❫ → 𝐓❪0,c2❫ → 𝐓❪n,c1∨c2❫.
  31 #n #c1 #c2 #H1 #H2 >(max_O2 n) /2 width=1 by ist_max/
  32 qed.
  33
  34 lemma ist_max_idem1: ∀n,c1,c2. 𝐓❪n,c1❫ → 𝐓❪n,c2❫ → 𝐓❪n,c1∨c2❫.
  35 #n #c1 #c2 #H1 #H2 >(idempotent_max n) /2 width=1 by ist_max/
  36 qed.
  37
  38 (* Inversion properties with test for t-transition counter ******************)
  39
  40 lemma ist_inv_max:
  41       ∀n,c1,c2. 𝐓❪n,c1 ∨ c2❫ →
  42       ∃∃n1,n2. 𝐓❪n1,c1❫ & 𝐓❪n2,c2❫ & (n1 ∨ n2) = n.
  43 #n #c1 #c2 #H
  44 elim (max_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #H1 #H2 #H3 #H4 #H5 #H6 destruct
  45 elim (max_inv_O3 … H1) -H1 #H11 #H12 destruct
  46 elim (max_inv_O3 … H2) -H2 #H21 #H22 destruct
  47 elim (max_inv_O3 … H3) -H3 #H31 #H32 destruct
  48 /2 width=5 by ex3_2_intro/
  49 qed-.
  50
  51 lemma ist_O_inv_max: ∀c1,c2. 𝐓❪0,c1 ∨ c2❫ → ∧∧ 𝐓❪0,c1❫ & 𝐓❪0,c2❫.
  52 #c1 #c2 #H
  53 elim (ist_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H
  54 elim (max_inv_O3 … H) -H #H1 #H2 destruct
  55 /2 width=1 by conj/
  56 qed-.
  57
  58 lemma ist_inv_max_O_dx: ∀n,c1,c2. 𝐓❪n,c1 ∨ c2❫ → 𝐓❪0,c2❫ → 𝐓❪n,c1❫.
  59 #n #c1 #c2 #H #H2
  60 elim (ist_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct //
  61 qed-.