matita/matita/contribs/lambdadelta/static_2/relocation/drops_ltc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/ltc.ma".
  16 include "static_2/relocation/seq_seq.ma".
  17
  18 (* GENERIC SLICING FOR LOCAL ENVIRONMENTS ***********************************)
  19
  20 (* Properties with labeled transitive closure *******************************)
  21
  22 lemma d2_liftable_sn_ltc: ∀A,f. associative … f →
  23                           ∀C,S,R. (∀n. d_liftable2_sn C S (λL. R L n)) →
  24                           ∀n. d_liftable2_sn C S (λL. ltc A f … (R L) n).
  25 #A #g #Hg #C #S #R #HR #n #K #T1 #T2 #H
  26 @(ltc_ind_dx … Hg ???? H) -n -T2
  27 [ #n #T2 #HT12 #b #g #L #HLK #U1 #HTU1
  28   elim (HR … HT12 … HLK … HTU1) -b -K -T1 -HR
  29   /3 width=3 by ltc_rc, ex2_intro/
  30 | #n1 #n2 #T #T2 #_ #IHT1 #HT2 #b #f #L #HLK #U1 #HTU1
  31   elim (IHT1 … HLK … HTU1) -T1 #U #HTU #HU1
  32   elim (HR … HT2 … HLK … HTU) -HR -K -T
  33   /3 width=5 by ltc_dx, ex2_intro/
  34 ]
  35 qed-.
  36
  37 lemma d2_deliftable_sn_ltc: ∀A,f. associative … f →
  38                             ∀C,S,R. (∀n. d_deliftable2_sn C S (λL. R L n)) →
  39                             ∀n. d_deliftable2_sn C S (λL. ltc A f … (R L) n).
  40 #A #g #Hg #C #S #R #HR #n #L #U1 #U2 #H
  41 @(ltc_ind_dx … Hg ???? H) -n -U2
  42 [ #n #U2 #HU12 #b #g #K #HLK #T1 #HTU1
  43   elim (HR … HU12 … HLK … HTU1) -b -L -U1 -HR
  44   /3 width=3 by ltc_rc, ex2_intro/
  45 | #n1 #n2 #U #U2 #_ #IHU1 #HU2 #b #f #K #HLK #T1 #HTU1
  46   elim (IHU1 … HLK … HTU1) -IHU1 -U1 #T #HTU #HT1
  47   elim (HR … HU2 … HLK … HTU) -L -U -HR
  48   /3 width=5 by ltc_dx, ex2_intro/
  49 ]
  50 qed-.
  51
  52 lemma co_dropable_sn_ltc: ∀A,f. associative … f →
  53                           ∀R. (∀n. co_dropable_sn (λL. R L n)) →
  54                           ∀n. co_dropable_sn (λL. ltc A f … (R L) n).
  55 #A #g #Hg #R #HR #n #b #f #L1 #K1 #HLK1 #Hf #f2 #L2 #H
  56 @(ltc_ind_dx … Hg ???? H) -n -L2
  57 [ #n #L2 #HL12 #g1 #H
  58   elim (HR … HLK1 … Hf … HL12 … H) -f2 -L1 -HR -Hf
  59   /3 width=3 by ltc_rc, ex2_intro/
  60 | #n1 #n2 #L #L2 #_ #IH #HL2 #f1 #H
  61   elim (IH … H) -IH #K #HK1 #HLK
  62   elim (HR … HLK … HL2 … H) -f2 -L -HR
  63   /3 width=3 by ltc_dx, ex2_intro/
  64 ]
  65 qed-.
  66
  67 lemma co_dropable_dx_ltc: ∀A,f. associative … f →
  68                           ∀R. (∀n. co_dropable_dx (λL. R L n)) →
  69                           ∀n. co_dropable_dx (λL. ltc A f … (R L) n).
  70 #A #g #Hg #R #HR #n #f2 #L1 #L2 #H
  71 @(ltc_ind_dx … Hg ???? H) -n -L2
  72 [ #n #L2 #HL12 #b #f #K2 #HLK2 #Hf #f1 #Hf2
  73   elim (HR … HL12 … HLK2 … Hf … Hf2) -f2 -L2 -HR -Hf
  74   /3 width=3 by ltc_rc, ex2_intro/
  75 | #n1 #n2 #L #L2 #_ #IHL1 #HL2 #b #f #K2 #HLK2 #Hf #f1 #Hf2
  76   elim (HR … HL2 … HLK2 … Hf … Hf2) -L2 -HR #K #HLK #HK2
  77   elim (IHL1 … HLK … Hf … Hf2) -Hf -f2 -L
  78   /3 width=5 by ltc_dx, ex2_intro/
  79 ]
  80 qed-.
  81
  82 lemma co_dedropable_sn_ltc: ∀A,f. associative … f →
  83                             ∀R. (∀n. co_dedropable_sn (λL. R L n)) →
  84                             ∀n. co_dedropable_sn (λL. ltc A f … (R L) n).
  85 #A #g #Hg #R #HR #n #b #f #L1 #K1 #HLK1 #f1 #K2 #H
  86 @(ltc_ind_dx … Hg ???? H) -n -K2
  87 [ #n #K2 #HK12 #f2 #Hf
  88   elim (HR … HLK1 … HK12 … Hf) -f1 -K1 -HR
  89   /3 width=4 by ltc_rc, ex3_intro/
  90 | #n1 #n2 #K #K2 #_ #IH #HK2 #f2 #Hf
  91   elim (IH … Hf) -K1 -IH #L #H1L1 #HLK #H2L1
  92   elim (HR … HLK … HK2 … Hf) -f1 -K -HR
  93   /3 width=6 by seq_trans, ltc_dx, ex3_intro/
  94 ]
  95 qed-.