matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic forward lemmas *****************************************************)
  28
  29 lemma ylt_fwd_gen: ∀x,y. x < y → ∃m. x = yinj m.
  30 #x #y * -x -y /2 width=2 by ex_intro/
  31 qed-.
  32
  33 lemma ylt_fwd_le_succ: ∀x,y. x < y → ⫯x ≤ y.
  34 #x #y * -x -y /2 width=1 by yle_inj/
  35 qed-.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  40                        ∃∃m. m < n & x = yinj m.
  41 #x #y * -x -y
  42 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  43   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  44 | #x #n #Hy destruct
  45 ]
  46 qed-.
  47
  48 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  49                     ∃∃m. m < n & x = yinj m.
  50 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  51
  52 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  53 #m #n #H elim (ylt_inv_inj2 … H) -H
  54 #x #Hx #H destruct //
  55 qed-.
  56
  57 lemma ylt_inv_Y1: ∀n. ∞ < n → ⊥.
  58 #n #H elim (ylt_fwd_gen … H) -H
  59 #y #H destruct
  60 qed-.
  61
  62 lemma ylt_inv_O1: ∀n. 0 < n → ⫯⫰n = n.
  63 * // #n #H lapply (ylt_inv_inj … H) -H normalize
  64 /3 width=1 by S_pred, eq_f/
  65 qed-.
  66
  67 (* Inversion lemmas on successor ********************************************)
  68
  69 fact ylt_inv_succ1_aux: ∀x,y. x < y → ∀m. x = ⫯m → m < ⫰y ∧ ⫯⫰y = y.
  70 #x #y * -x -y
  71 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  72   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  73   #m #Hnm #H destruct /3 width=1 by ylt_inj, conj/
  74 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  75   #m #H #_ destruct /2 width=1 by ylt_Y, conj/
  76 ]
  77 qed-.
  78
  79 lemma ylt_inv_succ1: ∀m,y. ⫯m < y → m < ⫰y ∧ ⫯⫰y = y.
  80 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  81
  82 lemma ylt_inv_succ: ∀m,n. ⫯m < ⫯n → m < n.
  83 #m #n #H elim (ylt_inv_succ1 … H) -H //
  84 qed-.
  85
  86 (* Forward lemmas on successor **********************************************)
  87
  88 fact ylt_fwd_succ2_aux: ∀x,y. x < y → ∀n. y = ⫯n → x ≤ n.
  89 #x #y * -x -y
  90 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  91   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  92 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  93 ]
  94 qed-.
  95
  96 lemma ylt_fwd_succ2: ∀m,n. m < ⫯n → m ≤ n.
  97 /2 width=3 by ylt_fwd_succ2_aux/ qed-.
  98
  99 (* inversion and forward lemmas on yle **************************************)
 100
 101 lemma ylt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
 102 #m #n * -m -n /3 width=1 by yle_pred_sn, yle_inj, yle_Y/
 103 qed-.
 104
 105 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
 106 #m #n * -m -n
 107 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
 108   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
 109 | #m #H lapply (yle_inv_Y1 … H) -H
 110   #H destruct
 111 ]
 112 qed-.
 113
 114 (* Basic properties *********************************************************)
 115
 116 lemma ylt_O: ∀x. ⫯⫰(yinj x) = yinj x → 0 < x.
 117 * /2 width=1 by/ normalize
 118 #H destruct
 119 qed.
 120
 121 (* Properties on successor **************************************************)
 122
 123 lemma ylt_O_succ: ∀n. 0 < ⫯n.
 124 * /2 width=1 by ylt_inj/
 125 qed.
 126
 127 lemma ylt_succ: ∀m,n. m < n → ⫯m < ⫯n.
 128 #m #n #H elim H -m -n /3 width=1 by ylt_inj, le_S_S/
 129 qed.
 130
 131 (* Properties on order ******************************************************)
 132
 133 lemma yle_split_eq: ∀m:ynat. ∀n:ynat. m ≤ n → m < n ∨ m = n.
 134 #m #n * -m -n
 135 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 136   /3 width=1 by or_introl, ylt_inj/
 137 | * /2 width=1 by or_introl, ylt_Y/
 138 ]
 139 qed-.
 140
 141 lemma ylt_split: ∀m,n:ynat. m < n ∨ n ≤ m..
 142 #m #n elim (yle_split m n) /2 width=1 by or_intror/
 143 #H elim (yle_split_eq … H) -H /2 width=1 by or_introl, or_intror/
 144 qed-.
 145
 146 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 147 #x #y #z * -y -z
 148 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 149   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 150 | #y * //
 151 ]
 152 qed-.
 153
 154 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 155 #x #y #z * -y -z
 156 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 157   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 158 | #y #H elim (yle_inv_inj2 … H) -H //
 159 ]
 160 qed-.
 161
 162 (* Main properties **********************************************************)
 163
 164 theorem ylt_trans: Transitive … ylt.
 165 #x #y * -x -y
 166 [ #x #y #Hxy * //
 167   #z #H lapply (ylt_inv_inj … H) -H
 168   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 169 | #x #z #H elim (ylt_yle_false … H) //
 170 ]
 171 qed-.