matita/matita/contribs/lambdadelta/static_2/relocation/lifts_teqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/teqx.ma".
  16 include "static_2/relocation/lifts_lifts.ma".
  17
  18 (* GENERIC RELOCATION FOR TERMS *********************************************)
  19
  20 (* Properties with sort-irrelevant equivalence for terms ********************)
  21
  22 lemma teqx_lifts_sn: liftable2_sn teqx.
  23 #T1 #T2 #H elim H -T1 -T2 [||| * ]
  24 [ #s1 #s2 #f #X #H >(lifts_inv_sort1 … H) -H
  25   /3 width=3 by lifts_sort, teqx_sort, ex2_intro/
  26 | #i #f #X #H elim (lifts_inv_lref1 … H) -H
  27   /3 width=3 by lifts_lref, teqx_lref, ex2_intro/
  28 | #l #f #X #H >(lifts_inv_gref1 … H) -H
  29   /2 width=3 by lifts_gref, teqx_gref, ex2_intro/
  30 | #p #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f #X #H elim (lifts_inv_bind1 … H) -H
  31   #W1 #U1 #HVW1 #HTU1 #H destruct
  32   elim (IHV … HVW1) -V1 elim (IHT … HTU1) -T1
  33   /3 width=5 by lifts_bind, teqx_pair, ex2_intro/
  34 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV #IHT #f #X #H elim (lifts_inv_flat1 … H) -H
  35   #W1 #U1 #HVW1 #HTU1 #H destruct
  36   elim (IHV … HVW1) -V1 elim (IHT … HTU1) -T1
  37   /3 width=5 by lifts_flat, teqx_pair, ex2_intro/
  38 ]
  39 qed-.
  40
  41 lemma teqx_lifts_dx: liftable2_dx teqx.
  42 /3 width=3 by teqx_lifts_sn, liftable2_sn_dx, teqx_sym/ qed-.
  43
  44 lemma teqx_lifts_bi: liftable2_bi teqx.
  45 /3 width=6 by teqx_lifts_sn, liftable2_sn_bi/ qed-.
  46
  47 (* Inversion lemmas with sort-irrelevant equivalence for terms **************)
  48
  49 lemma teqx_inv_lifts_sn: deliftable2_sn teqx.
  50 #U1 #U2 #H elim H -U1 -U2 [||| * ]
  51 [ #s1 #s2 #f #X #H >(lifts_inv_sort2 … H) -H
  52   /3 width=3 by lifts_sort, teqx_sort, ex2_intro/
  53 | #i #f #X #H elim (lifts_inv_lref2 … H) -H
  54   /3 width=3 by lifts_lref, teqx_lref, ex2_intro/
  55 | #l #f #X #H >(lifts_inv_gref2 … H) -H
  56   /2 width=3 by lifts_gref, teqx_gref, ex2_intro/
  57 | #p #I #W1 #W2 #U1 #U2 #_ #_ #IHW #IHU #f #X #H elim (lifts_inv_bind2 … H) -H
  58   #V1 #T1 #HVW1 #HTU1 #H destruct
  59   elim (IHW … HVW1) -W1 elim (IHU … HTU1) -U1
  60   /3 width=5 by lifts_bind, teqx_pair, ex2_intro/
  61 | #I #W1 #W2 #U1 #U2 #_ #_ #IHW #IHU #f #X #H elim (lifts_inv_flat2 … H) -H
  62   #V1 #T1 #HVW1 #HTU1 #H destruct
  63   elim (IHW … HVW1) -W1 elim (IHU … HTU1) -U1
  64   /3 width=5 by lifts_flat, teqx_pair, ex2_intro/
  65 ]
  66 qed-.
  67
  68 lemma teqx_inv_lifts_dx: deliftable2_dx teqx.
  69 /3 width=3 by teqx_inv_lifts_sn, deliftable2_sn_dx, teqx_sym/ qed-.
  70
  71 lemma teqx_inv_lifts_bi: deliftable2_bi teqx.
  72 /3 width=6 by teqx_inv_lifts_sn, deliftable2_sn_bi/ qed-.
  73
  74 lemma teqx_lifts_inv_pair_sn (I) (f:rtmap):
  75                              ∀X,T. ⇧*[f]X ≘ T → ∀V. ②[I]V.T ≛ X → ⊥.
  76 #I #f #X #T #H elim H -f -X -T
  77 [ #f #s #V #H
  78   elim (teqx_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  79 | #f #i #j #_ #V #H
  80   elim (teqx_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  81 | #f #l #V #H
  82   elim (teqx_inv_pair1 … H) -H #X1 #X2 #_ #_ #H destruct
  83 | #f #p #J #X1 #T1 #X2 #T2 #_ #_ #_ #IH2 #V #H
  84   elim (teqx_inv_pair1 … H) -H #Z1 #Z2 #_ #HZ2 #H destruct
  85   /2 width=2 by/
  86 | #f #J #X1 #T1 #X2 #T2 #_ #_ #_ #IH2 #V #H
  87   elim (teqx_inv_pair1 … H) -H #Z1 #Z2 #_ #HZ2 #H destruct
  88   /2 width=2 by/
  89 ]
  90 qed-.