matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  30                        ∃∃m. m < n & x = yinj m.
  31 #x #y * -x -y
  32 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  33   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  34 | #x #n #Hy destruct
  35 ]
  36 qed-.
  37
  38 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  39                     ∃∃m. m < n & x = yinj m.
  40 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  41
  42 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  43 #m #n #H elim (ylt_inv_inj2 … H) -H
  44 #x #Hx #H destruct //
  45 qed-.
  46
  47 fact ylt_inv_Y2_aux: ∀x,y. x < y → y = ∞ → ∃m. x = yinj m.
  48 #x #y * -x -y /2 width=2 by ex_intro/
  49 qed-.
  50
  51 lemma ylt_inv_Y2: ∀x. x < ∞ → ∃m. x = yinj m.
  52 /2 width=3 by ylt_inv_Y2_aux/ qed-.
  53
  54 lemma ylt_inv_O1: ∀n. 0 < n → ⫯⫰n = n.
  55 * // #n #H lapply (ylt_inv_inj … H) -H normalize
  56 /3 width=1 by S_pred, eq_f/
  57 qed-.
  58
  59 (* Inversion lemmas on successor ********************************************)
  60
  61 fact ylt_inv_succ1_aux: ∀x,y. x < y → ∀m. x = ⫯m → m < ⫰y ∧ y = ⫯⫰y.
  62 #x #y * -x -y
  63 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  64   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  65   #m #Hnm #H destruct /3 width=1 by ylt_inj, conj/
  66 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  67   #m #H #_ destruct /2 width=1 by ylt_Y, conj/
  68 ]
  69 qed-.
  70
  71 lemma ylt_inv_succ1: ∀m,y. ⫯m < y → m < ⫰y ∧ y = ⫯⫰y.
  72 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  73
  74 lemma ylt_inv_succ: ∀m,n. ⫯m < ⫯n → m < n.
  75 #m #n #H elim (ylt_inv_succ1 … H) -H //
  76 qed-.
  77
  78 (* Forward lemmas on successor **********************************************)
  79
  80 fact ylt_fwd_succ2_aux: ∀x,y. x < y → ∀n. y = ⫯n → x ≤ n.
  81 #x #y * -x -y
  82 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  83   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  84 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  85 ]
  86 qed-.
  87
  88 lemma ylt_fwd_succ2: ∀m,n. m < ⫯n → m ≤ n.
  89 /2 width=3 by ylt_fwd_succ2_aux/ qed-.
  90
  91 (* inversion and forward lemmas on yle **************************************)
  92
  93 lemma lt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
  94 #m #n * -m -n /3 width=1 by yle_pred_sn, yle_inj, yle_Y/
  95 qed-.
  96
  97 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
  98 #m #n * -m -n
  99 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
 100   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
 101 | #m #H lapply (yle_inv_Y1 … H) -H
 102   #H destruct
 103 ]
 104 qed-.
 105
 106 (* Properties on successor **************************************************)
 107
 108 lemma ylt_O_succ: ∀n. 0 < ⫯n.
 109 * /2 width=1 by ylt_inj/
 110 qed.
 111
 112 (* Properties on yle ********************************************************)
 113
 114 lemma yle_to_ylt_or_eq: ∀m:ynat. ∀n:ynat. m ≤ n → m < n ∨ m = n.
 115 #m #n * -m -n
 116 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 117   /3 width=1 by or_introl, ylt_inj/
 118 | * /2 width=1 by or_introl, ylt_Y/
 119 ]
 120 qed-.
 121
 122 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 123 #x #y #z * -y -z
 124 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 125   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 126 | #y * //
 127 ]
 128 qed-.
 129
 130 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 131 #x #y #z * -y -z
 132 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 133   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 134 | #y #H elim (yle_inv_inj2 … H) -H //
 135 ]
 136 qed-.
 137
 138 (* Main properties **********************************************************)
 139
 140 theorem ylt_trans: Transitive … ylt.
 141 #x #y * -x -y
 142 [ #x #y #Hxy * //
 143   #z #H lapply (ylt_inv_inj … H) -H
 144   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 145 | #x #z #H elim (ylt_yle_false … H) //
 146 ]
 147 qed-.