matita/matita/contribs/lambdadelta/static_2/etc/teqx/reqx_fqus.etc

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/s_computation/fqus_fqup.ma".
  16 include "static_2/static/reqx_drops.ma".
  17 include "static_2/static/reqx_fqup.ma".
  18 include "static_2/static/reqx_reqx.ma".
  19
  20 (* SORT-IRRELEVANT EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***)
  21
  22 (* Properties with extended structural successor for closures ***************)
  23
  24 lemma fqu_teqx_conf (b):
  25       ∀G1,G2,L1,L2,U1,T1. ❪G1,L1,U1❫ ⬂[b] ❪G2,L2,T1❫ →
  26       ∀U2. U1 ≛ U2 →
  27       ∃∃L,T2. ❪G1,L1,U2❫ ⬂[b] ❪G2,L,T2❫ & L2 ≛[T1] L & T1 ≛ T2.
  28 #b #G1 #G2 #L1 #L2 #U1 #T1 #H elim H -G1 -G2 -L1 -L2 -U1 -T1
  29 [ #I #G #L #W #X #H >(teqx_inv_lref1 … H) -X
  30   /2 width=5 by fqu_lref_O, ex3_2_intro/
  31 | #I #G #L #W1 #U1 #X #H
  32   elim (teqx_inv_pair1 … H) -H #W2 #U2 #HW12 #_ #H destruct
  33   /2 width=5 by fqu_pair_sn, ex3_2_intro/
  34 | #p #I #G #L #W1 #U1 #Hb #X #H
  35   elim (teqx_inv_pair1 … H) -H #W2 #U2 #HW12 #HU12 #H destruct
  36   /3 width=5 by reqx_pair_refl, fqu_bind_dx, ex3_2_intro/
  37 | #p #I #G #L #W1 #U1 #Hb #X #H
  38   elim (teqx_inv_pair1 … H) -H #W2 #U2 #HW12 #HU12 #H destruct
  39   /3 width=5 by fqu_clear, ex3_2_intro/
  40 | #I #G #L #W1 #U1 #X #H
  41   elim (teqx_inv_pair1 … H) -H #W2 #U2 #_ #HU12 #H destruct
  42   /2 width=5 by fqu_flat_dx, ex3_2_intro/
  43 | #I #G #L #T1 #U1 #HTU1 #U2 #HU12
  44   elim (teqx_inv_lifts_sn … HU12 … HTU1) -U1
  45   /3 width=5 by fqu_drop, ex3_2_intro/
  46 ]
  47 qed-.
  48
  49 lemma teqx_fqu_trans (b):
  50       ∀G1,G2,L1,L2,U1,T1. ❪G1,L1,U1❫ ⬂[b] ❪G2,L2,T1❫ →
  51       ∀U2. U2 ≛ U1 →
  52       ∃∃L,T2. ❪G1,L1,U2❫ ⬂[b] ❪G2,L,T2❫ & T2 ≛ T1 & L ≛[T1] L2.
  53 #b #G1 #G2 #L1 #L2 #U1 #T1 #H12 #U2 #HU21
  54 elim (fqu_teqx_conf … H12 U2) -H12
  55 /3 width=5 by reqx_sym, teqx_sym, ex3_2_intro/
  56 qed-.
  57
  58 (* Basic_2A1: uses: lleq_fqu_trans *)
  59 lemma reqx_fqu_trans (b):
  60       ∀G1,G2,L2,K2,T,U. ❪G1,L2,T❫ ⬂[b] ❪G2,K2,U❫ →
  61       ∀L1. L1 ≛[T] L2 →
  62       ∃∃K1,U0. ❪G1,L1,T❫ ⬂[b] ❪G2,K1,U0❫ & U0 ≛ U & K1 ≛[U] K2.
  63 #b #G1 #G2 #L2 #K2 #T #U #H elim H -G1 -G2 -L2 -K2 -T -U
  64 [ #I #G #L2 #V2 #L1 #H elim (reqx_inv_zero_pair_dx … H) -H
  65   #K1 #V1 #HV1 #HV12 #H destruct
  66   /3 width=7 by teqx_reqx_conf_sn, fqu_lref_O, ex3_2_intro/
  67 | * [ #p ] #I #G #L2 #V #T #L1 #H
  68   [ elim (reqx_inv_bind … H)
  69   | elim (reqx_inv_flat … H)
  70   ] -H
  71   /2 width=5 by fqu_pair_sn, ex3_2_intro/
  72 | #p #I #G #L2 #V #T #Hb #L1 #H elim (reqx_inv_bind … H) -H
  73   /3 width=5 by fqu_bind_dx, ex3_2_intro/
  74 | #p #I #G #L2 #V #T #Hb #L1 #H elim (reqx_inv_bind_void … H) -H
  75   /3 width=5 by fqu_clear, ex3_2_intro/
  76 | #I #G #L2 #V #T #L1 #H elim (reqx_inv_flat … H) -H
  77   /2 width=5 by fqu_flat_dx, ex3_2_intro/
  78 | #I #G #L2 #T #U #HTU #Y #HU
  79   elim (reqx_fwd_dx … HU) #L1 #V1 #H destruct
  80   /5 width=14 by reqx_inv_lifts_bi, fqu_drop, drops_refl, drops_drop, ex3_2_intro/
  81 ]
  82 qed-.
  83
  84 (* Properties with optional structural successor for closures ***************)
  85
  86 lemma teqx_fquq_trans (b):
  87       ∀G1,G2,L1,L2,U1,T1. ❪G1,L1,U1❫ ⬂⸮[b] ❪G2,L2,T1❫ →
  88       ∀U2. U2 ≛ U1 →
  89       ∃∃L,T2. ❪G1,L1,U2❫ ⬂⸮[b] ❪G2,L,T2❫ & T2 ≛ T1 & L ≛[T1] L2.
  90 #b #G1 #G2 #L1 #L2 #U1 #T1 #H elim H -H
  91 [ #H #U2 #HU21 elim (teqx_fqu_trans … H … HU21) -U1
  92   /3 width=5 by fqu_fquq, ex3_2_intro/
  93 | * #HG #HL #HT destruct /2 width=5 by ex3_2_intro/
  94 ]
  95 qed-.
  96
  97 (* Basic_2A1: was just: lleq_fquq_trans *)
  98 lemma reqx_fquq_trans (b):
  99       ∀G1,G2,L2,K2,T,U. ❪G1,L2,T❫ ⬂⸮[b] ❪G2,K2,U❫ →
 100       ∀L1. L1 ≛[T] L2 →
 101       ∃∃K1,U0. ❪G1,L1,T❫ ⬂⸮[b] ❪G2,K1,U0❫ & U0 ≛ U & K1 ≛[U] K2.
 102 #b #G1 #G2 #L2 #K2 #T #U #H elim H -H
 103 [ #H #L1 #HL12 elim (reqx_fqu_trans … H … HL12) -L2 /3 width=5 by fqu_fquq, ex3_2_intro/
 104 | * #HG #HL #HT destruct /2 width=5 by ex3_2_intro/
 105 ]
 106 qed-.
 107
 108 (* Properties with plus-iterated structural successor for closures **********)
 109
 110 (* Basic_2A1: was just: lleq_fqup_trans *)
 111 lemma reqx_fqup_trans (b):
 112       ∀G1,G2,L2,K2,T,U. ❪G1,L2,T❫ ⬂+[b] ❪G2,K2,U❫ →
 113       ∀L1. L1 ≛[T] L2 →
 114       ∃∃K1,U0. ❪G1,L1,T❫ ⬂+[b] ❪G2,K1,U0❫ & U0 ≛ U & K1 ≛[U] K2.
 115 #b #G1 #G2 #L2 #K2 #T #U #H @(fqup_ind … H) -G2 -K2 -U
 116 [ #G2 #K2 #U #HTU #L1 #HL12 elim (reqx_fqu_trans … HTU … HL12) -L2
 117   /3 width=5 by fqu_fqup, ex3_2_intro/
 118 | #G #G2 #K #K2 #U #U2 #_ #HU2 #IHTU #L1 #HL12
 119   elim (IHTU … HL12) -L2 #K0 #U0 #HTU #HU0 #HK0
 120   elim (reqx_fqu_trans … HU2 … HK0) -K #K1 #U1 #HU1 #HU12 #HK12
 121   elim (teqx_fqu_trans … HU1 … HU0) -U #K3 #U3 #HU03 #HU31 #HK31
 122   @(ex3_2_intro … K3 U3) (**) (* full auto too slow *)
 123   /3 width=5 by reqx_trans, teqx_reqx_conf_sn, fqup_strap1, teqx_trans/
 124 ]
 125 qed-.
 126
 127 lemma teqx_fqup_trans (b):
 128       ∀G1,G2,L1,L2,U1,T1. ❪G1,L1,U1❫ ⬂+[b] ❪G2,L2,T1❫ →
 129       ∀U2. U2 ≛ U1 →
 130       ∃∃L,T2. ❪G1,L1,U2❫ ⬂+[b] ❪G2,L,T2❫ & T2 ≛ T1 & L ≛[T1] L2.
 131 #b #G1 #G2 #L1 #L2 #U1 #T1 #H @(fqup_ind_dx … H) -G1 -L1 -U1
 132 [ #G1 #L1 #U1 #H #U2 #HU21 elim (teqx_fqu_trans … H … HU21) -U1
 133   /3 width=5 by fqu_fqup, ex3_2_intro/
 134 | #G1 #G #L1 #L #U1 #U #H #_ #IH #U2 #HU21
 135   elim (teqx_fqu_trans … H … HU21) -U1 #L0 #T #H1 #HTU #HL0
 136   lapply (teqx_reqx_div … HTU … HL0) -HL0 #HL0
 137   elim (IH … HTU) -U #K2 #U1 #H2 #HUT1 #HKL2
 138   elim (reqx_fqup_trans … H2 … HL0) -L #K #U #H2 #HU1 #HK2
 139   lapply (teqx_reqx_conf_sn … HUT1 … HK2) -HK2 #HK2
 140   /3 width=7 by reqx_trans, fqup_strap2, teqx_trans, ex3_2_intro/
 141 ]
 142 qed-.
 143
 144 (* Properties with star-iterated structural successor for closures **********)
 145
 146 lemma teqx_fqus_trans (b):
 147       ∀G1,G2,L1,L2,U1,T1. ❪G1,L1,U1❫ ⬂*[b] ❪G2,L2,T1❫ →
 148       ∀U2. U2 ≛ U1 →
 149       ∃∃L,T2. ❪G1,L1,U2❫ ⬂*[b] ❪G2,L,T2❫ & T2 ≛ T1 & L ≛[T1] L2.
 150 #b #G1 #G2 #L1 #L2 #U1 #T1 #H #U2 #HU21 elim(fqus_inv_fqup … H) -H
 151 [ #H elim (teqx_fqup_trans … H … HU21) -U1 /3 width=5 by fqup_fqus, ex3_2_intro/
 152 | * #HG #HL #HT destruct /2 width=5 by ex3_2_intro/
 153 ]
 154 qed-.
 155
 156 (* Basic_2A1: was just: lleq_fqus_trans *)
 157 lemma reqx_fqus_trans (b):
 158       ∀G1,G2,L2,K2,T,U. ❪G1,L2,T❫ ⬂*[b] ❪G2,K2,U❫ →
 159       ∀L1. L1 ≛[T] L2 →
 160       ∃∃K1,U0. ❪G1,L1,T❫ ⬂*[b] ❪G2,K1,U0❫ & U0 ≛ U & K1 ≛[U] K2.
 161 #b #G1 #G2 #L2 #K2 #T #U #H #L1 #HL12 elim(fqus_inv_fqup … H) -H
 162 [ #H elim (reqx_fqup_trans … H … HL12) -L2 /3 width=5 by fqup_fqus, ex3_2_intro/
 163 | * #HG #HL #HT destruct /2 width=5 by ex3_2_intro/
 164 ]
 165 qed-.