matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic forward lemmas *****************************************************)
  28
  29 lemma ylt_inv_gen: ∀x,y. x < y → ∃m. x = yinj m.
  30 #x #y * -x -y /2 width=2 by ex_intro/
  31 qed-.
  32
  33 (* Basic inversion lemmas ***************************************************)
  34
  35 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  36                        ∃∃m. m < n & x = yinj m.
  37 #x #y * -x -y
  38 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  39   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  40 | #x #n #Hy destruct
  41 ]
  42 qed-.
  43
  44 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  45                     ∃∃m. m < n & x = yinj m.
  46 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  47
  48 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  49 #m #n #H elim (ylt_inv_inj2 … H) -H
  50 #x #Hx #H destruct //
  51 qed-.
  52
  53 lemma ylt_inv_Y1: ∀n. ∞ < n → ⊥.
  54 #n #H elim (ylt_inv_gen … H) -H
  55 #y #H destruct
  56 qed-.
  57
  58 lemma ylt_inv_O1: ∀n. 0 < n → ⫯⫰n = n.
  59 * // #n #H lapply (ylt_inv_inj … H) -H normalize
  60 /3 width=1 by S_pred, eq_f/
  61 qed-.
  62
  63 (* Inversion lemmas on successor ********************************************)
  64
  65 fact ylt_inv_succ1_aux: ∀x,y. x < y → ∀m. x = ⫯m → m < ⫰y ∧ ⫯⫰y = y.
  66 #x #y * -x -y
  67 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  68   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  69   #m #Hnm #H destruct /3 width=1 by ylt_inj, conj/
  70 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  71   #m #H #_ destruct /2 width=1 by ylt_Y, conj/
  72 ]
  73 qed-.
  74
  75 lemma ylt_inv_succ1: ∀m,y. ⫯m < y → m < ⫰y ∧ ⫯⫰y = y.
  76 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  77
  78 lemma ylt_inv_succ: ∀m,n. ⫯m < ⫯n → m < n.
  79 #m #n #H elim (ylt_inv_succ1 … H) -H //
  80 qed-.
  81
  82 (* Forward lemmas on successor **********************************************)
  83
  84 fact ylt_fwd_succ2_aux: ∀x,y. x < y → ∀n. y = ⫯n → x ≤ n.
  85 #x #y * -x -y
  86 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  87   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  88 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  89 ]
  90 qed-.
  91
  92 lemma ylt_fwd_succ2: ∀m,n. m < ⫯n → m ≤ n.
  93 /2 width=3 by ylt_fwd_succ2_aux/ qed-.
  94
  95 (* inversion and forward lemmas on yle **************************************)
  96
  97 lemma lt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
  98 #m #n * -m -n /3 width=1 by yle_pred_sn, yle_inj, yle_Y/
  99 qed-.
 100
 101 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
 102 #m #n * -m -n
 103 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
 104   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
 105 | #m #H lapply (yle_inv_Y1 … H) -H
 106   #H destruct
 107 ]
 108 qed-.
 109
 110 (* Basic properties *********************************************************)
 111
 112 lemma ylt_O: ∀x. ⫯⫰(yinj x) = yinj x → 0 < x.
 113 * /2 width=1 by/ normalize
 114 #H destruct
 115 qed.
 116
 117 (* Properties on successor **************************************************)
 118
 119 lemma ylt_O_succ: ∀n. 0 < ⫯n.
 120 * /2 width=1 by ylt_inj/
 121 qed.
 122
 123 lemma ylt_succ: ∀m,n. m < n → ⫯m < ⫯n.
 124 #m #n #H elim H -m -n /3 width=1 by ylt_inj, le_S_S/
 125 qed.
 126
 127 (* Properties on order ******************************************************)
 128
 129 lemma yle_split_eq: ∀m:ynat. ∀n:ynat. m ≤ n → m < n ∨ m = n.
 130 #m #n * -m -n
 131 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 132   /3 width=1 by or_introl, ylt_inj/
 133 | * /2 width=1 by or_introl, ylt_Y/
 134 ]
 135 qed-.
 136
 137 lemma ylt_split: ∀m,n:ynat. m < n ∨ n ≤ m..
 138 #m #n elim (yle_split m n) /2 width=1 by or_intror/
 139 #H elim (yle_split_eq … H) -H /2 width=1 by or_introl, or_intror/
 140 qed-.
 141
 142 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 143 #x #y #z * -y -z
 144 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 145   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 146 | #y * //
 147 ]
 148 qed-.
 149
 150 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 151 #x #y #z * -y -z
 152 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 153   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 154 | #y #H elim (yle_inv_inj2 … H) -H //
 155 ]
 156 qed-.
 157
 158 (* Main properties **********************************************************)
 159
 160 theorem ylt_trans: Transitive … ylt.
 161 #x #y * -x -y
 162 [ #x #y #Hxy * //
 163   #z #H lapply (ylt_inv_inj … H) -H
 164   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 165 | #x #z #H elim (ylt_yle_false … H) //
 166 ]
 167 qed-.