matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic forward lemmas *****************************************************)
  28
  29 lemma ylt_fwd_gen: ∀x,y. x < y → ∃m. x = yinj m.
  30 #x #y * -x -y /2 width=2 by ex_intro/
  31 qed-.
  32
  33 lemma ylt_fwd_lt_O1: ∀x,y:ynat. x < y → 0 < y.
  34 #x #y #H elim H -x -y /3 width=2 by ylt_inj, ltn_to_ltO/
  35 qed-.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  40                        ∃∃m. m < n & x = yinj m.
  41 #x #y * -x -y
  42 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  43   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  44 | #x #n #Hy destruct
  45 ]
  46 qed-.
  47
  48 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  49                     ∃∃m. m < n & x = yinj m.
  50 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  51
  52 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  53 #m #n #H elim (ylt_inv_inj2 … H) -H
  54 #x #Hx #H destruct //
  55 qed-.
  56
  57 lemma ylt_inv_Y1: ∀n. ∞ < n → ⊥.
  58 #n #H elim (ylt_fwd_gen … H) -H
  59 #y #H destruct
  60 qed-.
  61
  62 lemma ylt_inv_O1: ∀n. 0 < n → ⫯⫰n = n.
  63 * // #n #H lapply (ylt_inv_inj … H) -H normalize
  64 /3 width=1 by S_pred, eq_f/
  65 qed-.
  66
  67 (* Inversion lemmas on successor ********************************************)
  68
  69 fact ylt_inv_succ1_aux: ∀x,y. x < y → ∀m. x = ⫯m → m < ⫰y ∧ ⫯⫰y = y.
  70 #x #y * -x -y
  71 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  72   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  73   #m #Hnm #H destruct /3 width=1 by ylt_inj, conj/
  74 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  75   #m #H #_ destruct /2 width=1 by ylt_Y, conj/
  76 ]
  77 qed-.
  78
  79 lemma ylt_inv_succ1: ∀m,y. ⫯m < y → m < ⫰y ∧ ⫯⫰y = y.
  80 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  81
  82 lemma ylt_inv_succ: ∀m,n. ⫯m < ⫯n → m < n.
  83 #m #n #H elim (ylt_inv_succ1 … H) -H //
  84 qed-.
  85
  86 (* Forward lemmas on successor **********************************************)
  87
  88 fact ylt_fwd_succ2_aux: ∀x,y. x < y → ∀n. y = ⫯n → x ≤ n.
  89 #x #y * -x -y
  90 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  91   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  92 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  93 ]
  94 qed-.
  95
  96 lemma ylt_fwd_succ2: ∀m,n. m < ⫯n → m ≤ n.
  97 /2 width=3 by ylt_fwd_succ2_aux/ qed-.
  98
  99 (* inversion and forward lemmas on yle **************************************)
 100
 101 lemma ylt_fwd_le_succ1: ∀m,n. m < n → ⫯m ≤ n.
 102 #m #n * -m -n /2 width=1 by yle_inj/
 103 qed-.
 104
 105 lemma ylt_fwd_le_pred2: ∀x,y:ynat. x < y → x ≤ ⫰y.
 106 #x #y #H elim H -x -y /3 width=1 by yle_inj, monotonic_pred/
 107 qed-.
 108
 109 lemma ylt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
 110 #m #n * -m -n /3 width=1 by lt_to_le, yle_inj/
 111 qed-.
 112
 113 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
 114 #m #n * -m -n
 115 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
 116   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
 117 | #m #H lapply (yle_inv_Y1 … H) -H
 118   #H destruct
 119 ]
 120 qed-.
 121
 122 (* Basic properties *********************************************************)
 123
 124 lemma ylt_O: ∀x. ⫯⫰(yinj x) = yinj x → 0 < x.
 125 * /2 width=1 by/ normalize
 126 #H destruct
 127 qed.
 128
 129 (* Properties on predecessor ************************************************)
 130
 131 lemma ylt_pred: ∀m,n. m < n → 0 < m → ⫰m < ⫰n.
 132 #m #n * -m -n
 133 /4 width=1 by ylt_inv_inj, ylt_inj, monotonic_lt_pred/
 134 qed.
 135
 136 (* Properties on successor **************************************************)
 137
 138 lemma ylt_O_succ: ∀n. 0 < ⫯n.
 139 * /2 width=1 by ylt_inj/
 140 qed.
 141
 142 lemma ylt_succ: ∀m,n. m < n → ⫯m < ⫯n.
 143 #m #n #H elim H -m -n /3 width=1 by ylt_inj, le_S_S/
 144 qed.
 145
 146 lemma yle_succ1_inj: ∀x,y. ⫯yinj x ≤ y → x < y.
 147 #x * /3 width=1 by yle_inv_inj, ylt_inj/
 148 qed.
 149
 150 (* Properties on order ******************************************************)
 151
 152 lemma yle_split_eq: ∀m,n:ynat. m ≤ n → m < n ∨ m = n.
 153 #m #n * -m -n
 154 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 155   /3 width=1 by or_introl, ylt_inj/
 156 | * /2 width=1 by or_introl, ylt_Y/
 157 ]
 158 qed-.
 159
 160 lemma ylt_split: ∀m,n:ynat. m < n ∨ n ≤ m.
 161 #m #n elim (yle_split m n) /2 width=1 by or_intror/
 162 #H elim (yle_split_eq … H) -H /2 width=1 by or_introl, or_intror/
 163 qed-.
 164
 165 lemma ylt_split_eq: ∀m,n:ynat. ∨∨ m < n | n = m | n < m.
 166 #m #n elim (ylt_split m n) /2 width=1 by or3_intro0/
 167 #H elim (yle_split_eq … H) -H /2 width=1 by or3_intro1, or3_intro2/
 168 qed-.
 169
 170 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 171 #x #y #z * -y -z
 172 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 173   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 174 | #y * //
 175 ]
 176 qed-.
 177
 178 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 179 #x #y #z * -y -z
 180 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 181   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 182 | #y #H elim (yle_inv_inj2 … H) -H //
 183 ]
 184 qed-.
 185
 186 (* Main properties **********************************************************)
 187
 188 theorem ylt_trans: Transitive … ylt.
 189 #x #y * -x -y
 190 [ #x #y #Hxy * //
 191   #z #H lapply (ylt_inv_inj … H) -H
 192   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 193 | #x #z #H elim (ylt_yle_false … H) //
 194 ]
 195 qed-.