matita/matita/contribs/lambdadelta/ground_2A/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "arithmetics/nat.ma".
  16 include "ground_2A/lib/star.ma".
  17
  18 (* ARITHMETICAL PROPERTIES **************************************************)
  19
  20 (* Equations ****************************************************************)
  21
  22 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  23 // qed-.
  24
  25 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  26 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  27 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  28 qed-.
  29
  30 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  31 /2 width=1 by plus_minus_minus_be/ qed-.
  32
  33 lemma plus_n_2: ∀n. n + 2 = n + 1 + 1.
  34 // qed.
  35
  36 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  37 /2 by plus_minus/ qed.
  38
  39 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  40 /2 by plus_minus/ qed.
  41
  42 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  43 // qed.
  44
  45 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
  46 #a #b #c1 #H >minus_minus_comm >minus_le_minus_minus_comm //
  47 qed.
  48
  49 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
  50 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2 width=1 by arith_b1/
  51 qed.
  52
  53 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
  54 /3 by monotonic_le_minus_l, le_to_le_to_eq, le_n/ qed.
  55
  56 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
  57                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
  58 #a1 #a2 #b #c1 #H1 #H2 >plus_minus /2 width=1 by arith_b2/
  59 qed.
  60
  61 lemma arith_i: ∀x,y,z. y < x → x+z-y-1 = x-y-1+z.
  62 /2 width=1 by plus_minus/ qed-.
  63
  64 (* Properties ***************************************************************)
  65
  66 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
  67 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
  68 [1,4: @or_intror #H destruct
  69 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
  70 | /2 width=1 by or_introl/
  71 ]
  72 qed-.
  73
  74 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  75 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
  76 #H elim H -m /2 width=1 by or3_intro1/
  77 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
  78 qed-.
  79
  80 fact le_repl_sn_conf_aux: ∀x,y,z:nat. x ≤ z → x = y → y ≤ z.
  81 // qed-.
  82
  83 fact le_repl_sn_trans_aux: ∀x,y,z:nat. x ≤ z → y = x → y ≤ z.
  84 // qed-.
  85
  86 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
  87 /3 width=1 by monotonic_le_minus_l/ qed.
  88
  89 (* Note: this might interfere with nat.ma *)
  90 lemma monotonic_lt_pred: ∀m,n. m < n → O < m → pred m < pred n.
  91 #m #n #Hmn #Hm whd >(S_pred … Hm)
  92 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
  93 qed.
  94
  95 lemma arith_j: ∀x,y,z. x-y-1 ≤ x-(y-z)-1.
  96 /3 width=1 by monotonic_le_minus_l, monotonic_le_minus_r/ qed.
  97
  98 lemma arith_k_sn: ∀z,x,y,n. z < x → x+n ≤ y → x-z-1+n ≤ y-z-1.
  99 #z #x #y #n #Hzx #Hxny
 100 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 101 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 102 /2 width=1 by monotonic_le_minus_l2/
 103 qed.
 104
 105 lemma arith_k_dx: ∀z,x,y,n. z < x → y ≤ x+n → y-z-1 ≤ x-z-1+n.
 106 #z #x #y #n #Hzx #Hyxn
 107 >plus_minus [2: /2 width=1 by monotonic_le_minus_r/ ]
 108 >plus_minus [2: /2 width=1 by lt_to_le/ ]
 109 /2 width=1 by monotonic_le_minus_l2/
 110 qed.
 111
 112 (* Inversion & forward lemmas ***********************************************)
 113
 114 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 115 // qed-.
 116
 117 lemma lt_plus_SO_to_le: ∀x,y. x < y + 1 → x ≤ y.
 118 /2 width=1 by monotonic_pred/ qed-.
 119
 120 lemma lt_refl_false: ∀n. n < n → ⊥.
 121 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 122 qed-.
 123
 124 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 125 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 126 qed-.
 127
 128 lemma pred_inv_refl: ∀m. pred m = m → m = 0.
 129 * // normalize #m #H elim (lt_refl_false m) //
 130 qed-.
 131
 132 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 133 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 134 qed-.
 135
 136 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 137 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 138 #H elim (le_plus_xSy_O_false … H)
 139 qed-.
 140
 141 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 142 /2 width=4 by le_plus_xySz_x_false/ qed-.
 143
 144 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 145 /2 width=4 by plus_xySz_x_false/ qed-.
 146
 147 (* Note this should go in nat.ma *)
 148 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 149 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 150 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 151 #y #_ >minus_plus_plus_l
 152 #H lapply (discr_plus_xy_minus_xz … H) -H
 153 #H destruct
 154 qed-.
 155
 156 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 157 * /2 width=1 by conj/ #x #y normalize #H destruct
 158 qed-.
 159
 160 (* Iterators ****************************************************************)
 161
 162 (* Note: see also: lib/arithemetics/bigops.ma *)
 163 let rec iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 164   match n with
 165    [ O   ⇒ nil
 166    | S k ⇒ op (iter k B op nil)
 167    ].
 168
 169 interpretation "iterated function" 'exp op n = (iter n ? op).
 170
 171 lemma iter_SO: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^(l+1) b = f (f^l b).
 172 #B #f #b #l >commutative_plus //
 173 qed.
 174
 175 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 176 #B #f #b #l elim l -l normalize //
 177 qed.
 178
 179 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 180 #B #f #b #l1 elim l1 -l1 normalize //
 181 qed.
 182
 183 (* Trichotomy operator ******************************************************)
 184
 185 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 186 let rec tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 187   match n1 with
 188   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 189   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 190   ].
 191
 192 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 193 #A #a1 #a2 #a3 #n2 elim n2 -n2
 194 [ #n1 #H elim (lt_zero_false … H)
 195 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 196 ]
 197 qed.
 198
 199 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 200 #A #a1 #a2 #a3 #n elim n -n normalize //
 201 qed.
 202
 203 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 204 #A #a1 #a2 #a3 #n1 elim n1 -n1
 205 [ #n2 #H elim (lt_zero_false … H)
 206 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 207 ]
 208 qed.