matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_le.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_succ.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* order relation *)
  20 inductive yle: relation ynat ≝
  21 | yle_inj: ∀m,n. m ≤ n → yle m n
  22 | yle_Y  : ∀m. yle m (∞)
  23 .
  24
  25 interpretation "ynat 'less or equal to'" 'leq x y = (yle x y).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact yle_inv_inj2_aux: ∀x,y. x ≤ y → ∀n. y = yinj n →
  30                        ∃∃m. m ≤ n & x = yinj m.
  31 #x #y * -x -y
  32 [ #x #y #Hxy #n #Hy destruct /2 width=3 by ex2_intro/
  33 | #x #n #Hy destruct
  34 ]
  35 qed-.
  36
  37 lemma yle_inv_inj2: ∀x,n. x ≤ yinj n → ∃∃m. m ≤ n & x = yinj m.
  38 /2 width=3 by yle_inv_inj2_aux/ qed-.
  39
  40 lemma yle_inv_inj: ∀m,n. yinj m ≤ yinj n → m ≤ n.
  41 #m #n #H elim (yle_inv_inj2 … H) -H
  42 #x #Hxn #H destruct //
  43 qed-.
  44
  45 fact yle_inv_O2_aux: ∀m:ynat. ∀x:ynat. m ≤ x → x = 0 → m = 0.
  46 #m #x * -m -x
  47 [ #m #n #Hmn #H destruct /3 width=1 by le_n_O_to_eq, eq_f/
  48 | #m #H destruct
  49 ]
  50 qed-.
  51
  52 lemma yle_inv_O2: ∀m:ynat. m ≤ 0 → m = 0.
  53 /2 width =3 by yle_inv_O2_aux/ qed-.
  54
  55 fact yle_inv_Y1_aux: ∀x,n. x ≤ n → x = ∞ → n = ∞.
  56 #x #n * -x -n //
  57 #x #n #_ #H destruct
  58 qed-.
  59
  60 lemma yle_inv_Y1: ∀n. ∞ ≤ n → n = ∞.
  61 /2 width=3 by yle_inv_Y1_aux/ qed-.
  62
  63 (* Basic properties *********************************************************)
  64
  65 lemma le_O1: ∀n:ynat. 0 ≤ n.
  66 * /2 width=1 by yle_inj/
  67 qed.
  68
  69 lemma yle_refl: reflexive … yle.
  70 * /2 width=1 by le_n, yle_inj/
  71 qed.
  72
  73 lemma yle_split: ∀x,y:ynat. x ≤ y ∨ y ≤ x.
  74 * /2 width=1 by or_intror/
  75 #x * /2 width=1 by or_introl/
  76 #y elim (le_or_ge x y) /3 width=1 by yle_inj, or_introl, or_intror/
  77 qed-.
  78
  79 (* Inversion lemmas on successor ********************************************)
  80
  81 fact yle_inv_succ1_aux: ∀x,y. x ≤ y → ∀m. x = ⫯m → m ≤ ⫰y ∧ ⫯⫰y = y.
  82 #x #y * -x -y
  83 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  84   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  85   #m #Hnm #H destruct /3 width=1 by yle_inj, conj/
  86 | #x #y #H destruct /2 width=1 by yle_Y, conj/
  87 ]
  88 qed-.
  89
  90 lemma yle_inv_succ1: ∀m,y. ⫯m ≤ y → m ≤ ⫰y ∧ ⫯⫰y = y.
  91 /2 width=3 by yle_inv_succ1_aux/ qed-.
  92
  93 lemma yle_inv_succ: ∀m,n. ⫯m ≤ ⫯n → m ≤ n.
  94 #m #n #H elim (yle_inv_succ1 … H) -H //
  95 qed-.
  96
  97 lemma yle_inv_succ2: ∀x,y. x ≤ ⫯y → ⫰x ≤ y.
  98 #x #y #Hxy elim (ynat_cases x)
  99 [ #H destruct //
 100 | * #m #H destruct /2 width=1 by yle_inv_succ/
 101 ]
 102 qed-.
 103
 104 (* Properties on predecessor ************************************************)
 105
 106 lemma yle_pred_sn: ∀m,n. m ≤ n → ⫰m ≤ n.
 107 #m #n * -m -n /3 width=3 by transitive_le, yle_inj/
 108 qed.
 109
 110 lemma yle_refl_pred_sn: ∀x. ⫰x ≤ x.
 111 /2 width=1 by yle_refl, yle_pred_sn/ qed.
 112
 113 lemma yle_pred: ∀m,n. m ≤ n → ⫰m ≤ ⫰n.
 114 #m #n * -m -n /3 width=1 by yle_inj, monotonic_pred/
 115 qed.
 116
 117 (* Properties on successor **************************************************)
 118
 119 lemma yle_succ: ∀m,n. m ≤ n → ⫯m ≤ ⫯n.
 120 #m #n * -m -n /3 width=1 by yle_inj, le_S_S/
 121 qed.
 122
 123 lemma yle_succ_dx: ∀m,n. m ≤ n → m ≤ ⫯n.
 124 #m #n * -m -n /3 width=1 by le_S, yle_inj/
 125 qed.
 126
 127 lemma yle_refl_S_dx: ∀x. x ≤ ⫯x.
 128 /2 width=1 by yle_succ_dx/ qed.
 129
 130 lemma yle_refl_SP_dx: ∀x. x ≤ ⫯⫰x.
 131 * // * //
 132 qed.
 133
 134 lemma yle_succ2: ∀x,y. ⫰x ≤ y → x ≤ ⫯y.
 135 #x #y #Hxy elim (ynat_cases x)
 136 [ #H destruct //
 137 | * #m #H destruct /2 width=1 by yle_succ/
 138 ]
 139 qed-.
 140
 141 (* Main properties **********************************************************)
 142
 143 theorem yle_trans: Transitive … yle.
 144 #x #y * -x -y
 145 [ #x #y #Hxy * //
 146   #z #H lapply (yle_inv_inj … H) -H
 147   /3 width=3 by transitive_le, yle_inj/ (**) (* full auto too slow *)
 148 | #x #z #H lapply (yle_inv_Y1 … H) //
 149 ]
 150 qed-.