matita/matita/contribs/lambdadelta/ground_2A/ynat/ynat_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2A/ynat/ynat_minus.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* addition *)
  20 definition yplus: ynat → ynat → ynat ≝ λx,y. match y with
  21 [ yinj n ⇒ ysucc^n x
  22 | Y      ⇒ Y
  23 ].
  24
  25 interpretation "ynat plus" 'plus x y = (yplus x y).
  26
  27 (* Properties on successor **************************************************)
  28
  29 lemma yplus_succ2: ∀m,n. m + ⫯n = ⫯(m + n).
  30 #m * //
  31 qed.
  32
  33 lemma yplus_succ1: ∀m,n. ⫯m + n = ⫯(m + n).
  34 #m * normalize //
  35 qed.
  36
  37 lemma yplus_succ_swap: ∀m,n. m + ⫯n = ⫯m + n.
  38 // qed.
  39
  40 lemma yplus_SO2: ∀m. m + 1 = ⫯m.
  41 * //
  42 qed.
  43
  44 (* Basic properties *********************************************************)
  45
  46 lemma yplus_inj: ∀n,m. yinj m + yinj n = yinj (m + n).
  47 #n elim n -n [ normalize // ]
  48 #n #IHn #m >(yplus_succ2 ? n) >IHn -IHn
  49 <plus_n_Sm //
  50 qed.
  51
  52 lemma yplus_Y1: ∀m. ∞ + m = ∞.
  53 * normalize //
  54 qed.
  55
  56 lemma yplus_comm: commutative … yplus.
  57 * [ #m ] * [1,3: #n ] //
  58 normalize >ysucc_iter_Y //
  59 qed.
  60
  61 lemma yplus_assoc: associative … yplus.
  62 #x #y * // #z cases y -y
  63 [ #y >yplus_inj whd in ⊢ (??%%); <iter_plus //
  64 | >yplus_Y1 //
  65 ]
  66 qed.
  67
  68 lemma yplus_O1: ∀n:ynat. 0 + n = n.
  69 #n >yplus_comm // qed.
  70
  71 (* Basic inversion lemmas ***************************************************)
  72
  73 lemma yplus_inv_inj: ∀z,y,x. x + y = yinj z →
  74                      ∃∃m,n. m + n = z & x = yinj m & y = yinj n.
  75 #z * [2: normalize #x #H destruct ]
  76 #y * [2: >yplus_Y1 #H destruct ]
  77 /3 width=5 by yinj_inj, ex3_2_intro/
  78 qed-.
  79
  80 (* Properties on order ******************************************************)
  81
  82 lemma yle_plus_dx2: ∀n,m. n ≤ m + n.
  83 * //
  84 #n elim n -n //
  85 #n #IHn #m >(yplus_succ2 ? n) @(yle_succ n) // (**) (* full auto fails *)
  86 qed.
  87
  88 lemma yle_plus_dx1: ∀n,m. m ≤ m + n.
  89 // qed.
  90
  91 lemma yle_plus_dx1_trans: ∀x,z. z ≤ x → ∀y. z ≤ x + y.
  92 /2 width=3 by yle_trans/ qed.
  93
  94 lemma yle_plus_dx2_trans: ∀y,z. z ≤ y → ∀x. z ≤ x + y.
  95 /2 width=3 by yle_trans/ qed.
  96
  97 lemma monotonic_yle_plus_dx: ∀x,y. x ≤ y → ∀z. x + z ≤ y + z.
  98 #x #y #Hxy * //
  99 #z elim z -z /3 width=1 by yle_succ/
 100 qed.
 101
 102 lemma monotonic_yle_plus_sn: ∀x,y. x ≤ y → ∀z. z + x ≤ z + y.
 103 /2 width=1 by monotonic_yle_plus_dx/ qed.
 104
 105 lemma monotonic_yle_plus: ∀x1,y1. x1 ≤ y1 → ∀x2,y2. x2 ≤ y2 →
 106                           x1 + x2 ≤ y1 + y2.
 107 /3 width=3 by monotonic_yle_plus_dx, yle_trans/ qed.
 108
 109 (* Forward lemmas on order **************************************************)
 110
 111 lemma yle_fwd_plus_sn2: ∀x,y,z. x + y ≤ z → y ≤ z.
 112 /2 width=3 by yle_trans/ qed-.
 113
 114 lemma yle_fwd_plus_sn1: ∀x,y,z. x + y ≤ z → x ≤ z.
 115 /2 width=3 by yle_trans/ qed-.
 116
 117 lemma yle_inv_monotonic_plus_dx: ∀x,y:ynat.∀z:nat. x + z ≤ y + z → x ≤ y.
 118 #x #y #z elim z -z /3 width=1 by yle_inv_succ/
 119 qed-.
 120
 121 lemma yle_inv_monotonic_plus_sn: ∀x,y:ynat.∀z:nat. z + x ≤ z + y → x ≤ y.
 122 /2 width=2 by yle_inv_monotonic_plus_dx/ qed-.
 123
 124 lemma yle_fwd_plus_ge: ∀m1,m2:nat. m2 ≤ m1 → ∀n1,n2:ynat. m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 125 #m1 #m2 #Hm12 #n1 #n2 #H
 126 lapply (monotonic_yle_plus … Hm12 … H) -Hm12 -H
 127 /2 width=2 by yle_inv_monotonic_plus_sn/
 128 qed-.
 129
 130 lemma yle_fwd_plus_ge_inj: ∀m1:nat. ∀m2,n1,n2:ynat. m2 ≤ m1 → m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 131 #m2 #m1 #n1 #n2 #H elim (yle_inv_inj2 … H) -H
 132 #x #H0 #H destruct /3 width=4 by yle_fwd_plus_ge, yle_inj/
 133 qed-.
 134
 135 (* Forward lemmas on strict order *******************************************)
 136
 137 lemma ylt_inv_monotonic_plus_dx: ∀x,y,z. x + z < y + z → x < y.
 138 * [2: #y #z >yplus_comm #H elim (ylt_inv_Y1 … H) ]
 139 #x * // #y * [2: #H elim (ylt_inv_Y1 … H) ]
 140 /4 width=3 by ylt_inv_inj, ylt_inj, lt_plus_to_lt_l/
 141 qed-.
 142
 143 (* Properties on strict order ***********************************************)
 144
 145 lemma ylt_plus_dx1_trans: ∀x,z. z < x → ∀y. z < x + yinj y.
 146 /2 width=3 by ylt_yle_trans/ qed.
 147
 148 lemma ylt_plus_dx2_trans: ∀y,z. z < y → ∀x. z < yinj x + y.
 149 /2 width=3 by ylt_yle_trans/ qed.
 150
 151 lemma monotonic_ylt_plus_dx: ∀x,y. x < y → ∀z:nat. x + yinj z < y + yinj z.
 152 #x #y #Hxy #z elim z -z /3 width=1 by ylt_succ/
 153 qed.
 154
 155 lemma monotonic_ylt_plus_sn: ∀x,y. x < y → ∀z:nat. yinj z + x < yinj z + y.
 156 /2 width=1 by monotonic_ylt_plus_dx/ qed.
 157
 158 (* Properties on minus ******************************************************)
 159
 160 lemma yplus_minus_inj: ∀m:ynat. ∀n:nat. m + n - n = m.
 161 #m #n elim n -n //
 162 #n #IHn >(yplus_succ2 m n) >(yminus_succ … n) //
 163 qed.
 164
 165 lemma yplus_minus: ∀m,n. m + n - n ≤ m.
 166 #m * //
 167 qed.
 168
 169 (* Forward lemmas on minus **************************************************)
 170
 171 lemma yle_plus1_to_minus_inj2: ∀x,z:ynat. ∀y:nat. x + y ≤ z → x ≤ z - y.
 172 /2 width=1 by monotonic_yle_minus_dx/ qed-.
 173
 174 lemma yle_plus1_to_minus_inj1: ∀x,z:ynat. ∀y:nat. y + x ≤ z → x ≤ z - y.
 175 /2 width=1 by yle_plus1_to_minus_inj2/ qed-.
 176
 177 lemma yle_plus2_to_minus_inj2: ∀x,y:ynat. ∀z:nat. x ≤ y + z → x - z ≤ y.
 178 /2 width=1 by monotonic_yle_minus_dx/ qed-.
 179
 180 lemma yle_plus2_to_minus_inj1: ∀x,y:ynat. ∀z:nat. x ≤ z + y → x - z ≤ y.
 181 /2 width=1 by yle_plus2_to_minus_inj2/ qed-.
 182
 183 lemma yplus_minus_assoc_inj: ∀x:nat. ∀y,z:ynat. x ≤ y → z + (y - x) = z + y - x.
 184 #x *
 185 [ #y * // #z >yminus_inj >yplus_inj >yplus_inj
 186   /4 width=1 by yle_inv_inj, plus_minus, eq_f/
 187 | >yminus_Y_inj //
 188 ]
 189 qed-.
 190
 191 lemma yplus_minus_comm_inj: ∀y:nat. ∀x,z:ynat. y ≤ x → x + z - y = x - y + z.
 192 #y * // #x * //
 193 #z #Hxy >yplus_inj >yminus_inj <plus_minus
 194 /2 width=1 by yle_inv_inj/
 195 qed-.
 196
 197 (* Inversion lemmas on minus ************************************************)
 198
 199 lemma yle_inv_plus_inj2: ∀x,z:ynat. ∀y:nat. x + y ≤ z → x ≤ z - y ∧ y ≤ z.
 200 /3 width=3 by yle_plus1_to_minus_inj2, yle_trans, conj/ qed-.
 201
 202 lemma yle_inv_plus_inj1: ∀x,z:ynat. ∀y:nat. y + x ≤ z → x ≤ z - y ∧ y ≤ z.
 203 /2 width=1 by yle_inv_plus_inj2/ qed-.