matita/matita/contribs/lambdadelta/static_2/relocation/drops_ctc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/star.ma".
  16 include "static_2/relocation/seq_seq.ma".
  17
  18 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Properties with contextual transitive closure ****************************)
  21
  22 (* Basic_2A1: was: d_liftable_LTC *)
  23 lemma d2_liftable_sn_CTC: ∀C,S,R. d_liftable2_sn C S R → d_liftable2_sn C S (CTC … R).
  24 #C #S #R #HR #K #T1 #T2 #H elim H -T2
  25 [ #T2 #HT12 #b #f #L #HLK #U1 #HTU1
  26   elim (HR … HT12 … HLK … HTU1) /3 width=3 by inj, ex2_intro/
  27 | #T #T2 #_ #HT2 #IHT1 #b #f #L #HLK #U1 #HTU1
  28   elim (IHT1 … HLK … HTU1) -T1 #U #HTU #HU1
  29   elim (HR … HT2 … HLK … HTU) -HR -K -T /3 width=5 by step, ex2_intro/
  30 ]
  31 qed-.
  32
  33 (* Basic_2A1: was: d_deliftable_sn_LTC *)
  34 lemma d2_deliftable_sn_CTC: ∀C,S,R. d_deliftable2_sn C S R → d_deliftable2_sn C S (CTC … R).
  35 #C #S #R #HR #L #U1 #U2 #H elim H -U2
  36 [ #U2 #HU12 #b #f #K #HLK #T1 #HTU1
  37   elim (HR … HU12 … HLK … HTU1) -HR -L -U1 /3 width=3 by inj, ex2_intro/
  38 | #U #U2 #_ #HU2 #IHU1 #b #f #K #HLK #T1 #HTU1
  39   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
  40   elim (HR … HU2 … HLK … HTU) -HR -L -U /3 width=5 by step, ex2_intro/
  41 ]
  42 qed-.
  43
  44 lemma co_dropable_sn_CTC: ∀R. co_dropable_sn R → co_dropable_sn (CTC … R).
  45 #R #HR #b #f #L1 #K1 #HLK1 #Hf #f2 #L2 #H elim H -L2
  46 [ #L2 #HL12 #f1 #H elim (HR … HLK1 … Hf … HL12 … H) -HR -Hf -f2 -L1
  47   /3 width=3 by inj, ex2_intro/
  48 | #L #L2 #_ #HL2 #IH #f1 #H elim (IH … H) -IH
  49   #K #HK1 #HLK elim (HR … HLK … HL2 … H) -HR -f2 -L
  50   /3 width=3 by step, ex2_intro/
  51 ]
  52 qed-.
  53
  54 lemma co_dropable_dx_CTC: ∀R. co_dropable_dx R → co_dropable_dx (CTC … R).
  55 #R #HR #f2 #L1 #L2 #H elim H -L2
  56 [ #L2 #HL12 #b #f #K2 #HLK2 #Hf #f1 #Hf2 elim (HR … HL12 … HLK2 … Hf … Hf2) -HR -Hf -f2 -L2
  57   /3 width=3 by inj, ex2_intro/
  58 | #L #L2 #_ #HL2 #IHL1 #b #f #K2 #HLK2 #Hf #f1 #Hf2 elim (HR … HL2 … HLK2 … Hf … Hf2) -HR -L2
  59   #K #HLK #HK2 elim (IHL1 … HLK … Hf … Hf2) -Hf -f2 -L
  60   /3 width=5 by step, ex2_intro/
  61 ]
  62 qed-.
  63
  64 lemma co_dedropable_sn_CTC: ∀R. co_dedropable_sn R → co_dedropable_sn (CTC … R).
  65 #R #HR #b #f #L1 #K1 #HLK1 #f1 #K2 #H elim H -K2
  66 [ #K2 #HK12 #f2 #Hf elim (HR … HLK1 … HK12 … Hf) -HR -f1 -K1
  67   /3 width=4 by inj, ex3_intro/
  68 | #K #K2 #_ #HK2 #IH #f2 #Hf elim (IH … Hf) -IH -K1
  69   #L #H1L1 #HLK #H2L1 elim (HR … HLK … HK2 … Hf) -HR -f1 -K
  70   /3 width=6 by seq_trans, step, ex3_intro/
  71 ]
  72 qed-.