matita/matita/contribs/lambdadelta/ground_2/steps/rtc_ist_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/steps/rtc_plus.ma".
  16 include "ground_2/steps/rtc_ist.ma".
  17
  18 (* RT-TRANSITION COUNTER ****************************************************)
  19
  20 (* Properties with test for t-transition counter ****************************)
  21
  22 lemma ist_plus: ∀n1,n2,c1,c2. 𝐓⦃n1,c1⦄ → 𝐓⦃n2,c2⦄ → 𝐓⦃n1+n2,c1+c2⦄.
  23 #n1 #n2 #c1 #c2 #H1 #H2 destruct //
  24 qed.
  25
  26 lemma ist_plus_O1: ∀n,c1,c2. 𝐓⦃0,c1⦄ → 𝐓⦃n,c2⦄ → 𝐓⦃n,c1+c2⦄.
  27 /2 width=1 by ist_plus/ qed.
  28
  29 lemma ist_plus_O2: ∀n,c1,c2. 𝐓⦃n,c1⦄ → 𝐓⦃0,c2⦄ → 𝐓⦃n,c1+c2⦄.
  30 #n #c1 #c2 #H1 #H2 >(plus_n_O n) /2 width=1 by ist_plus/
  31 qed.
  32
  33 lemma ist_succ: ∀n,c. 𝐓⦃n,c⦄ → 𝐓⦃↑n,c+𝟘𝟙⦄.
  34 /2 width=1 by ist_plus/ qed.
  35
  36 (* Inversion properties with test for constrained rt-transition counter *****)
  37
  38 lemma ist_inv_plus:
  39       ∀n,c1,c2. 𝐓⦃n,c1 + c2⦄ →
  40       ∃∃n1,n2. 𝐓⦃n1,c1⦄ & 𝐓⦃n2,c2⦄ & n1 + n2 = n.
  41 #n #c1 #c2 #H
  42 elim (plus_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #H1 #H2 #H3 #H4 #H5 #H6 destruct
  43 elim (plus_inv_O3 … H1) -H1 #H11 #H12 destruct
  44 elim (plus_inv_O3 … H2) -H2 #H21 #H22 destruct
  45 elim (plus_inv_O3 … H3) -H3 #H31 #H32 destruct
  46 /3 width=5 by ex3_2_intro/
  47 qed-.
  48
  49 lemma ist_inv_plus_O_dx: ∀n,c1,c2. 𝐓⦃n,c1 + c2⦄ → 𝐓⦃0,c2⦄ → 𝐓⦃n,c1⦄.
  50 #n #c1 #c2 #H #H2
  51 elim (ist_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct //
  52 qed-.
  53
  54 lemma ist_inv_plus_SO_dx:
  55       ∀n,c1,c2. 𝐓⦃n,c1 + c2⦄ → 𝐓⦃1,c2⦄ →
  56       ∃∃m. 𝐓⦃m,c1⦄ & n = ↑m.
  57 #n #c1 #c2 #H #H2 destruct
  58 elim (ist_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  59 /2 width=3 by ex2_intro/
  60 qed-.