matita/matita/contribs/lambdadelta/static_2/static/feqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareqsn_6.ma".
  16 include "static_2/syntax/genv.ma".
  17 include "static_2/static/reqx.ma".
  18
  19 (* SORT-IRRELEVANT EQUIVALENCE FOR CLOSURES ON REFERRED ENTRIES *************)
  20
  21 inductive feqx (G) (L1) (T1): relation3 genv lenv term ≝
  22 | feqx_intro_sn: ∀L2,T2. L1 ≛[T1] L2 → T1 ≛ T2 →
  23                  feqx G L1 T1 G L2 T2
  24 .
  25
  26 interpretation
  27   "sort-irrelevant equivalence on referred entries (closure)"
  28   'StarEqSn G1 L1 T1 G2 L2 T2 = (feqx G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic_properties *********************************************************)
  31
  32 lemma feqx_intro_dx (G):
  33       ∀L1,L2,T2. L1 ≛[T2] L2 →
  34       ∀T1. T1 ≛ T2 → ❪G,L1,T1❫ ≛ ❪G,L2,T2❫.
  35 /3 width=3 by feqx_intro_sn, teqx_reqx_div/ qed.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 lemma feqx_inv_gen_sn:
  40       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ →
  41       ∧∧ G1 = G2 & L1 ≛[T1] L2 & T1 ≛ T2.
  42 #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2 /2 width=1 by and3_intro/
  43 qed-.
  44
  45 lemma feqx_inv_gen_dx:
  46       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ →
  47       ∧∧ G1 = G2 & L1 ≛[T2] L2 & T1 ≛ T2.
  48 #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  49 /3 width=3 by teqx_reqx_conf_sn, and3_intro/
  50 qed-.
  51
  52 (* Basic_2A1: removed theorems 6:
  53               fleq_refl fleq_sym fleq_inv_gen
  54               fleq_trans fleq_canc_sn fleq_canc_dx
  55 *)