matita/matita/contribs/lambdadelta/ground_2A/ynat/ynat_le.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/ynat/ynat_succ.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* order relation *)
  20 inductive yle: relation ynat ≝
  21 | yle_inj: ∀m,n. m ≤ n → yle m n
  22 | yle_Y  : ∀m. yle m (∞)
  23 .
  24
  25 interpretation "ynat 'less or equal to'" 'leq x y = (yle x y).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact yle_inv_inj2_aux: ∀x,y. x ≤ y → ∀n. y = yinj n →
  30                        ∃∃m. m ≤ n & x = yinj m.
  31 #x #y * -x -y
  32 [ #x #y #Hxy #n #Hy destruct /2 width=3 by ex2_intro/
  33 | #x #n #Hy destruct
  34 ]
  35 qed-.
  36
  37 lemma yle_inv_inj2: ∀x,n. x ≤ yinj n → ∃∃m. m ≤ n & x = yinj m.
  38 /2 width=3 by yle_inv_inj2_aux/ qed-.
  39
  40 lemma yle_inv_inj: ∀m,n. yinj m ≤ yinj n → m ≤ n.
  41 #m #n #H elim (yle_inv_inj2 … H) -H
  42 #x #Hxn #H destruct //
  43 qed-.
  44
  45 fact yle_inv_O2_aux: ∀m:ynat. ∀x:ynat. m ≤ x → x = 0 → m = 0.
  46 #m #x * -m -x
  47 [ #m #n #Hmn #H destruct /3 width=1 by le_n_O_to_eq, eq_f/
  48 | #m #H destruct
  49 ]
  50 qed-.
  51
  52 lemma yle_inv_O2: ∀m:ynat. m ≤ 0 → m = 0.
  53 /2 width =3 by yle_inv_O2_aux/ qed-.
  54
  55 fact yle_inv_Y1_aux: ∀x,n. x ≤ n → x = ∞ → n = ∞.
  56 #x #n * -x -n //
  57 #x #n #_ #H destruct
  58 qed-.
  59
  60 lemma yle_inv_Y1: ∀n. ∞ ≤ n → n = ∞.
  61 /2 width=3 by yle_inv_Y1_aux/ qed-.
  62
  63 (* Inversion lemmas on successor ********************************************)
  64
  65 fact yle_inv_succ1_aux: ∀x,y. x ≤ y → ∀m. x = ⫯m → m ≤ ⫰y ∧ ⫯⫰y = y.
  66 #x #y * -x -y
  67 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  68   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  69   #m #Hnm #H destruct /3 width=1 by yle_inj, conj/
  70 | #x #y #H destruct /2 width=1 by yle_Y, conj/
  71 ]
  72 qed-.
  73
  74 lemma yle_inv_succ1: ∀m,y. ⫯m ≤ y → m ≤ ⫰y ∧ ⫯⫰y = y.
  75 /2 width=3 by yle_inv_succ1_aux/ qed-.
  76
  77 lemma yle_inv_succ: ∀m,n. ⫯m ≤ ⫯n → m ≤ n.
  78 #m #n #H elim (yle_inv_succ1 … H) -H //
  79 qed-.
  80
  81 (* Basic properties *********************************************************)
  82
  83 lemma le_O1: ∀n:ynat. 0 ≤ n.
  84 * /2 width=1 by yle_inj/
  85 qed.
  86
  87 lemma yle_refl: reflexive … yle.
  88 * /2 width=1 by le_n, yle_inj/
  89 qed.
  90
  91 lemma yle_split: ∀x,y:ynat. x ≤ y ∨ y ≤ x.
  92 * /2 width=1 by or_intror/
  93 #x * /2 width=1 by or_introl/
  94 #y elim (le_or_ge x y) /3 width=1 by yle_inj, or_introl, or_intror/
  95 qed-.
  96
  97 (* Properties on predecessor ************************************************)
  98
  99 lemma yle_pred_sn: ∀m,n. m ≤ n → ⫰m ≤ n.
 100 #m #n * -m -n /3 width=3 by transitive_le, yle_inj/
 101 qed.
 102
 103 lemma yle_refl_pred_sn: ∀x. ⫰x ≤ x.
 104 /2 width=1 by yle_refl, yle_pred_sn/ qed.
 105
 106 lemma yle_pred: ∀m,n. m ≤ n → ⫰m ≤ ⫰n.
 107 #m #n * -m -n /3 width=1 by yle_inj, monotonic_pred/
 108 qed.
 109
 110 (* Properties on successor **************************************************)
 111
 112 lemma yle_succ: ∀m,n. m ≤ n → ⫯m ≤ ⫯n.
 113 #m #n * -m -n /3 width=1 by yle_inj, le_S_S/
 114 qed.
 115
 116 lemma yle_succ_dx: ∀m,n. m ≤ n → m ≤ ⫯n.
 117 #m #n * -m -n /3 width=1 by le_S, yle_inj/
 118 qed.
 119
 120 lemma yle_refl_S_dx: ∀x. x ≤ ⫯x.
 121 /2 width=1 by yle_succ_dx/ qed.
 122
 123 lemma yle_refl_SP_dx: ∀x. x ≤ ⫯⫰x.
 124 * // * //
 125 qed.
 126
 127 (* Main properties **********************************************************)
 128
 129 theorem yle_trans: Transitive … yle.
 130 #x #y * -x -y
 131 [ #x #y #Hxy * //
 132   #z #H lapply (yle_inv_inj … H) -H
 133   /3 width=3 by transitive_le, yle_inj/ (**) (* full auto too slow *)
 134 | #x #z #H lapply (yle_inv_Y1 … H) //
 135 ]
 136 qed-.