matita/matita/contribs/lambdadelta/ground_2/ynat/ynat_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/ynat/ynat_lt.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* addition *)
  20 definition yplus: ynat → ynat → ynat ≝ λx,y. match y with
  21 [ yinj n ⇒ ysucc^n x
  22 | Y      ⇒ Y
  23 ].
  24
  25 interpretation "ynat plus" 'plus x y = (yplus x y).
  26
  27 lemma yplus_O2: ∀m:ynat. m + 0 = m.
  28 // qed.
  29
  30 lemma yplus_S2: ∀m:ynat. ∀n. m + S n = ↑(m + n).
  31 // qed.
  32
  33 lemma yplus_Y2: ∀m:ynat. m + (∞) = ∞.
  34 // qed.
  35
  36 (* Properties on successor **************************************************)
  37
  38 lemma yplus_succ2: ∀m,n. m + ↑n = ↑(m + n).
  39 #m * //
  40 qed.
  41
  42 lemma yplus_succ1: ∀m,n. ↑m + n = ↑(m + n).
  43 #m * // #n elim n -n //
  44 qed.
  45
  46 lemma yplus_succ_swap: ∀m,n. m + ↑n = ↑m + n.
  47 // qed.
  48
  49 lemma yplus_SO2: ∀m. m + 1 = ↑m.
  50 * //
  51 qed.
  52
  53 (* Basic properties *********************************************************)
  54
  55 lemma yplus_inj: ∀n,m. yinj m + yinj n = yinj (m + n).
  56 #n elim n -n //
  57 #n #IHn #m >(yplus_succ2 ? n) >IHn -IHn
  58 <plus_n_Sm //
  59 qed.
  60
  61 lemma yplus_Y1: ∀m. ∞ + m = ∞.
  62 * // #m elim m -m //
  63 qed.
  64
  65 lemma yplus_comm: commutative … yplus.
  66 * [ #m ] * [1,3: #n ] //
  67 qed.
  68
  69 lemma yplus_assoc: associative … yplus.
  70 #x #y * // #z cases y -y
  71 [ #y >yplus_inj whd in ⊢ (??%%); <iter_plus //
  72 | >yplus_Y1 //
  73 ]
  74 qed.
  75
  76 lemma yplus_O1: ∀n:ynat. 0 + n = n.
  77 #n >yplus_comm // qed.
  78
  79 lemma yplus_comm_23: ∀x,y,z. x + z + y = x + y + z.
  80 #x #y #z >yplus_assoc //
  81 qed.
  82
  83 lemma yplus_comm_24: ∀x1,x2,x3,x4. x1 + x4 + x3 + x2 = x1 + x2 + x3 + x4.
  84 #x1 #x2 #x3 #x4
  85 >yplus_assoc >yplus_assoc >yplus_assoc >yplus_assoc
  86 /2 width=1 by eq_f2/
  87 qed.
  88
  89 lemma yplus_assoc_23: ∀x1,x2,x3,x4. x1 + x2 + (x3 + x4) = x1 + (x2 + x3) + x4.
  90 #x1 #x2 #x3 #x4 >yplus_assoc >yplus_assoc
  91 /2 width=1 by eq_f2/
  92 qed.
  93
  94 (* Inversion lemmas on successor *********************************************)
  95
  96 lemma yplus_inv_succ_lt_dx: ∀x,y,z:ynat. 0 < y → x + y = ↑z → x + ↓y = z.
  97 #x #y #z #H <(ylt_inv_O1 y) // >yplus_succ2
  98 /2 width=1 by ysucc_inv_inj/
  99 qed-.
 100
 101 lemma yplus_inv_succ_lt_sn: ∀x,y,z:ynat. 0 < x → x + y = ↑z → ↓x + y = z.
 102 #x #y #z #H <(ylt_inv_O1 x) // >yplus_succ1
 103 /2 width=1 by ysucc_inv_inj/
 104
 105 qed-.
 106
 107 (* Inversion lemmas on order ************************************************)
 108
 109 lemma yle_inv_plus_dx: ∀x,y. x ≤ y → ∃z. x + z = y.
 110 #x #y #H elim H -x -y /2 width=2 by ex_intro/
 111 #m #n #H @(ex_intro … (yinj (n-m))) (**) (* explicit constructor *)
 112 /3 width=1 by plus_minus, eq_f/
 113 qed-.
 114
 115 lemma yle_inv_plus_sn: ∀x,y. x ≤ y → ∃z. z + x = y.
 116 #x #y #H elim (yle_inv_plus_dx … H) -H
 117 /2 width=2 by ex_intro/
 118 qed-.
 119
 120 (* Basic inversion lemmas ***************************************************)
 121
 122 lemma yplus_inv_inj: ∀z,y,x. x + y = yinj z →
 123                      ∃∃m,n. m + n = z & x = yinj m & y = yinj n.
 124 #z * [2: normalize #x #H destruct ]
 125 #y * [2: >yplus_Y1 #H destruct ]
 126 /3 width=5 by yinj_inj, ex3_2_intro/
 127 qed-.
 128
 129 lemma yplus_inv_O: ∀x,y:ynat. x + y = 0 → x = 0 ∧ y = 0.
 130 #x #y #H elim (yplus_inv_inj … H) -H
 131 #m * /2 width=1 by conj/ #n <plus_n_Sm #H destruct
 132 qed-.
 133
 134 lemma discr_yplus_xy_x: ∀x,y. x + y = x → x = ∞ ∨ y = 0.
 135 * /2 width=1 by or_introl/
 136 #x elim x -x /2 width=1 by or_intror/
 137 #x #IHx * [2: >yplus_Y2 #H destruct ]
 138 #y <ysucc_inj >yplus_succ1 #H
 139 lapply (ysucc_inv_inj … H) -H #H
 140 elim (IHx … H) -IHx -H /2 width=1 by or_introl, or_intror/
 141 qed-.
 142
 143 lemma discr_yplus_x_xy: ∀x,y. x = x + y → x = ∞ ∨ y = 0.
 144 /2 width=1 by discr_yplus_xy_x/ qed-.
 145
 146 lemma yplus_inv_monotonic_dx_inj: ∀z,x,y. x + yinj z = y + yinj z → x = y.
 147 #z @(nat_ind_plus … z) -z /3 width=2 by ysucc_inv_inj/
 148 qed-.
 149
 150 lemma yplus_inv_monotonic_dx: ∀z,x,y. z < ∞ → x + z = y + z → x = y.
 151 #z #x #y #H elim (ylt_inv_Y2 … H) -H /2 width=2 by yplus_inv_monotonic_dx_inj/
 152 qed-.
 153
 154 lemma yplus_inv_Y2: ∀x,y. x + y = ∞ → x = ∞ ∨ y = ∞.
 155 * /2 width=1 by or_introl/ #x * // #y >yplus_inj #H destruct
 156 qed-.
 157
 158 lemma yplus_inv_monotonic_23: ∀z,x1,x2,y1,y2. z < ∞ →
 159                               x1 + z + y1 = x2 + z + y2 → x1 + y1 = x2 + y2.
 160 #z #x1 #x2 #y1 #y2 #Hz #H @(yplus_inv_monotonic_dx z) //
 161 >yplus_comm_23 >H -H //
 162 qed-.
 163
 164 (* Inversion lemmas on strict_order *****************************************)
 165
 166 lemma ylt_inv_plus_Y: ∀x,y. x + y < ∞ → x < ∞ ∧ y < ∞.
 167 #x #y #H elim (ylt_inv_Y2 … H) -H
 168 #z #H elim (yplus_inv_inj … H) -H /2 width=1 by conj/
 169 qed-.
 170
 171 lemma ylt_inv_plus_sn: ∀x,y. x < y → ∃∃z. ↑z + x = y & x < ∞.
 172 #x #y #H elim (ylt_inv_le … H) -H
 173 #Hx #H elim (yle_inv_plus_sn … H) -H
 174 /2 width=2 by ex2_intro/
 175 qed-.
 176
 177 lemma ylt_inv_plus_dx: ∀x,y. x < y → ∃∃z. x + ↑z = y & x < ∞.
 178 #x #y #H elim (ylt_inv_plus_sn … H) -H
 179 #z >yplus_comm /2 width=2 by ex2_intro/
 180 qed-.
 181
 182 (* Properties on order ******************************************************)
 183
 184 lemma yle_plus_dx2: ∀n,m. n ≤ m + n.
 185 * //
 186 #n elim n -n //
 187 #n #IHn #m >(yplus_succ2 ? n) @(yle_succ n) // (**) (* full auto fails *)
 188 qed.
 189
 190 lemma yle_plus_dx1: ∀n,m. m ≤ m + n.
 191 // qed.
 192
 193 lemma yle_plus_dx1_trans: ∀x,z. z ≤ x → ∀y. z ≤ x + y.
 194 /2 width=3 by yle_trans/ qed.
 195
 196 lemma yle_plus_dx2_trans: ∀y,z. z ≤ y → ∀x. z ≤ x + y.
 197 /2 width=3 by yle_trans/ qed.
 198
 199 lemma monotonic_yle_plus_dx: ∀x,y. x ≤ y → ∀z. x + z ≤ y + z.
 200 #x #y #Hxy * //
 201 #z elim z -z /3 width=1 by yle_succ/
 202 qed.
 203
 204 lemma monotonic_yle_plus_sn: ∀x,y. x ≤ y → ∀z. z + x ≤ z + y.
 205 /2 width=1 by monotonic_yle_plus_dx/ qed.
 206
 207 lemma monotonic_yle_plus: ∀x1,y1. x1 ≤ y1 → ∀x2,y2. x2 ≤ y2 →
 208                           x1 + x2 ≤ y1 + y2.
 209 /3 width=3 by monotonic_yle_plus_dx, monotonic_yle_plus_sn, yle_trans/ qed.
 210
 211 lemma ylt_plus_Y: ∀x,y. x < ∞ → y < ∞ → x + y < ∞.
 212 #x #y #Hx elim (ylt_inv_Y2 … Hx) -Hx
 213 #m #Hm #Hy elim (ylt_inv_Y2 … Hy) -Hy //
 214 qed.
 215
 216 (* Forward lemmas on order **************************************************)
 217
 218 lemma yle_fwd_plus_sn2: ∀x,y,z. x + y ≤ z → y ≤ z.
 219 /2 width=3 by yle_trans/ qed-.
 220
 221 lemma yle_fwd_plus_sn1: ∀x,y,z. x + y ≤ z → x ≤ z.
 222 /2 width=3 by yle_trans/ qed-.
 223
 224 lemma yle_inv_monotonic_plus_dx_inj: ∀x,y:ynat.∀z:nat. x + z ≤ y + z → x ≤ y.
 225 #x #y #z elim z -z /3 width=1 by yle_inv_succ/
 226 qed-.
 227
 228 lemma yle_inv_monotonic_plus_sn_inj: ∀x,y:ynat.∀z:nat. z + x ≤ z + y → x ≤ y.
 229 /2 width=2 by yle_inv_monotonic_plus_dx_inj/ qed-.
 230
 231 lemma yle_inv_monotonic_plus_dx: ∀x,y,z. z < ∞ → x + z ≤ y + z → x ≤ y.
 232 #x #y #z #Hz elim (ylt_inv_Y2 … Hz) -Hz #m #H destruct
 233 /2 width=2 by yle_inv_monotonic_plus_sn_inj/
 234 qed-.
 235
 236 lemma yle_inv_monotonic_plus_sn: ∀x,y,z. z < ∞ → z + x ≤ z + y → x ≤ y.
 237 /2 width=3 by yle_inv_monotonic_plus_dx/ qed-.
 238
 239 lemma yle_fwd_plus_ge: ∀m1,m2:nat. m2 ≤ m1 → ∀n1,n2:ynat. m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 240 #m1 #m2 #Hm12 #n1 #n2 #H
 241 lapply (monotonic_yle_plus … Hm12 … H) -Hm12 -H
 242 /2 width=2 by yle_inv_monotonic_plus_sn_inj/
 243 qed-.
 244
 245 lemma yle_fwd_plus_ge_inj: ∀m1:nat. ∀m2,n1,n2:ynat. m2 ≤ m1 → m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 246 #m2 #m1 #n1 #n2 #H elim (yle_inv_inj2 … H) -H
 247 #x #H0 #H destruct /3 width=4 by yle_fwd_plus_ge, yle_inj/
 248 qed-.
 249
 250 lemma yle_fwd_plus_yge: ∀n2,m1:ynat. ∀n1,m2:nat. m2 ≤ m1 → m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 251 * // #n2 * /2 width=4 by yle_fwd_plus_ge_inj/
 252 qed-.
 253
 254 (* Properties on strict order ***********************************************)
 255
 256 lemma ylt_plus_dx1_trans: ∀x,z. z < x → ∀y. z < x + y.
 257 /2 width=3 by ylt_yle_trans/ qed.
 258
 259 lemma ylt_plus_dx2_trans: ∀y,z. z < y → ∀x. z < x + y.
 260 /2 width=3 by ylt_yle_trans/ qed.
 261
 262 lemma monotonic_ylt_plus_dx_inj: ∀x,y. x < y → ∀z:nat. x + yinj z < y + yinj z.
 263 #x #y #Hxy #z elim z -z /3 width=1 by ylt_succ/
 264 qed.
 265
 266 lemma monotonic_ylt_plus_sn_inj: ∀x,y. x < y → ∀z:nat. yinj z + x < yinj z + y.
 267 /2 width=1 by monotonic_ylt_plus_dx_inj/ qed.
 268
 269 lemma monotonic_ylt_plus_dx: ∀x,y. x < y → ∀z. z < ∞ → x + z < y + z.
 270 #x #y #Hxy #z #Hz elim (ylt_inv_Y2 … Hz) -Hz
 271 #m #H destruct /2 width=1 by monotonic_ylt_plus_dx_inj/
 272 qed.
 273
 274 lemma monotonic_ylt_plus_sn: ∀x,y. x < y → ∀z. z < ∞ → z + x < z + y.
 275 /2 width=1 by monotonic_ylt_plus_dx/ qed.
 276
 277 lemma monotonic_ylt_plus_inj: ∀m1,m2. m1 < m2 → ∀n1,n2. yinj n1 ≤ n2 → m1 + n1 < m2 + n2.
 278 /3 width=3 by monotonic_ylt_plus_sn_inj, monotonic_yle_plus_sn, ylt_yle_trans/
 279 qed.
 280
 281 lemma monotonic_ylt_plus: ∀m1,m2. m1 < m2 → ∀n1. n1 < ∞ → ∀n2. n1 ≤ n2 → m1 + n1 < m2 + n2.
 282 #m1 #m2 #Hm12 #n1 #H elim (ylt_inv_Y2 … H) -H #m #H destruct /2 width=1 by monotonic_ylt_plus_inj/
 283 qed.
 284
 285 (* Forward lemmas on strict order *******************************************)
 286
 287 lemma ylt_inv_monotonic_plus_dx: ∀x,y,z. x + z < y + z → x < y.
 288 * [2: #y #z >yplus_comm #H elim (ylt_inv_Y1 … H) ]
 289 #x * // #y * [2: #H elim (ylt_inv_Y1 … H) ]
 290 /4 width=3 by ylt_inv_inj, ylt_inj, lt_plus_to_lt_l/
 291 qed-.
 292
 293 lemma ylt_fwd_plus_ge: ∀m1,m2. m2 ≤ m1 → ∀n1,n2. m1 + n1 < m2 + n2 → n1 < n2.
 294 #m1 #m2 #Hm12 #n1 #n2 #H elim (ylt_fwd_gen … H)
 295 #x #H0 elim (yplus_inv_inj … H0) -H0
 296 #y #z #_ #H2 #H3 destruct -x
 297 elim (yle_inv_inj2 … Hm12)
 298 #x #_ #H0 destruct
 299 lapply (monotonic_ylt_plus … H … Hm12) -H -Hm12
 300 /2 width=2 by ylt_inv_monotonic_plus_dx/
 301 qed-.
 302
 303 (* Properties on predeccessor ***********************************************)
 304
 305 lemma yplus_pred1: ∀x,y:ynat. 0 < x → ↓x + y = ↓(x+y).
 306 #x * // #y elim y -y // #y #IH #Hx
 307 >yplus_S2 >yplus_S2 >IH -IH // >ylt_inv_O1
 308 /2 width=1 by ylt_plus_dx1_trans/
 309 qed-.
 310
 311 lemma yplus_pred2: ∀x,y:ynat. 0 < y → x + ↓y = ↓(x+y).
 312 /2 width=1 by yplus_pred1/ qed-.