matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  30                        ∃∃m. m < n & x = yinj m.
  31 #x #y * -x -y
  32 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  33   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  34 | #x #n #Hy destruct
  35 ]
  36 qed-.
  37
  38 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  39                     ∃∃m. m < n & x = yinj m.
  40 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  41
  42 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  43 #m #n #H elim (ylt_inv_inj2 … H) -H
  44 #x #Hx #H destruct //
  45 qed-.
  46
  47 fact ylt_inv_Y2_aux: ∀x,y. x < y → y = ∞ → ∃m. x = yinj m.
  48 #x #y * -x -y /2 width=2 by ex_intro/
  49 qed-.
  50
  51 lemma ylt_inv_Y2: ∀x. x < ∞ → ∃m. x = yinj m.
  52 /2 width=3 by ylt_inv_Y2_aux/ qed-.
  53
  54 (* Inversion lemmas on successor ********************************************)
  55
  56 fact ylt_inv_succ1_aux: ∀x,y. x < y → ∀m. x = ⫯m → ∃∃n. m < n & y = ⫯n.
  57 #x #y * -x -y
  58 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  59   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  60   #m #Hnm #H destruct
  61   @(ex2_intro … m) /2 width=1 by ylt_inj/ (**) (* explicit constructor *)
  62 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  63   #m #H #_ destruct
  64   @(ex2_intro … (∞)) /2 width=1 by/ (**) (* explicit constructor *)
  65 ]
  66 qed-.
  67
  68 lemma ylt_inv_succ1: ∀m,y.  ⫯m < y → ∃∃n. m < n & y = ⫯n.
  69 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  70
  71 lemma yle_inv_succ: ∀m,n. ⫯m < ⫯n → m < n.
  72 #m #n #H elim (ylt_inv_succ1 … H) -H
  73 #x #Hx #H destruct //
  74 qed-.
  75
  76 fact ylt_inv_succ2_aux: ∀x,y. x < y → ∀n. y = ⫯n → x ≤ n.
  77 #x #y * -x -y
  78 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  79   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  80 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  81 ]
  82 qed-.
  83
  84 lemma ylt_inv_succ2: ∀m,n. m < ⫯n → m ≤ n.
  85 /2 width=3 by ylt_inv_succ2_aux/ qed-.
  86
  87 (* inversion and forward lemmas on yle **************************************)
  88
  89 lemma lt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
  90 #m #n * -m -n /3 width=1 by yle_pred_sn, yle_inj, yle_Y/
  91 qed-.
  92
  93 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
  94 #m #n * -m -n
  95 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
  96   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
  97 | #m #H lapply (yle_inv_Y1 … H) -H
  98   #H destruct
  99 ]
 100 qed-.
 101
 102 (* Properties on yle ********************************************************)
 103
 104 lemma yle_to_ylt_or_eq: ∀m:ynat. ∀n:ynat. m ≤ n → m < n ∨ m = n.
 105 #m #n * -m -n
 106 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 107   /3 width=1 by or_introl, ylt_inj/
 108 | * /2 width=1 by or_introl, ylt_Y/
 109 ]
 110 qed-.
 111
 112 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 113 #x #y #z * -y -z
 114 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 115   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 116 | #y * //
 117 ]
 118 qed-.
 119
 120 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 121 #x #y #z * -y -z
 122 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 123   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 124 | #y #H elim (yle_inv_inj2 … H) -H //
 125 ]
 126 qed-.
 127
 128 (* Main properties **********************************************************)
 129
 130 theorem ylt_trans: Transitive … ylt.
 131 #x #y * -x -y
 132 [ #x #y #Hxy * //
 133   #z #H lapply (ylt_inv_inj … H) -H
 134   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 135 | #x #z #H elim (ylt_yle_false … H) //
 136 ]
 137 qed-.