matita/matita/contribs/lambdadelta/static_2/static/fdeq_fdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_rdeq.ma".
  16 include "static_2/static/fdeq.ma".
  17
  18 (* DEGREE-BASED EQUIVALENCE FOR CLOSURES ON REFERRED ENTRIES ****************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma fdeq_sym: ∀h,o. tri_symmetric … (fdeq h o).
  23 #h #o #G1 #G2 #L1 #L2 #T1 #T2 * -G1 -L1 -T1
  24 /3 width=1 by fdeq_intro_dx, rdeq_sym, tdeq_sym/
  25 qed-.
  26
  27 (* Main properties **********************************************************)
  28
  29 theorem fdeq_trans: ∀h,o. tri_transitive … (fdeq h o).
  30 #h #o #G1 #G #L1 #L #T1 #T * -G -L -T
  31 #L #T #HL1 #HT1 #G2 #L2 #T2 * -G2 -L2 -T2
  32 /4 width=5 by fdeq_intro_sn, rdeq_trans, tdeq_rdeq_div, tdeq_trans/
  33 qed-.
  34
  35 theorem fdeq_canc_sn: ∀h,o,G,G1,G2,L,L1,L2,T,T1,T2.
  36                       ⦃G, L, T⦄ ≛[h, o] ⦃G1, L1, T1⦄→ ⦃G, L, T⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  37 /3 width=5 by fdeq_trans, fdeq_sym/ qed-.
  38
  39 theorem fdeq_canc_dx: ∀h,o,G1,G2,G,L1,L2,L,T1,T2,T.
  40                       ⦃G1, L1, T1⦄ ≛[h, o] ⦃G, L, T⦄ → ⦃G2, L2, T2⦄ ≛[h, o] ⦃G, L, T⦄ → ⦃G1, L1, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  41 /3 width=5 by fdeq_trans, fdeq_sym/ qed-.
  42
  43 (* Main inversion lemmas with degree-based equivalence on terms *************)
  44
  45 theorem fdeq_tdneq_repl_dx: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄ →
  46                             ∀U1,U2. ⦃G1, L1, U1⦄ ≛[h, o] ⦃G2, L2, U2⦄ →
  47                             (T2 ≛[h, o] U2 → ⊥) → (T1 ≛[h, o] U1 → ⊥).
  48 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #HT #U1 #U2 #HU #HnTU2 #HTU1
  49 elim (fdeq_inv_gen_sn … HT) -HT #_ #_ #HT
  50 elim (fdeq_inv_gen_sn … HU) -HU #_ #_ #HU
  51 /3 width=5 by tdeq_repl/
  52 qed-.