matita/matita/contribs/lambdadelta/static_2/relocation/lifts_tdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/tdeq.ma".
  16 include "static_2/relocation/lifts_lifts.ma".
  17
  18 (* GENERIC RELOCATION FOR TERMS *********************************************)
  19
  20 (* Properties with sort-irrelevant equivalence for terms ********************)
  21
  22 lemma tdeq_lifts_sn: liftable2_sn tdeq.
  23 #T1 #T2 #H elim H -T1 -T2 [||| * ]
  24 [ #s1 #s2 #f #X #H >(lifts_inv_sort1 … H) -H
  25   /3 width=3 by lifts_sort, tdeq_sort, ex2_intro/
  26 | #i #f #X #H elim (lifts_inv_lref1 … H) -H
  27   /3 width=3 by lifts_lref, tdeq_lref, ex2_intro/
  28 | #l #f #X #H >(lifts_inv_gref1 … H) -H
  29   /2 width=3 by lifts_gref, tdeq_gref, ex2_intro/
  30 | #p #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f #X #H elim (lifts_inv_bind1 … H) -H
  31   #W1 #U1 #HVW1 #HTU1 #H destruct
  32   elim (IHV … HVW1) -V1 elim (IHT … HTU1) -T1
  33   /3 width=5 by lifts_bind, tdeq_pair, ex2_intro/
  34 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f #X #H elim (lifts_inv_flat1 … H) -H
  35   #W1 #U1 #HVW1 #HTU1 #H destruct
  36   elim (IHV … HVW1) -V1 elim (IHT … HTU1) -T1
  37   /3 width=5 by lifts_flat, tdeq_pair, ex2_intro/
  38 ]
  39 qed-.
  40
  41 lemma tdeq_lifts_bi: liftable2_bi tdeq.
  42 /3 width=6 by tdeq_lifts_sn, liftable2_sn_bi/ qed-.
  43
  44 (* Inversion lemmas with sort-irrelevant equivalence for terms **************)
  45
  46 lemma tdeq_inv_lifts_sn: deliftable2_sn tdeq.
  47 #U1 #U2 #H elim H -U1 -U2 [||| * ]
  48 [ #s1 #s2 #f #X #H >(lifts_inv_sort2 … H) -H
  49   /3 width=3 by lifts_sort, tdeq_sort, ex2_intro/
  50 | #i #f #X #H elim (lifts_inv_lref2 … H) -H
  51   /3 width=3 by lifts_lref, tdeq_lref, ex2_intro/
  52 | #l #f #X #H >(lifts_inv_gref2 … H) -H
  53   /2 width=3 by lifts_gref, tdeq_gref, ex2_intro/
  54 | #p #I #W1 #W2 #U1 #U2 #_ #_ #IHW #IHU #f #X #H elim (lifts_inv_bind2 … H) -H
  55   #V1 #T1 #HVW1 #HTU1 #H destruct
  56   elim (IHW … HVW1) -W1 elim (IHU … HTU1) -U1
  57   /3 width=5 by lifts_bind, tdeq_pair, ex2_intro/
  58 | #I #W1 #W2 #U1 #U2 #_ #_ #IHW #IHU #f #X #H elim (lifts_inv_flat2 … H) -H
  59   #V1 #T1 #HVW1 #HTU1 #H destruct
  60   elim (IHW … HVW1) -W1 elim (IHU … HTU1) -U1
  61   /3 width=5 by lifts_flat, tdeq_pair, ex2_intro/
  62 ]
  63 qed-.
  64
  65 lemma tdeq_inv_lifts_dx: deliftable2_dx tdeq.
  66 /3 width=3 by tdeq_inv_lifts_sn, deliftable2_sn_dx, tdeq_sym/ qed-.
  67
  68 lemma tdeq_inv_lifts_bi: deliftable2_bi tdeq.
  69 /3 width=6 by tdeq_inv_lifts_sn, deliftable2_sn_bi/ qed-.
  70
  71 lemma tdeq_lifts_inv_pair_sn (I) (f:rtmap):
  72                              ∀X,T. ⬆*[f]X ≘ T → ∀V. ②{I}V.T ≛ X → ⊥.
  73 #I #f #X #T #H elim H -f -X -T
  74 [ #f #s #V #H
  75   elim (tdeq_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  76 | #f #i #j #_ #V #H
  77   elim (tdeq_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  78 | #f #l #V #H
  79   elim (tdeq_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  80 | #f #p #J #X1 #T1 #X2 #T2 #_ #_ #_ #IH2 #V #H
  81   elim (tdeq_inv_pair1 … H) -H #Z1 #Z2 #_ #HZ2 #H destruct
  82   /2 width=2 by/
  83 | #f #J #X1 #T1 #X2 #T2 #_ #_ #_ #IH2 #V #H
  84   elim (tdeq_inv_pair1 … H) -H #Z1 #Z2 #_ #HZ2 #H destruct
  85   /2 width=2 by/
  86 ]
  87 qed-.