matita/matita/contribs/lambdadelta/static_2/relocation/lifts_lifts_vector.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_lifts.ma".
  16 include "static_2/relocation/lifts_vector.ma".
  17
  18 (* GENERIC RELOCATION FOR TERM VECTORS *************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: includes: lifts_inj *)
  23 theorem liftsv_inj: ∀f,T1s,Us. ⬆*[f] T1s ≘ Us →
  24                     ∀T2s. ⬆*[f] T2s ≘ Us → T1s = T2s.
  25 #f #T1s #Us #H elim H -T1s -Us
  26 [ #T2s #H >(liftsv_inv_nil2 … H) -H //
  27 | #T1s #Us #T1 #U #HT1U #_ #IHT1Us #X #H destruct
  28   elim (liftsv_inv_cons2 … H) -H #T2 #T2s #HT2U #HT2Us #H destruct
  29   >(lifts_inj … HT1U … HT2U) -U /3 width=1 by eq_f/
  30 ]
  31 qed-.
  32
  33 (* Basic_2A1: includes: liftv_mono *)
  34 theorem liftsv_mono: ∀f,Ts,U1s. ⬆*[f] Ts ≘ U1s →
  35                      ∀U2s. ⬆*[f] Ts ≘ U2s → U1s = U2s.
  36 #f #Ts #U1s #H elim H -Ts -U1s
  37 [ #U2s #H >(liftsv_inv_nil1 … H) -H //
  38 | #Ts #U1s #T #U1 #HTU1 #_ #IHTU1s #X #H destruct
  39   elim (liftsv_inv_cons1 … H) -H #U2 #U2s #HTU2 #HTU2s #H destruct
  40   >(lifts_mono … HTU1 … HTU2) -T /3 width=1 by eq_f/
  41 ]
  42 qed-.
  43
  44 (* Basic_1: includes: lifts1_xhg (right to left) *)
  45 (* Basic_2A1: includes: liftsv_liftv_trans_le *)
  46 theorem liftsv_trans: ∀f1,T1s,Ts. ⬆*[f1] T1s ≘ Ts → ∀T2s,f2. ⬆*[f2] Ts ≘ T2s →
  47                       ∀f. f2 ⊚ f1 ≘ f → ⬆*[f] T1s ≘ T2s.
  48 #f1 #T1s #Ts #H elim H -T1s -Ts
  49 [ #T2s #f2 #H >(liftsv_inv_nil1 … H) -T2s /2 width=3 by liftsv_nil/
  50 | #T1s #Ts #T1 #T #HT1 #_ #IHT1s #X #f2 #H elim (liftsv_inv_cons1 … H) -H
  51   #T2 #T2s #HT2 #HT2s #H destruct /3 width=6 by lifts_trans, liftsv_cons/
  52 ]
  53 qed-.